1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
|
#!/usr/bin/mawk -We
# *********************************************************************
# Written by and copyright Carlo Strozzi <carlos@linux.it>.
#
# listtotable: converts from a properly-formatted list into a
# NoSQL table.
# Copyright (C) 1998-2001 Carlo Strozzi <carlos@linux.it>
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
#
# 2001-01-03 Ported to NoSQL v3
# 2001-04-17 Added inline help
# 2001-08-17 Added stdio portability
# 2001-09-04 Added option '-p'
# 2001-09-09 Option '-p' changed into '-s'
#
# $Id$
# *********************************************************************
BEGIN {
NULL = ""; OFS = "\t";
while(ARGV[++i] != NULL) {
if (ARGV[i] == "-n" || ARGV[i] == "--no-chomp") nochomp = 1
else if (ARGV[i] == "-t" || ARGV[i] == "--trim") trim = 1
else if (ARGV[i] == "-i" || ARGV[i] == "--input") i_file = ARGV[++i]
else if (ARGV[i] == "-o" || ARGV[i] == "--output") o_file = ARGV[++i]
else if (ARGV[i] == "-s" || ARGV[i] == "--skip") {
s_flag = 1
skip_re = ARGV[++i]
}
else if (ARGV[i] == "-h" || ARGV[i] == "--help") {
system("grep -v '^#' @DOCPATH@/listtotable.txt")
rc = 1
exit(rc)
}
}
ARGC = 1 # Fix argv[]
if (o_file == NULL) o_file = "@STDOUT@"
if (i_file != NULL) { ARGV[1] = i_file; ARGC = 2 }
}
s_flag && $0 ~ skip_re { NR--; next } # Handle '-s' option.
NR == 1 { next }
/^[A-Za-z_]/ && got_header == 0 {
if (trim) { sub(/^ +/, NULL, $1); sub(/ +$/, NULL, $1) }
header == NULL ? header = $1 : header = header OFS $1
}
{ r_length = length($0) }
r_length {
if (/^[A-Za-z_]/) {
# This is a field name.
# Remove field name. This _must_ be done in two steps !!
sub(/^[^ \t]+/, NULL)
sub(/^[ \t]/, NULL)
if (trim) { sub(/^ +/, NULL); sub(/ +$/, NULL) }
# Escape any '\t' characters in the data.
gsub(/\t/, "\\t")
out_rec = out_rec OFS $0
} else {
# This is a continuation line.
# Remove the leading blank inserted by 'tabletolist' on
# continuation lines, unless explicitly requested not to do so.
if (!nochomp) sub(/^ /, NULL)
# Escape any '\t' characters in the data.
gsub(/\t/, "\\t")
# Preserve output formatting by inserting an escaped newline '\n'.
out_rec = out_rec "\\n" $0
}
}
!r_length {
if (!got_header) {
got_header = 1
# Remove possible extra trailing tab from out_rec.
sub(/\t$/, NULL, header)
print header > o_file
gsub(/[^\t]/, "-", header)
print header > o_file
}
# Remove possible extra leading tab from out_rec.
sub(/^\t/, NULL, out_rec)
# print out_rec unless it contains only tabs.
if (out_rec !~ /^\t+$/) print out_rec > o_file
out_rec = NULL
}
#
# End of program.
#
|
