1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
|
#!/usr/bin/mawk -We
# *********************************************************************
# Written by and copyright Carlo Strozzi <carlos@linux.it>.
#
# compute: applies arbitrary AWK expressions to table data, using
# column names.
# Copyright (C) 2000-2001 Carlo Strozzi <carlos@linux.it>
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
#
# 2001-01-03 Ported to NoSQL v3
# 2001-02-02 Fixed a bug in parser()
# 2001-04-17 Added inline help
# 2001-08-17 Added stdio portability
#
# $Id$
# *********************************************************************
BEGIN {
NULL = ""; FS = OFS = "\t"; srand()
while (ARGV[++i] != NULL) {
if (ARGV[i] == "-x" || ARGV[i] == "--debug") debug = 1
else if (ARGV[i] == "-N" || ARGV[i] == "--no-header") no_hdr = 1
else if (ARGV[i] == "-i" || ARGV[i] == "--input") i_file = ARGV[++i]
else if (ARGV[i] == "-o" || ARGV[i] == "--output") o_file = ARGV[++i]
else if (ARGV[i] == "-h" || ARGV[i] == "--help") {
system("grep -v '^#' @DOCPATH@/compute.txt")
rc = 1
exit(rc)
}
else awk_program = awk_program " " ARGV[i]
}
if (awk_program == NULL) exit
ARGC = 1 # Fix argv[]
if (o_file == NULL) o_file = "@STDOUT@"
if (i_file != NULL) { ARGV[1] = i_file; ARGC = 2 }
}
# Table header
r == 0 {
# Start building the back-end awk program.
awkpgm = "'BEGIN{FS=OFS=\"\\t\";}{"
# Do not let duplicated input columns fool us.
for (col = 1; col <= NF; col++) {
if (col_names[$(col)] == NULL) {
col_names[$(col)] = $(col)
awk_col[$(col)] = "$(" col ")"
}
}
awkpgm = awkpgm parser(awk_program) " } {print}'"
unix_cmd = "mawk " awkpgm
# Print header.
if (!no_hdr) {
print > o_file ; gsub(/[^\t]/, "-"); print > o_file
# Make sure we print the header before calling mawk(1) again.
fflush()
# Close output file before the back-end mawk(1) appends to it.
if (o_file != "@STDOUT@") close(o_file)
}
r++ ; next
}
# Dashline.
r == 1 {
# Let's save one concurrent process and a couple of msec.
unix_cmd = "exec " unix_cmd
if (o_file != "@STDOUT@") unix_cmd = unix_cmd " >> " o_file
if (debug) {
print "\n" awk_program "\n" unix_cmd "\n" > "@STDERR@"
}
r++ ; next
}
# Table body.
{ print | unix_cmd }
END {
if (rc) exit(rc)
exit(close(unix_cmd)) # Return back-end mawk(1) exit status.
}
#
# Function section.
#
function parser(in_pgm, i, var_name, col_pos, p_length, \
a, quoted, escaped, slashed, \
tilde, out_pgm) {
p_length = split(in_pgm, a, "")
# The next statement is necessary, to make sure the last section
# of the parser is entered once even after the end of the input AWK
# program.
p_length++
while (++i <= p_length) {
# Do not remove the next two lines of code. They can be *very*
# useful to debug the parser. Simply comment them out when
# not in use.
#
# "q:" stands for "quoted", "e:" for "escaped, etc.
#
#print "q:" quoted " e:" escaped " t:" tilde " s:" slashed \
# " a:" a[i] > "@STDERR@"
# The "/" character triggers regexp matching only after "~",
# otherwise it stands for the divide operator.
if (a[i] == "~" && !escaped && !quoted && !slashed) tilde = 1
if (a[i] == "\\" && !escaped) {
escaped = 1; out_pgm = out_pgm a[i] ; continue
}
if (a[i] == "/" && !escaped && !quoted && tilde) {
if (slashed) tilde = slashed = 0
else slashed = 1
}
if (a[i] == "\"" && !escaped && !slashed) {
quoted ? quoted = 0 : quoted = 1
}
escaped = 0
if (quoted || slashed) { out_pgm = out_pgm a[i] ; continue }
if (a[i] ~ /[A-Za-z_]/) { var_name = var_name a[i] ; continue }
if (var_name != NULL) {
if (a[i] ~ /[0-9]/) { var_name = var_name a[i] ; continue }
col_pos = awk_col[var_name]
if (col_pos != NULL) { out_pgm = out_pgm col_pos }
else out_pgm = out_pgm var_name
var_name = NULL
}
out_pgm = out_pgm a[i]
}
gsub(/'/, "\\047", out_pgm) # Escape single quotes for sh(1).
return out_pgm
}
#
# End of program.
#
|
