1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
|
#!/usr/bin/mawk -We
# *********************************************************************
# Written by and copyright Carlo Strozzi <carlos@linux.it>.
#
# istable: checks that a file is a valid NoSQL table.
# Copyright (C) 1998-2001 Carlo Strozzi <carlos@linux.it>
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
#
# 2001-01-03 Ported to NoSQL v3
# 2001-01-15 Fixed a typo in an error message
# 2001-03-09 Added option '-E'
# 2001-04-17 Added inline help
# 2001-08-17 Added stdio portability
#
# $Id$
# *********************************************************************
BEGIN {
NULL = ""; FS = OFS = "\t"
while (ARGV[++i] != NULL) {
if (ARGV[i] == "-v" || ARGV[i] == "--verbose") verbose = 1
else if (ARGV[i] == "-n" || ARGV[i] == "--skip-header") skip_hdr = 1
else if (ARGV[i] == "-e" || ARGV[i] == "--echo") gEcho = 1
else if (ARGV[i] == "-E" || ARGV[i] == "--edit") edit = 1
else if (ARGV[i] == "-N" || ARGV[i] == "--no-header") gMinRec = 2
else if (ARGV[i] == "-i" || ARGV[i] == "--input") sIfile = ARGV[++i]
else if (ARGV[i] == "-h" || ARGV[i] == "--help") {
system("grep -v '^#' @DOCPATH@/istable.txt")
rc = 1
exit(rc)
}
}
ARGC = 1 # Fix argv[]
if (sIfile != NULL) { ARGV[1] = sIfile; ARGC = 2 }
}
#
# Main loop
#
gEcho && NR > gMinRec { print }
# Column names.
NR == 1 {
num_cols = NF
# Check the column name line.
if (!/^[A-Za-z0-9\t_ ]+$/) {
if (verbose)
print "istable: invalid characters in column names" > "@STDERR@"
errors = 1
exit 1
}
# Check individual column names.
for (i = 1; i <= NF; i++) {
if ($i !~ /^[A-Za-z]/) {
if (verbose)
print "istable: invalid column name '" $i "'" > "@STDERR@"
errors = 1
exit 1
}
}
}
# Dashline.
NR == 2 {
if (NF != num_cols) {
if (verbose)
print "istable: dashes do not match column names" > "@STDERR@"
errors = 1
exit 1
}
if (!/^[-\t]+$/) {
if (verbose)
print "istable: dashline is missing" > "@STDERR@"
errors = 1
exit 1
}
}
NR > 2 {
# Empty rows in a one-column table are ok.
if (/^$/ && num_cols == 1) next
if (NF != num_cols) {
if (verbose) {
if (skip_hdr) nr = NR - 2
else nr = NR
print "istable: bad No. of fields at line " nr > "@STDERR@"
}
errors = 1
exit 1
}
}
END {
if (rc) exit(rc)
if (NR < 2) { errors = 1; badrow = NR }
if (verbose) {
if (errors) {
print "istable: table not ok" > "@STDERR@"
if (edit) print "istable: " NR
} else print "istable: table ok" > "@STDERR@"
}
if (errors) exit 1
}
#
# End of program.
#
|
