dnl without this order in this file, autoconf will not work!
dnl the argument is a source file out of your sources. But
dnl acinclude.m4 makes the job for all programs ;-)
AC_INIT(aclocal.m4)

dnl enable the following if you want to use autoconf/automake
dnl framework from a certain directory (like kde-common)
dnl AC_CONFIG_AUX_DIR(admin)

AC_CANONICAL_SYSTEM
AC_ARG_PROGRAM

AM_INIT_AUTOMAKE(mutella,0.4.5)

AC_PREFIX_DEFAULT(/usr/local)
if test "x$prefix" = "xNONE"; then
  prefix=$ac_default_prefix
  ac_configure_args="$ac_configure_args --prefix $prefix"
fi

dnl without this order in this file, automake will be confused!
dnl
AM_CONFIG_HEADER(config.h)

dnl checks for programs.
dnl first check for c/c++ compilers
dnl (do not use in later versions - this is evil ) AC_CHECK_COMPILERS
kde_use_debug_define=no
dnl enable-debug=no
AC_PROG_CC
AC_PROG_CXX

dnl Autoconf 2.13/Automake 1.4 Compatibility Issues
dnl OBJEXT and EXEEXT have changed.  We'll stay backwards-compatible for now.
AC_EXEEXT
AC_OBJEXT
AC_SUBST(EXEEXT)
AC_SUBST(OBJEXT)

dnl create only shared libtool-libraries
dnl Pointless until we readd libtool.
dnl AC_ENABLE_SHARED(yes)

dnl set the following to yes, if you want to create static
dnl libtool-libraries
dnl Pointless until we readd libtool.
dnl Of course should also be a --with flag, not this way.
dnl AC_ENABLE_STATIC(no)

dnl create a working libtool-script
dnl KDE_PROG_LIBTOOL

dnl check for presence of dynamic-loading-library functions
dnl Libtool uses ltdl by default - we'll readd when this day comes.
dnl KDE_CHECK_LIBDL

dnl activate the following for some additional tests
dnl   (compat, crypt, socket, nsl, ...)
dnl KDE_MISC_TESTS

AC_ARG_ENABLE(sgi-stl,
[  --enable-sgi-stl	Enables use of STL library from SGI, shipped with mutella [default=no]],
[case "${enableval}" in
  yes) sgi_stl=true
	;;
  no)  sgi_stl=false
	;;
  *) AC_MSG_ERROR(bad value ${enableval} for --enable-sgi-stl) ;;
esac],[sgi_stl=false])
if test $sgi_stl = true; then
	CXXFLAGS="-I./sgi_stl -I../sgi_stl -ftemplate-depth-25 -Wno-deprecated $CXXFLAGS"
fi

AC_MSG_CHECKING(for extra libs)
AC_ARG_WITH(extra-libs,
    [  --with-extra-libs=DIR	Adds the directory provided to the list of library paths],
    m_extra_libs="$withval"; USER_LIBRARIES="$USER_LIBRARIES -L$withval",
    m_extra_libs="(none)" )
AC_MSG_RESULT($m_extra_libs)

dnl do USER_INCLUDES/USER_LIBRARIES substitutions (not used, methinks, but wtf.)
dnl MZ: wtf? it does not work on my box. (tries to build -L/home/...)
dnl AC_SUBST(USER_INCLUDES)
dnl AC_SUBST(USER_LIBRARIES)

dnl Set our CFLAGS and LDFLAGS entries, which will be used in tests.
CFLAGS="$CFLAGS $USER_INCLUDES"
CPPFLAGS="$CPPFLAGS $USER_INCLUDES"
LDFLAGS="$LDFLAGS $USER_LIBRARIES"

dnl Set our "all libraries" and "all includes" variables, which will be used in makefiles.
all_libraries="$all_libraries $USER_LIBRARIES"
all_includes="$all_includes $USER_INCLUDES"
AC_SUBST(all_libraries)
AC_SUBST(all_includes)

