1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
|
COMMENT
Copy of modeldb 151458 (Nakano et al. 2013) damsg.mod
Using to test net_move for nrn<->coreneuron.
Count number of net_move and net_send
ENDCOMMENT
COMMENT
Simple model of synaptic modulation of a second messenger "msg" by dopamine.
msg approaches its steady state msginf with a single time constant tau.
Initially msg has value msginf = 1, and tau is tau0
(default is 100 ms).
If an input event with positive weight w arrives at time t
If msginf == 1
msginf = 1+w
tau = tau1
send a self-event that will return at t+dur
else
move the self-event to t+dur (i.e. just prolong "on" phase)
If a self-event arrives
msginf = 1
tau = tau0
An input event with negative weight has no effect.
Affects other mechanisms via POINTER variables linked to msg.
This model has simple dynamics and no stream-specificity.
ENDCOMMENT
NEURON {
POINT_PROCESS DAsyn
RANGE tau, tau0, tau1, dur, msg, msginf, spkcnt, ip3i
RANGE n_netmove, n_netsend
}
PARAMETER {
tau0 = 100 (ms)
tau1 = 30 (ms)
dur = 60:600 (ms)
}
ASSIGNED {
tau (ms)
msginf (1)
n_netmove (1)
n_netsend (1)
spkcnt
ip3i (mM)
}
STATE {
msg (1)
}
INITIAL {
tau = tau0
msginf = 1
msg = 1
spkcnt=0
ip3i =0
n_netmove = 0
n_netsend = 0
}
BREAKPOINT {
SOLVE state METHOD cnexp
}
DERIVATIVE state {
msg' = (msginf - msg)/tau
}
NET_RECEIVE (w(1)) {
if (flag == 0) { : this is an input event
if (w>0) { : ignore events with nonpositive weight
if (msginf==1) {
msginf = 1 + w
tau = tau1
net_send(dur, 1)
n_netsend = n_netsend + 1
} else {
net_move(t + dur)
n_netmove = n_netmove + 1
}
}
} else { : this is a self-event
msginf = 1
tau = tau0
}
spkcnt = spkcnt +1
}
|
