File: type_socklen_t.m4

package info (click to toggle)
nc6 1.0-1
  • links: PTS
  • area: main
  • in suites: etch, etch-m68k
  • size: 2,108 kB
  • ctags: 1,581
  • sloc: ansic: 12,966; sh: 6,695; makefile: 541; yacc: 288; sed: 16
file content (46 lines) | stat: -rw-r--r-- 1,494 bytes parent folder | download | duplicates (4)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
dnl Check for socklen_t: historically on BSD it is an int, and in
dnl POSIX 1g it is a type of its own, but some platforms use different
dnl types for the argument to getsockopt, getpeername, etc.  So we
dnl have to test to find something that will work.

dnl This is no good, because passing the wrong pointer on C compilers is
dnl likely to only generate a warning, not an error.  We don't call this at
dnl the moment.

AC_DEFUN([TYPE_SOCKLEN_T],
[
  AC_CHECK_TYPE([socklen_t], ,[
    AC_MSG_CHECKING([for socklen_t equivalent])
    AC_CACHE_VAL([rsync_cv_type_socklen_t_equiv],[
      # Systems have either "struct sockaddr *" or
      # "void *" as the second argument to getpeername
      rsync_cv_type_socklen_t_equiv=
      for arg2 in "struct sockaddr" void; do
        for t in int size_t unsigned long "unsigned long"; do
          AC_TRY_COMPILE([
#include <sys/types.h>
#include <sys/socket.h>

int getpeername (int, $arg2 *, $t *);
          ],[
$t len;
getpeername(0,0,&len);
          ],[
            rsync_cv_type_socklen_t_equiv="$t"
            break
          ])
        done
      done

      if test "x$rsync_cv_type_socklen_t_equiv" = x; then
        AC_MSG_ERROR([Cannot find a type to use in place of socklen_t])
      fi
    ])
    AC_MSG_RESULT($rsync_cv_type_socklen_t_equiv)
    AC_DEFINE_UNQUOTED(socklen_t, $rsync_cv_type_socklen_t_equiv,
            [type to use in place of socklen_t if not defined])
  ],[
#include <sys/types.h>
#include <sys/socket.h>
  ])
])