AC_SUBST(AUTODIRS)

AC_ARG_WITH(sgi-stl,
    [  --with-sgi-stl=yes	Forses mutella to use STL library from SGI],
    m_extra_libs="$withval"; USER_LIBRARIES="$USER_LIBRARIES -L$withval",
    m_extra_libs="(none)" )
AC_MSG_RESULT($m_extra_libs)

dnl examples are specific headers, libraries, etc.

dnl Check for C++ specific headers
dnl AC_LANG_SAVE
AC_LANG_CPLUSPLUS

dnl Check to see if we have limits (gcc3.x)
AC_CHECK_HEADERS(limits)

dnl AC_LANG_RESTORE not present in 2.5.4
AC_LANG_C

dnl Check for endianness.
AC_C_BIGENDIAN

dnl Check for the existence and location of alloca.h
dnl Solaris and AIX have wierdness about this.
AC_FUNC_ALLOCA

dnl Let's grab our time headers before going on.
AC_HEADER_TIME

dnl Check to see if we've got decent sleeps.
dnl First, we check for nanosleep and the existence of librt and libposix4.
AC_CHECK_FUNCS(nanosleep,,
	[AC_CHECK_LIB(rt,nanosleep,LTHREAD_LIBS="$LTHREAD_LIBS -lrt",
		[AC_CHECK_LIB(posix4,nanosleep,LIB="$LTHREAD_LIBS -lposix4")]
	)])

dnl AC_CHECK_DECL does not work for C++ & finctions
AC_LANG_C

