File: configure.ac

package info (click to toggle)
oath-toolkit 2.6.1-1.3
  • links: PTS, VCS
  • area: main
  • in suites: bullseye, buster, sid
  • size: 20,924 kB
  • sloc: ansic: 54,713; sh: 13,738; yacc: 1,254; xml: 756; makefile: 353
file content (70 lines) | stat: -rw-r--r-- 1,971 bytes parent folder | download | duplicates (2)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
# Copyright (C) 2009-2015 Simon Josefsson

# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.

# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.

# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <http://www.gnu.org/licenses/>.

AC_INIT([oath-toolkit],
  m4_esyscmd([build-aux/oath-toolkit-version .tarball-version]),
  [oath-toolkit-help@nongnu.org],,
  [http://www.nongnu.org/oath-toolkit/])

AC_CONFIG_AUX_DIR([build-aux])
AC_CONFIG_MACRO_DIR([m4])
AM_INIT_AUTOMAKE([1.11 -Wall -Werror])
AM_SILENT_RULES([yes])

AC_CHECK_HEADERS_ONCE([security/pam_appl.h])
AC_ARG_ENABLE([pam],
  [AS_HELP_STRING([--disable-pam], [disable PAM module])],
   [],
   [enable_pam=$ac_cv_header_security_pam_appl_h])
AM_CONDITIONAL([ENABLE_PAM], [test "x$enable_pam" = xyes])

AC_ARG_ENABLE([pskc],
  [AS_HELP_STRING([--disable-pskc], [disable PSKC support])],
   [],
   [enable_pskc=yes])
if test "x$enable_pskc" = xyes; then
  AM_PATH_XML2([], [], [enable_pskc=no])
fi
AM_CONDITIONAL([ENABLE_PSKC], [test "x$enable_pskc" = xyes])

gl_EARLY
gl_INIT

AC_CONFIG_SUBDIRS([
  liboath
  oathtool
])
if test "x$enable_pskc" = xyes; then
  AC_CONFIG_SUBDIRS([libpskc])
  AC_CONFIG_SUBDIRS([pskctool])
fi
if test "x$enable_pam" = xyes; then
  AC_CONFIG_SUBDIRS([pam_oath])
fi
AC_CONFIG_FILES([
  Makefile
  gl/Makefile
  gl/tests/Makefile
])
AC_OUTPUT

AC_MSG_NOTICE([summary of build options:

  version:          ${VERSION}
  Install prefix:   ${prefix}
  Compiler:         ${CC}
  Build PAM module: $enable_pam
  PSKC:             $enable_pskc
])