File: setup.pro

package info (click to toggle)
myodbc 3.51.11-6.1
  • links: PTS
  • area: main
  • in suites: etch, etch-m68k
  • size: 5,056 kB
  • ctags: 1,933
  • sloc: ansic: 31,656; sh: 10,955; cpp: 2,439; makefile: 1,120
file content (118 lines) | stat: -rw-r--r-- 3,991 bytes parent folder | download
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
# #########################################################
#
# NAME:
#       setup.pro
#
# PURPOSE:
#       Use qt qmake on this to make the Makefile.
#
# DESCRIPTION:
#       This setup code is based upon the Qt class library
#       where the usual way to build code is to use the
#       Qt qmake tool to create a Makefile from a project
#       (this file).
#
# NOTES:
#       On UNIX, Linux and OSX your preference should be
#       to use the GNU auto-build but this will do as an 
#       alternative.
#
#	We need to build as a 'plugin' and not just a 'dll'
#	because on OSX plugins are special share libraries
#	called 'bundles' which can be explicitly loaded.
#
#	The target directory is hard-coded but could be 
#	done using an environment variable substitution
#	- or one could just edit this file. The hard coding
#	has been done just to save some time (for me).
#
# #########################################################

# #########################################################
# COMMON
# #########################################################
TEMPLATE                = lib
TARGET                  = myodbc3S
DESTDIR                 = ./
!win32:VERSION		= 3.51.11
UI_DIR                  = .tmp
MOC_DIR                 = .tmp
OBJECTS_DIR             = .tmp
LANGUAGE                = C++
CPP_ALWAYS_CREATE_SOURCE = TRUE
CONFIG                  += plugin qt thread warn_on release

# #########################################################
# WIN
# #########################################################
win32:DEFINES           -= UNICODE
win32:DEFINES           += WIN32 HAVE_SQLGETPRIVATEPROFILESTRING HAVE_ODBCINST_H
win32:LIBS              += ../util/myodbcutil.lib odbc32.lib odbccp32.lib
win32:DEF_FILE          = myodbc3S.def
win32:RC_FILE           = myodbc3S.rc
win32:libraries.path	= /windows/system32
win32:libraries.files	= myodbc3S.dll

# #########################################################
# UNIX
#       Your preference should be to use the GNU auto-build
#       on unix - but this will do as alternative.
# #########################################################
unix:DEFINES		+= HAVE_CONFIG_H
unix:INCLUDEPATH	+= /usr/include
unix:LIBS               += -L../util/.libs -lmyodbcutil  -L/usr/lib -lodbc -lodbcinst
unix:libraries.path	= /usr/lib
unix:libraries.files	= libmyodbc*

# #########################################################
# OSX
#       Your preference should be to use the GNU auto-build
#       on OSX - but this will do as alternative.
# #########################################################
# mac:CONFIG		-= thread
mac:LIBS		-= -lodbc -lodbcinst
mac:LIBS		+= -liodbc -liodbcinst
mac:libraries.path     = /usr/lib
mac:libraries.files    = libmyodbc3S.dylib

INSTALLS		+= libraries

# #########################################################
# FILES
# #########################################################
HEADERS			= \
			MYODBCSetupCheckBox.h \
			MYODBCSetupComboBox.h \
			MYODBCSetupComboBoxDatabases.h \
			MYODBCSetup.h \
			MYODBCSetupDataSourceDialog.h \
			MYODBCSetupDataSourceTab1.h \
			MYODBCSetupDataSourceTab2.h \
			MYODBCSetupDataSourceTab3.h \
			MYODBCSetupDataSourceTab3a.h \
			MYODBCSetupDataSourceTab3b.h \
			MYODBCSetupDataSourceTab3c.h \
			MYODBCSetupDataSourceTab3d.h \
			MYODBCSetupLineEdit.h
SOURCES			= \
			ConfigDSN.c \
			MYODBCSetupCheckBox.cpp \
			MYODBCSetupComboBox.cpp \
			MYODBCSetupComboBoxDatabases.cpp \
			MYODBCSetupConfigDSNAdd.c \
			MYODBCSetupConfigDSNEdit.c \
			MYODBCSetupConfigDSNRemove.c \
			MYODBCSetupDataSourceConfig.cpp \
			MYODBCSetupDataSourceDialog.cpp \
			MYODBCSetupDataSourceTab1.cpp \
			MYODBCSetupDataSourceTab2.cpp \
			MYODBCSetupDataSourceTab3.cpp \
			MYODBCSetupDataSourceTab3a.cpp \
			MYODBCSetupDataSourceTab3b.cpp \
			MYODBCSetupDataSourceTab3c.cpp \
			MYODBCSetupDataSourceTab3d.cpp \
			MYODBCSetupDriverConnect.c \
			MYODBCSetupDriverConnectPrompt.cpp \
			MYODBCSetupHandleInstallerError.c \
			MYODBCSetupLineEdit.cpp