dnl Now ensure we have a declaration.
dnl MacOS X and others ship with support but not the header.
AC_CHECK_DECL(nanosleep,,,[#include <time.h>])

dnl AC_CHECK_DECL does not work for C++ & finctions
AC_LANG_CPLUSPLUS

dnl We use timespecs - make sure we've got 'em.
dnl Won't work until 2.52.
dnl AC_CHECK_TYPES(struct timespec)

dnl Check to see if we have poll.  If not, we'll use the emulated poll.
AC_CHECK_HEADERS(sys/poll.h)


dnl Check to see if we got a poll impl from libpoll, and if so, add it.
AC_CHECK_LIB(poll,poll,
	[g_cv_libpoll=yes],[g_cv_libpoll=no])

if test $g_cv_libpoll = yes ; then
	LIBS="$LIBS -lpoll"
fi

dnl Check to see if we got a zlib.
AC_CHECK_LIB(z,compress,
	[LIBS="$LIBS -lz"],[AC_MSG_ERROR([You must have zlib installed!])])

dnl AC_CHECK_HEADERS(stdint.h)
dnl AC_CHECK_HEADERS(sys/inttypes.h)

AC_CHECK_HEADERS(pthread.h)
g_link_threads=no

if test $g_link_threads = no ; then
	dnl look for libpthread.so
	AC_CHECK_LIB(pthread,pthread_create,
		[g_cv_libpthread=yes],[g_cv_libpthread=no])

	if test $g_cv_libpthread = yes ; then
		LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"
		g_link_threads=posix
	fi
fi

if test $g_link_threads = no ; then
	dnl try -pthreads
	AC_CACHE_CHECK([for pthread_create with -pthreads],
		[g_cv_pthreads_flag], [
		dnl save the flags
		save_LIBS="$LIBS"
		LIBS="-pthreads $LIBS"
		AC_TRY_LINK([#include <pthread.h>],
			[pthread_create(NULL,NULL,NULL,NULL);],
			[g_cv_pthreads_flag=yes], [g_cv_pthreads_flag=no])
		dnl restore the libs
		LIBS="$save_LIBS"
	])

	if test $g_cv_pthreads_flag = yes ; then
		LTHREAD_LIBS="$LTHREAD_LIBS -pthreads"
		g_link_threads=posix
	fi
fi

if test $g_link_threads = no ; then
	dnl try -pthread in CFLAGS
	AC_CACHE_CHECK([for pthread_create with -pthread in CFLAGS],
		[g_cv_pthread_flag], [
		dnl save the flags
		save_LIBS="$LIBS"
		save_CFLAGS="$CFLAGS"
		LIBS="-pthread $LIBS"
		CFLAGS="-pthread $CFLAGS"
		AC_TRY_LINK([#include <pthread.h>],
			[pthread_create(NULL,NULL,NULL,NULL);],
			[g_cv_pthread_flag=yes], [g_cv_thread_flag=no])
		dnl restore flags
		LIBS="$save_LIBS"
		CFLAGS="$save_CFLAGS"
	])

	if test $g_cv_pthread_flag=yes ; then
		LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
		LTHREAD_CFLAGS="$LTHREAD_CFLAGS -pthread"
		g_link_threads=posix
	fi
fi

if test $g_link_threads = no ; then
	dnl try -pthread
	AC_CACHE_CHECK([for pthread_create with -pthread],
		[g_cv_pthread_flag], [
		dnl save the flags
		save_LIBS="$LIBS"
		LIBS="-pthread $LIBS"
		AC_TRY_LINK([#include <pthread.h>],
			[pthread_create(NULL,NULL,NULL,NULL);],
			[g_cv_pthread_flag=yes], [g_cv_thread_flag=no])
		dnl restore the libs
		LIBS="$save_LIBS"
	])

	if test $g_cv_pthread_flag=yes ; then
		LTHREAD_LIBS="$LTHREAD_LIBS -pthread"
		g_link_threads=posix
	fi
fi

if test $g_link_threads = no ; then
	dnl try -thread
	AC_CACHE_CHECK([for pthread_create with -thread],
		[g_cv_thread_flag], [
		dnl save the flags
		save_LIBS="$LIBS"
		LIBS="-thread $LIBS"
		AC_TRY_LINK([char pthread_create();],
			[pthread_create();]
			[g_cv_thread_flag=yes], [g_cv_thread_flag=no])
		dnl restore the libs
		LIBS="$save_LIBS"
	])

	if test $g_cv_thread_flag=yes ; then
		LTHREAD_LIBS="$LTHREAD_LIBS -thread"
		g_link_threads=posix
	fi
fi

if test $g_link_threads = no ; then
	dnl try -lpthread
	save_LIBS="$LIBS"
	AC_CHECK_LIB(pthread, pthread_create, [
		g_link_threads=posix
		LTHREAD_LIBS="$LTHREAD_LIBS -lpthread"],:)
	LIBS="$save_LIBS"
fi

if test $g_link_threads = no ; then
	AC_MSG_ERROR([You must have some sort of thread library!])
fi

AC_CHECK_HEADERS(errno.h)
AC_CHECK_HEADERS(termcap.h term.h termios.h ncurses.h curses.h)
AC_CHECK_FUNC(tcgetattr, AC_DEFINE(HAVE_TERMIOS_FUNCS))

AC_CHECK_HEADERS(readline/readline.h)
g_link_readline=no

dnl Checks for readline library.
AC_CACHE_CHECK([for readline in readline.h],
	[g_cv_readline],[
	save_LIBS="$LIBS"
	LIBS="-lreadline $LIBS"
	AC_TRY_LINK([
		#include <stdio.h>
		#include <readline/readline.h>
		],
		[readline(NULL);],
		[g_cv_readline=yes],[g_cv_readline=no])
	LIBS="$save_LIBS"
])

if test $g_cv_readline = yes ; then
	LIBS="-lreadline $LIBS"
	g_link_readline=yes
fi

if test $g_link_readline = no ; then
	AC_CACHE_CHECK([for readline in readline.h with curses],
		[g_cv_readline_w_curses],[
		save_LIBS="$LIBS"
		LIBS="-lreadline -lcurses $LIBS"
		AC_TRY_LINK([
			#include <stdio.h>
			#include <readline/readline.h>
			],
			[readline(NULL);],
			[g_cv_readline_w_curses=yes],[g_cv_readline_w_curses=no])
		LIBS="$save_LIBS"
	])

	if test $g_cv_readline_w_curses = yes ; then
		LIBS="-lreadline -lcurses $LIBS"
		g_link_readline=yes
	fi
fi

if test $g_link_readline = no ; then
	AC_CACHE_CHECK([for readline in readline.h with ncurses],
		[g_cv_readline_w_ncurses],[
		save_LIBS="$LIBS"
		LIBS="-lreadline -lncurses $LIBS"
		AC_TRY_LINK([
			#include <stdio.h>
			#include <readline/readline.h>
			],
			[readline(NULL);],
			[g_cv_readline_w_ncurses=yes],[g_cv_readline_w_ncurses=no])
		LIBS="$save_LIBS"
	])

	if test $g_cv_readline_w_ncurses = yes ; then
		LIBS="-lreadline -lncurses $LIBS"
		g_link_readline=yes
	fi
fi

if test $g_link_readline = no ; then
	AC_CACHE_CHECK([for readline in readline.h with termcap],
		[g_cv_readline_w_termcap],[
		save_LIBS="$LIBS"
		LIBS="-lreadline -ltermcap $LIBS"
		AC_TRY_LINK([
			#include <stdio.h>
			#include <readline/readline.h>
			],
			[readline(NULL);],
			[g_cv_readline_w_termcap=yes],[g_cv_readline_w_termcap=no])
		LIBS="$save_LIBS"
	])

	if test $g_cv_readline_w_termcap = yes ; then
		LIBS="-lreadline -ltermcap $LIBS"
		g_link_readline=yes
		echo "libs = $LIBS"
	fi
fi

if test $g_link_readline = no ; then
	AC_MSG_ERROR([You must have readline library!])
fi

dnl Now check to see if we've got the filename comploetion functions.
AC_CHECK_FUNC(rl_get_screen_size,[g_cv_readline_42=yes],[g_cv_readline_42=no])

if test $g_cv_readline_42 = yes ; then
	AC_DEFINE(HAVE_READLINE_42)
else
	AC_MSG_WARN([You must have, at minimum, readline 4.2 in order to have command completion!])
fi

dnl Check if we still need -ltermcap or -lcurses to link term_help.c

m_cv_term_help_c_links=no
for m_add_lib in empty ncurses curses termcap
do
	if test $m_cv_term_help_c_links = no ; then
		AC_MSG_CHECKING("if term_help.c links with $m_add_lib")
			save_LIBS="$LIBS"
			if test $m_add_lib != empty ; then
				LIBS="-l$m_add_lib $LIBS"
			fi
			if test $ac_cv_header_termcap_h = no ; then
				if test $ac_cv_header_ncurses_h = yes ; then
					AC_TRY_LINK([
						#include <ncurses.h>
						#include <term.h>
						],
						[tigetnum("lines");],
						[m_cv_term_help_c_links=yes],[m_cv_term_help_c_links=no])
				else
					if test $ac_cv_header_curses_h = yes ; then
						AC_TRY_LINK([
						#include <curses.h>
						#include <term.h>
						],
						[tigetnum("lines");],
						[m_cv_term_help_c_links=yes],[m_cv_term_help_c_links=no])
					fi
				fi
			else
				AC_TRY_LINK([
				#include <termcap.h>
				],
				[tgetnum("li");],
				[m_cv_term_help_c_links=yes],[m_cv_term_help_c_links=no])
			fi
			LIBS="$save_LIBS"
			if test $m_cv_term_help_c_links = yes ; then
				m_cv_term_help_c_links_with=$m_add_lib
			else
				m_cv_term_help_c_links_with=no
			fi
		AC_MSG_RESULT("$m_cv_term_help_c_links")
		if test $m_cv_term_help_c_links_with != no ; then
			m_cv_term_help_c_links=yes
		fi
	fi
done

case $m_cv_term_help_c_links_with in
	no) AC_MSG_WARN("term_help.c might not link! You mignt need to edit term_help.c as described in the begining of the file") ;;
	empty) ;;
	ncurses | curses | termcap) LIBS="-l$m_cv_term_help_c_links_with $LIBS"
esac

g_have_socket=no
dnl Checks for inet-related stuff.
AC_CACHE_CHECK([for socket in libc],
	[g_cv_socket],[
	AC_TRY_LINK([
		#include <sys/types.h>
		#include <sys/socket.h>
		],
		[socket(AF_INET,SOCK_STREAM,0);],
		[g_cv_socket=yes],[g_cv_socket=no])
])
if test $g_cv_socket = yes ; then
	g_have_socket=yes
fi

dnl Checks for inet-related stuff with -lxnet.
if test $g_have_socket = no ; then
	AC_CACHE_CHECK([for socket in xnet],
		[g_cv_socket_w_xnet],[
		save_LIBS="$LIBS"
		LIBS="-lxnet $LIBS"
		AC_TRY_LINK([
			#include <sys/types.h>
			#include <sys/socket.h>
			],
			[socket(AF_INET,SOCK_STREAM,0);],
			[g_cv_socket_w_xnet=yes],[g_cv_socket_w_xnet=no])
		LIBS="$save_LIBS"
	])
	if test $g_cv_socket_w_xnet = yes ; then
		LIBS="-lxnet $LIBS"
		g_have_socket=yes
		echo "libs = $LIBS"
	fi	
fi

if test $g_have_socket = no ; then
	AC_MSG_ERROR([We cannot live without socket() function!])
fi

dnl AC_CHECK_TYPE(socklen_t,int)
dnl AC_CHECK_TYPE(TYPE, DEFAULT)
AC_MSG_CHECKING(for socklen_t)
AC_CACHE_VAL(ac_cv_type_socklen_t,
[AC_EGREP_CPP(dnl
changequote(<<,>>)dnl
<<(^|[^a-zA-Z_0-9])socklen_t[^a-zA-Z_0-9]>>dnl
changequote([,]), [#include <sys/types.h>
#include <sys/socket.h>], ac_cv_type_socklen_t=yes, ac_cv_type_socklen_t=no)])dnl
AC_MSG_RESULT($ac_cv_type_socklen_t)
if test $ac_cv_type_socklen_t = no; then
  AC_DEFINE(socklen_t, int)
fi

dnl AC_LANG_SAVE
AC_LANG_CPLUSPLUS
AC_MSG_CHECKING([for va_copy])
AC_TRY_LINK([
#include <stdarg.h>
],[
va_list v1,v2;
va_copy(v1, v2);
], [AC_MSG_RESULT(yes)
AC_DEFINE(VA_COPY,va_copy)],[AC_MSG_RESULT(no)
AC_MSG_CHECKING([for __va_copy])
AC_TRY_LINK([
#include <stdarg.h>
],[
va_list v1,v2;
__va_copy(v1, v2);
], [AC_MSG_RESULT(yes)
AC_DEFINE(VA_COPY,__va_copy)],[AC_MSG_RESULT(no)])])
dnl AC_LANG_RESTORE not supported...
AC_LANG_C

LIBS="$LTHREAD_LIBS $LIBS"
CFLAGS="-D_REENTRANT -D_MIT_POSIX_THREADS $LTHREAD_CFLAGS $CFLAGS"
dnl CygWin has problem with exception-enabled multithreaded C++ apps
dnl new operator seem to have pronlems with CygWin as well...
CPPFLAGS="-D_REENTRANT -D_MIT_POSIX_THREADS -fno-exceptions -fno-check-new $LTHREAD_CFLAGS $CPPFLAGS"

dnl pthread subfunction availability check.
AC_CHECK_FUNCS(pthread_condattr_init pthread_condattr_destroy)

dnl Optimisation flag support.
dnl Mutella seem to crash once in several days when compiled with -O2
dnl first get rid of any -On flags
CFLAGS=`echo $CFLAGS | sed 's/-O[[0-9]]//g'`
CXXFLAGS=`echo $CXXFLAGS | sed 's/-O[[0-9]]//g'`
AC_ARG_ENABLE(optimisation,
[  --enable-optimisation	Turn on compiler optimisation [default=no]],
[case "${enableval}" in
  yes) optimisation=true
	;;
  no)  optimisation=false
	;;
  *) AC_MSG_ERROR(bad value ${enableval} for --enable-optimisation) ;;
esac],[optimisation=false])
if test $optimisation = true; then
	CFLAGS="$CFLAGS -O2"
	CXXFLAGS="$CXXFLAGS -O2"
else
	CFLAGS="$CFLAGS -O0"
	CXXFLAGS="$CXXFLAGS -O0"
fi

dnl Debug flag support.
AC_ARG_ENABLE(debug,
[  --enable-debug	Turn on debugging [default=no]],
[case "${enableval}" in
  yes)  debug=true
	if test $ac_cv_prog_cc_g = yes; then
		CFLAGS="$CFLAGS -g3 -Wall"
		dnl should really (MZ: really what?)
	fi
	if test $ac_cv_prog_cxx_g = yes; then
		CXXFLAGS="$CXXFLAGS -g3 -Wall"
	fi
	AC_DEFINE(_DEBUG) ;;
  no)  debug=false ;;
  *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug) ;;
esac],[debug=false])

