1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
! This is part of the netCDF package.
! Copyright 2006 University Corporation for Atmospheric Research/Unidata.
! See COPYRIGHT file for conditions of use.
! This is a simple example which reads a small dummy array, from a
! netCDF data file created by the companion program simple_xy_wr.f90.
! This program is part of the netCDF tutorial:
! http://www.unidata.ucar.edu/software/netcdf/docs/tutorial_8dox.html
! Full documentation of the netCDF Fortran 90 API can be found at:
! http://www.unidata.ucar.edu/software/netcdf/docs-fortran/f90_The-NetCDF-Fortran-90-Interface-Guide.html
! Ed Hartnett
program simple_xy_rd
use netcdf
implicit none
! This is the name of the data file we will read.
character (len = *), parameter :: FILE_NAME = "simple_xy.nc"
! We are reading 2D data, a 12 x 6 grid.
integer, parameter :: NX = 6, NY = 12
integer, dimension(:,:), allocatable :: data_in
! This will be the netCDF ID for the file and data variable.
integer :: ncid, varid
! Loop indexes, and error handling.
integer :: x, y
! Allocate memory for data.
allocate(data_in(NY, NX))
! Open the file. NF90_NOWRITE tells netCDF we want read-only access to
! the file.
call check( nf90_open(FILE_NAME, NF90_NOWRITE, ncid) )
! Get the varid of the data variable, based on its name.
call check( nf90_inq_varid(ncid, "data", varid) )
! Read the data.
call check( nf90_get_var(ncid, varid, data_in) )
! Check the data.
do x = 1, NX
do y = 1, NY
if (data_in(y, x) /= (x - 1) * NY + (y - 1)) then
print *, "data_in(", y, ", ", x, ") = ", data_in(y, x)
stop "Stopped"
end if
end do
end do
! Close the file, freeing all resources.
call check( nf90_close(ncid) )
print *,"*** SUCCESS reading example file ", FILE_NAME, "! "
contains
subroutine check(status)
integer, intent ( in) :: status
if(status /= nf90_noerr) then
print *, trim(nf90_strerror(status))
stop 2
end if
end subroutine check
end program simple_xy_rd
|
