1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
|
/*
* Copyright (c) 2017, Oracle and/or its affiliates. All rights reserved.
* DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
*
* This code is free software; you can redistribute it and/or modify it
* under the terms of the GNU General Public License version 2 only, as
* published by the Free Software Foundation.
*
* This code is distributed in the hope that it will be useful, but WITHOUT
* ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
* FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
* version 2 for more details (a copy is included in the LICENSE file that
* accompanied this code).
*
* You should have received a copy of the GNU General Public License version
* 2 along with this work; if not, write to the Free Software Foundation,
* Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
*
* Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
* or visit www.oracle.com if you need additional information or have any
* questions.
*
*/
/*
* @test
* @bug 8154587
* @summary Check that calling clone() with an invokeinterface opcode throws an IAE
* even if there is a default method named clone() in a super interface.
* @compile DefaultNoCloneInC.jasm
* @run main DefaultNoCloneInC
*/
// The below .jasm code implements the following java code:
//
// public class DefaultNoCloneInC {
//
// interface I1 {
// default Object clone() {
// return "In I1's clone()";
// }
// }
//
//
// interface I2 extends I1 { }
//
//
// static class C implements I2 { }
//
//
// static Object test(I2 i) { return i.clone(); }
//
// public static void main(String[] args) {
// try {
// String s = (String)test(new C());
// throw new RuntimeException("Expected IAE not thrown");
// } catch (java.lang.IllegalAccessError e) {
// if (!e.toString().contains("C.clone")) {
// throw new RuntimeException("Wrong IllegalAccessError exception thrown");
// }
// }
// }
// }
interface DefaultNoCloneInC$I1 version 53:0 {
public Method clone:"()Ljava/lang/Object;" stack 1 locals 1 {
ldc String "In I1\'s clone()";
areturn;
}
static abstract interface InnerClass I1=class DefaultNoCloneInC$I1 of class DefaultNoCloneInC;
} // end Class DefaultNoCloneInC$I1
interface DefaultNoCloneInC$I2 implements DefaultNoCloneInC$I1 version 53:0 {
static abstract interface InnerClass I2=class DefaultNoCloneInC$I2 of class DefaultNoCloneInC;
static abstract interface InnerClass I1=class DefaultNoCloneInC$I1 of class DefaultNoCloneInC;
} // end Class DefaultNoCloneInC$I2
super class DefaultNoCloneInC$C implements DefaultNoCloneInC$I2 version 53:0 {
Method "<init>":"()V" stack 1 locals 1 {
aload_0;
invokespecial Method java/lang/Object."<init>":"()V";
return;
}
static InnerClass C=class DefaultNoCloneInC$C of class DefaultNoCloneInC;
static abstract interface InnerClass I2=class DefaultNoCloneInC$I2 of class DefaultNoCloneInC;
} // end Class DefaultNoCloneInC$C
super public class DefaultNoCloneInC version 53:0 {
public Method "<init>":"()V" stack 1 locals 1 {
aload_0;
invokespecial Method java/lang/Object."<init>":"()V";
return;
}
static Method test:"(LDefaultNoCloneInC$I2;)Ljava/lang/Object;" stack 1 locals 1 {
aload_0;
invokeinterface InterfaceMethod DefaultNoCloneInC$I2.clone:"()Ljava/lang/Object;", 1;
areturn;
}
public static Method main:"([Ljava/lang/String;)V" stack 3 locals 2 {
try t0;
new class DefaultNoCloneInC$C;
dup;
invokespecial Method DefaultNoCloneInC$C."<init>":"()V";
invokestatic Method test:"(LDefaultNoCloneInC$I2;)Ljava/lang/Object;";
checkcast class java/lang/String;
astore_1;
new class java/lang/RuntimeException;
dup;
ldc String "Expected IAE not thrown";
invokespecial Method java/lang/RuntimeException."<init>":"(Ljava/lang/String;)V";
athrow;
endtry t0;
catch t0 java/lang/IllegalAccessError;
stack_frame_type stack1;
stack_map class java/lang/IllegalAccessError;
astore_1;
aload_1;
invokevirtual Method java/lang/IllegalAccessError.toString:"()Ljava/lang/String;";
ldc String "C.clone";
invokevirtual Method java/lang/String.contains:"(Ljava/lang/CharSequence;)Z";
ifne L47;
new class java/lang/RuntimeException;
dup;
ldc String "Wrong IllegalAccessError exception thrown";
invokespecial Method java/lang/RuntimeException."<init>":"(Ljava/lang/String;)V";
athrow;
L47: stack_frame_type same;
return;
}
static InnerClass C=class DefaultNoCloneInC$C of class DefaultNoCloneInC;
static abstract interface InnerClass I2=class DefaultNoCloneInC$I2 of class DefaultNoCloneInC;
static abstract interface InnerClass I1=class DefaultNoCloneInC$I1 of class DefaultNoCloneInC;
} // end Class DefaultNoCloneInC
|
