1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
|
{*****************************************************************************}
{ }
{ Tnt Delphi Unicode Controls }
{ http://tnt.ccci.org/delphi_unicode_controls/ }
{ Version: 2.1.11 }
{ }
{ Copyright (c) 2002-2004, Troy Wolbrink (troy.wolbrink@ccci.org) }
{ }
{*****************************************************************************}
unit TntComCtrls_Design;
{$INCLUDE ..\TntCompilers.inc}
interface
uses
{$IFDEF COMPILER_6_UP} DesignIntf, DesignMenus, DesignEditors, {$ELSE} DsgnIntf, Menus, {$ENDIF}
Classes, ComCtrls;
type
{$IFDEF COMPILER_6_UP}
IPrepareMenuItem = IMenuItem;
{$ELSE}
IPrepareMenuItem = TMenuItem{TNT-ALLOW TMenuItem};
{$ENDIF}
TTntListViewEditor = class(TComponentEditor)
public
procedure ExecuteVerb(Index: Integer); override;
function GetVerb(Index: Integer): string{TNT-ALLOW string}; override;
function GetVerbCount: Integer; override;
end;
TTntPageControlEditor = class(TDefaultEditor)
private
function PageControl: TPageControl{TNT-ALLOW TPageControl};
public
procedure ExecuteVerb(Index: Integer); override;
function GetVerb(Index: Integer): string{TNT-ALLOW string}; override;
function GetVerbCount: Integer; override;
procedure PrepareItem(Index: Integer; const AItem: IPrepareMenuItem); override;
end;
TTntStatusBarEditor = class(TComponentEditor)
public
procedure ExecuteVerb(Index: Integer); override;
function GetVerb(Index: Integer): string{TNT-ALLOW string}; override;
function GetVerbCount: Integer; override;
end;
procedure Register;
implementation
uses
{$IFDEF COMPILER_6_UP} DsnConst, {$ENDIF} TntComCtrls, TntDesignEditors_Design;
procedure Register;
begin
RegisterComponentEditor(TTntListView, TTntListViewEditor);
RegisterComponentEditor(TTntPageControl, TTntPageControlEditor);
RegisterComponentEditor(TTntTabSheet, TTntPageControlEditor);
RegisterComponentEditor(TTntStatusBar, TTntStatusBarEditor);
end;
{$IFNDEF COMPILER_6_UP} // Delphi 5 compatibility
resourcestring
SListColumnsEditor = 'Columns Editor...';
SListItemsEditor = 'Items Editor...';
SNewPage = 'New Page';
SNextPage = 'Next Page';
SPrevPage = 'Previous Page';
SDeletePage = 'Delete Page';
SStatusBarPanelEdit = 'Panels Editor...';
{$ENDIF}
{ TTntListViewEditor }
function TTntListViewEditor.GetVerbCount: Integer;
begin
Result := 2;
end;
function TTntListViewEditor.GetVerb(Index: Integer): string{TNT-ALLOW string};
begin
case Index of
0: Result := SListColumnsEditor;
1: Result := SListItemsEditor;
end;
end;
procedure TTntListViewEditor.ExecuteVerb(Index: Integer);
begin
case Index of
0: EditPropertyWithDialog(Component, 'Columns', Designer);
1: EditPropertyWithDialog(Component, 'Items', Designer);
end;
end;
{ TTntPageControlEditor }
function TTntPageControlEditor.PageControl: TPageControl{TNT-ALLOW TPageControl};
begin
if Component is TTabSheet{TNT-ALLOW TTabSheet} then
Result := TTabSheet{TNT-ALLOW TTabSheet}(Component).PageControl
else
Result := Component as TPageControl{TNT-ALLOW TPageControl};
end;
function TTntPageControlEditor.GetVerbCount: Integer;
begin
Result := 4;
end;
function TTntPageControlEditor.GetVerb(Index: Integer): string{TNT-ALLOW string};
begin
case Index of
0: Result := SNewPage;
1: Result := SNextPage;
2: Result := SPrevPage;
3: Result := SDeletePage;
end;
end;
procedure TTntPageControlEditor.PrepareItem(Index: Integer; const AItem: IPrepareMenuItem);
begin
AItem.Enabled := (Index <> 3) or (PageControl.PageCount > 0);
end;
type TAccessPageControl = class(TPageControl{TNT-ALLOW TPageControl});
procedure TTntPageControlEditor.ExecuteVerb(Index: Integer);
procedure CreateNewTabSheet;
var
NewTabsheet: TTntTabSheet;
begin
NewTabSheet := TTntTabSheet.Create(PageControl.Owner);
NewTabSheet.PageControl := Self.PageControl;
with NewTabSheet do begin
Name := Designer.UniqueName(ClassName);
Caption := Name;
Visible := True;
end;
PageControl.ActivePage := NewTabSheet;
end;
procedure SelectNextPage(GoForward: Boolean);
{$IFDEF COMPILER_6_UP}
begin
PageControl.SelectNextPage(GoForward, False);
{$ELSE}
var
Page: TTabSheet{TNT-ALLOW TTabSheet};
begin
with TAccessPageControl(PageControl) do begin
Page := FindNextPage(ActivePage, GoForward, False);
if (Page <> nil) and (Page <> ActivePage) and CanChange then
begin
ActivePage := Page;
Change;
end;
end;
{$ENDIF}
end;
begin
case Index of
0: CreateNewTabSheet;
1: SelectNextPage(True);
2: SelectNextPage(False);
3: if PageControl.ActivePage <> nil then
PageControl.ActivePage.Free;
end;
end;
{ TTntStatusBarEditor }
function TTntStatusBarEditor.GetVerbCount: Integer;
begin
Result := 1;
end;
function TTntStatusBarEditor.GetVerb(Index: Integer): string{TNT-ALLOW string};
begin
case Index of
0: Result := SStatusBarPanelEdit;
end;
end;
procedure TTntStatusBarEditor.ExecuteVerb(Index: Integer);
begin
case Index of
0: EditPropertyWithDialog(Component, 'Panels', Designer);
end;
end;
end.
|