dnl Range checking support.
AC_ARG_ENABLE(range-check,
[  --enable-range-check	Turn on range checking [default=no]],
[case "${enableval}" in
  yes)  range_check=true
	AC_DEFINE(CHECK_RANGE) ;;
  no)   range_check=false ;;
  *)    AC_MSG_ERROR(bad value ${enableval} for --enable-range-check) ;;
esac],[range_check=false])

dnl Hopefully fix the Solaris crashes.
AC_ARG_ENABLE(sol-threads,
[  --enable-sol-threads	Makes STL aware of Solaris threads [default=no]],
[case "${enableval}" in
  yes)  sol_threads=true
	CXXFLAGS="-threads $CXXFLAGS"
	CFLAGS="-threads $CFLAGS"
	AC_DEFINE(__STL_SOLTHREADS) ;;
  no)   sol_threads=false ;;
  *)    AC_MSG_ERROR(bad value ${enableval} for --enable-sol-threads) ;;
esac],[sol_threads=false])

AC_ARG_ENABLE(use-malloc,
[  --enable-use-malloc	Makes STL to use standard memory allocation routines [default=no]],
[case "${enableval}" in
  yes)  use_malloc=true
	AC_DEFINE(__USE_MALLOC) ;;
  no)   use_malloc=false ;;
  *)    AC_MSG_ERROR(bad value ${enableval} for --enable-sol-threads) ;;
esac],[use_malloc=false])

dnl make installation paths available for the program
eval INSTALL_PREFIX="${prefix}"
eval INSTALL_DATADIR="${datadir}"

AC_DEFINE_UNQUOTED(INSTALL_PREFIX, "$INSTALL_PREFIX", [install prefix])
AC_DEFINE_UNQUOTED(INSTALL_DATA_DIR,"$INSTALL_DATADIR", [install path for shared files])

dnl add here all your Makefiles. These will be created by configure
AC_OUTPUT(Makefile mutella/Makefile mutella/docs/Makefile mutella/docs/en/Makefile share/Makefile share/remote/Makefile share/remote/template/Makefile share/remote/template/modules/Makefile share/remote/template/images/Makefile man1/Makefile util/Makefile )