1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
dnl Checks for TI-RPC library and headers
dnl
AC_DEFUN([AC_LIBTIRPC], [
PKG_PROG_PKG_CONFIG([0.9.0])
AS_IF(
[test "$enable_tirpc" != "no"],
[PKG_CHECK_MODULES([TIRPC], [libtirpc],
[LIBTIRPC="${TIRPC_LIBS}"
AM_CPPFLAGS="${AM_CPPFLAGS} ${TIRPC_CFLAGS}"
AC_DEFINE([HAVE_LIBTIRPC], [1],
[Define to 1 if you have and wish to use libtirpc.])],
[AC_LIBTIRPC_OLD
AS_IF([test "$enable_tirpc" = "yes" -a -z "${LIBTIRPC}"],
[AC_MSG_ERROR([libtirpc not found.])])])])
AS_IF([test -n "${LIBTIRPC}"],
[AC_CHECK_LIB([tirpc], [authgss_free_private_data],
[AC_DEFINE([HAVE_AUTHGSS_FREE_PRIVATE_DATA], [1],
[Define to 1 if your rpcsec library provides authgss_free_private_data])],,
[${LIBS}])])
AS_IF([test -n "${LIBTIRPC}"],
[AC_CHECK_LIB([tirpc], [libtirpc_set_debug],
[AC_DEFINE([HAVE_LIBTIRPC_SET_DEBUG], [1],
[Define to 1 if your tirpc library provides libtirpc_set_debug])],,
[${LIBS}])])
AS_IF([test -n "${LIBTIRPC}"],
[AC_CHECK_LIB([tirpc], [rpc_gss_seccreate],
[AC_DEFINE([HAVE_TIRPC_GSS_SECCREATE], [1],
[Define to 1 if your tirpc library provides rpc_gss_seccreate])],,
[${LIBS}])])
AC_SUBST([AM_CPPFLAGS])
AC_SUBST(LIBTIRPC)
])dnl
dnl Old way of checking libtirpc without pkg-config
dnl This can go away when virtually all libtirpc provide a .pc file
dnl
AC_DEFUN([AC_LIBTIRPC_OLD], [
AC_ARG_WITH([tirpcinclude],
[AS_HELP_STRING([--with-tirpcinclude=DIR],[use TI-RPC headers in DIR])],
[tirpc_header_dir=$withval],
[tirpc_header_dir=/usr/include/tirpc])
dnl Look for the library
AC_CHECK_LIB([tirpc], [clnt_tli_create],
[has_libtirpc="yes"],
[has_libtirpc="no"])
dnl Also must have the headers installed where we expect
dnl to look for headers; add -I compiler option if found
AS_IF([test "$has_libtirpc" = "yes"],
[AC_CHECK_FILE([${tirpc_header_dir}/netconfig.h],
[AC_SUBST([AM_CPPFLAGS], ["-I${tirpc_header_dir}"])],
[has_libtirpc="no"])])
dnl Now set $LIBTIRPC accordingly
AS_IF([test "$has_libtirpc" = "yes"],
[AC_DEFINE([HAVE_LIBTIRPC], [1],
[Define to 1 if you have and wish to use libtirpc.])
LIBTIRPC="-ltirpc"])
])dnl
|
