1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# libsocket.m4 serial 1 - based on gnulib socketlib.m4
dnl Copyright (C) 2008-2012 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.
dnl npth_SOCKETLIB
dnl Determines the library to use for socket functions.
dnl Sets and AC_SUBSTs LIBSOCKET.
AC_DEFUN([npth_LIBSOCKET],
[
LIBSOCKET=
dnl Unix API.
dnl Solaris has most socket functions in libsocket.
dnl Haiku has most socket functions in libnetwork.
dnl BeOS has most socket functions in libnet.
AC_CACHE_CHECK([for library containing setsockopt], [npth_cv_lib_socket], [
npth_cv_lib_socket=
AC_LINK_IFELSE([AC_LANG_PROGRAM([[extern
#ifdef __cplusplus
"C"
#endif
char setsockopt();]], [[setsockopt();]])],
[],
[npth_save_LIBS="$LIBS"
LIBS="$npth_save_LIBS -lsocket"
AC_LINK_IFELSE([AC_LANG_PROGRAM([[extern
#ifdef __cplusplus
"C"
#endif
char setsockopt();]], [[setsockopt();]])],
[npth_cv_lib_socket="-lsocket"])
if test -z "$npth_cv_lib_socket"; then
LIBS="$npth_save_LIBS -lnetwork"
AC_LINK_IFELSE([AC_LANG_PROGRAM([[extern
#ifdef __cplusplus
"C"
#endif
char setsockopt();]], [[setsockopt();]])],
[npth_cv_lib_socket="-lnetwork"])
if test -z "$npth_cv_lib_socket"; then
LIBS="$npth_save_LIBS -lnet"
AC_LINK_IFELSE([AC_LANG_PROGRAM([[extern
#ifdef __cplusplus
"C"
#endif
char setsockopt();]], [[setsockopt();]])],
[npth_cv_lib_socket="-lnet"])
fi
fi
LIBS="$npth_save_LIBS"
])
if test -z "$npth_cv_lib_socket"; then
npth_cv_lib_socket="none needed"
fi
])
if test "$npth_cv_lib_socket" != "none needed"; then
LIBSOCKET="$npth_cv_lib_socket"
fi
AC_SUBST([LIBSOCKET])
])
|
