1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
|
(**************************************************************************)
(* *)
(* OCaml *)
(* *)
(* Fabrice Le Fessant, INRIA Saclay *)
(* *)
(* Copyright 2012 Institut National de Recherche en Informatique et *)
(* en Automatique. *)
(* *)
(* All rights reserved. This file is distributed under the terms of *)
(* the GNU Lesser General Public License version 2.1, with the *)
(* special exception on linking described in the file LICENSE. *)
(* *)
(**************************************************************************)
open Misc
type pers_flags =
| Rectypes
| Alerts of alerts
| Opaque
type error =
| Not_an_interface of filepath
| Wrong_version_interface of filepath * string
| Corrupted_interface of filepath
exception Error of error
(* these type abbreviations are not exported;
they are used to provide consistency across
input_value and output_value usage. *)
type signature = Types.signature_item list
type flags = pers_flags list
type header = modname * signature
type cmi_infos = {
cmi_name : modname;
cmi_sign : signature;
cmi_crcs : crcs;
cmi_flags : flags;
}
let input_cmi ic =
let (name, sign) = (Compression.input_value ic : header) in
let crcs = (input_value ic : crcs) in
let flags = (input_value ic : flags) in
{
cmi_name = name;
cmi_sign = sign;
cmi_crcs = crcs;
cmi_flags = flags;
}
let read_cmi filename =
let ic = open_in_bin filename in
try
let buffer =
really_input_string ic (String.length Config.cmi_magic_number)
in
if buffer <> Config.cmi_magic_number then begin
close_in ic;
let pre_len = String.length Config.cmi_magic_number - 3 in
if String.sub buffer 0 pre_len
= String.sub Config.cmi_magic_number 0 pre_len then
begin
let msg =
if buffer < Config.cmi_magic_number then "an older" else "a newer" in
raise (Error (Wrong_version_interface (filename, msg)))
end else begin
raise(Error(Not_an_interface filename))
end
end;
let cmi = input_cmi ic in
close_in ic;
cmi
with End_of_file | Failure _ ->
close_in ic;
raise(Error(Corrupted_interface(filename)))
| Error e ->
close_in ic;
raise (Error e)
let output_cmi filename oc cmi =
(* beware: the provided signature must have been substituted for saving *)
output_string oc Config.cmi_magic_number;
Compression.output_value oc ((cmi.cmi_name, cmi.cmi_sign) : header);
flush oc;
let crc = Digest.file filename in
let crcs = (cmi.cmi_name, Some crc) :: cmi.cmi_crcs in
output_value oc (crcs : crcs);
output_value oc (cmi.cmi_flags : flags);
crc
(* Error report *)
open Format_doc
let report_error_doc ppf = function
| Not_an_interface filename ->
fprintf ppf "%a@ is not a compiled interface"
Location.Doc.quoted_filename filename
| Wrong_version_interface (filename, older_newer) ->
fprintf ppf
"%a@ is not a compiled interface for this version of OCaml.@.\
It seems to be for %s version of OCaml."
Location.Doc.quoted_filename filename older_newer
| Corrupted_interface filename ->
fprintf ppf "Corrupted compiled interface@ %a"
Location.Doc.quoted_filename filename
let () =
Location.register_error_of_exn
(function
| Error err -> Some (Location.error_of_printer_file report_error_doc err)
| _ -> None
)
let report_error = Format_doc.compat report_error_doc
|
