File: blkid.m4

package info (click to toggle)
ocfs2-tools 1.8.6-1
  • links: PTS, VCS
  • area: main
  • in suites: bullseye, sid
  • size: 6,232 kB
  • sloc: ansic: 86,865; sh: 5,781; python: 2,380; makefile: 1,305
file content (94 lines) | stat: -rw-r--r-- 2,483 bytes parent folder | download | duplicates (8)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
dnl Support for libblkid included in our tree for ocfs2console

AC_DEFUN([OCFS2_BLKID], [
  HAVE_BLKID=
  PKG_CHECK_MODULES(BLKID, blkid >= 1.36, HAVE_BLKID=yes,
    [AC_MSG_WARN([blkid >= 1.36 not found, using internal version])])
  AC_SUBST(HAVE_BLKID)

  if test "x$HAVE_BLKID" != "xyes"; then
    AC_CHECK_SIZEOF(short)
    AC_CHECK_SIZEOF(int)
    AC_CHECK_SIZEOF(long)
    AC_CHECK_SIZEOF(long long)

    AC_CONFIG_COMMANDS([ocfs2console/blkid/blkid_types.h], [
      outfile=ocfs2console/blkid/blkid_types.h-tmp
      cat > $outfile <<_______EOF
/* 
 * If linux/types.h is already been included, assume it has defined
 * everything we need.  (cross fingers)  Other header files may have 
 * also defined the types that we need.
 */
#if (!defined(_LINUX_TYPES_H) && !defined(_BLKID_TYPES_H) && \\
	!defined(_EXT2_TYPES_H))
#define _BLKID_TYPES_H

typedef unsigned char __u8;
typedef signed char __s8;

#if ($ocfs2_SIZEOF_INT == 8)
typedef int		__s64;
typedef unsigned int	__u64;
#else
#if ($ocfs2_SIZEOF_LONG == 8)
typedef long		__s64;
typedef unsigned long	__u64;
#else
#if ($ocfs2_SIZEOF_LONG_LONG == 8)
#if defined(__GNUC__)
typedef __signed__ long long 	__s64;
#else
typedef signed long long 	__s64;
#endif /* __GNUC__ */
typedef unsigned long long	__u64;
#endif /* SIZEOF_LONG_LONG == 8 */
#endif /* SIZEOF_LONG == 8 */
#endif /* SIZEOF_INT == 8 */

#if ($ocfs2_SIZEOF_INT == 2)
typedef	int		__s16;
typedef	unsigned int	__u16;
#else
#if ($ocfs2_SIZEOF_SHORT == 2)
typedef	short		__s16;
typedef	unsigned short	__u16;
#else
  ?==error: undefined 16 bit type
#endif /* SIZEOF_SHORT == 2 */
#endif /* SIZEOF_INT == 2 */

#if ($ocfs2_SIZEOF_INT == 4)
typedef	int		__s32;
typedef	unsigned int	__u32;
#else
#if ($ocfs2_SIZEOF_LONG == 4)
typedef	long		__s32;
typedef	unsigned long	__u32;
#else
#if ($ocfs2_SIZEOF_SHORT == 4)
typedef	short		__s32;
typedef	unsigned short	__u32;
#else
 ?== error: undefined 32 bit type
#endif /* SIZEOF_SHORT == 4 */
#endif /* SIZEOF_LONG == 4 */
#endif /* SIZEOF_INT == 4 */

#endif /* _*_TYPES_H */
_______EOF

      if cmp -s $outfile ocfs2console/blkid/blkid_types.h; then
        AC_MSG_NOTICE([ocfs2console/blkid/blkid_types.h is unchanged])
        rm -f $outfile
      else
        mv $outfile ocfs2console/blkid/blkid_types.h
      fi
    ],[
      ocfs2_SIZEOF_SHORT=$ac_cv_sizeof_short
      ocfs2_SIZEOF_INT=$ac_cv_sizeof_int
      ocfs2_SIZEOF_LONG=$ac_cv_sizeof_long
      ocfs2_SIZEOF_LONG_LONG=$ac_cv_sizeof_long_long
    ])
  fi
])