1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
|
/*
* Copyright (c) 2023, Oracle and/or its affiliates. All rights reserved.
* DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
*
* This code is free software; you can redistribute it and/or modify it
* under the terms of the GNU General Public License version 2 only, as
* published by the Free Software Foundation.
*
* This code is distributed in the hope that it will be useful, but WITHOUT
* ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
* FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
* version 2 for more details (a copy is included in the LICENSE file that
* accompanied this code).
*
* You should have received a copy of the GNU General Public License version
* 2 along with this work; if not, write to the Free Software Foundation,
* Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
*
* Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
* or visit www.oracle.com if you need additional information or have any
* questions.
*
*/
super public class TestBackedgeLoadArrayFill
{
public Method "<init>":"()V"
stack 2 locals 1
{
aload_0;
invokespecial Method java/lang/Object."<init>":"()V";
return;
}
static Method test_101:"()V"
stack 20 locals 20
{
// test_002 in jasm: using try-catch
ldc 6;
istore_0; // i = 6
ldc 25;
newarray int;
astore_1; // arr = new int[25]
HEAD:
aload_1;
iload_0;
iconst_1;
iastore; // arr[i] = 1
// second block - the only one -> head block can be copied: one before, one on backedge
try t0;
aload_1;
iload_0;
aload_1;
iload_0;
iaload;
iastore; // arr[i] = arr[i]
goto FINALLY;
endtry t0;
catch t0 java/lang/Exception;
pop; // exception
FINALLY:
iinc 0, 1; // i++
iload_0;
ldc 21;
if_icmplt HEAD; // if i < 21
// write array
aload_1;
putstatic Field TestBackedgeLoadArrayFillMain.intA:"[I";
return;
}
static Method test_102:"()V"
stack 20 locals 20
{
// test_002 in jasm: without try-catch
ldc 5;
istore_0; // i = 5
ldc 25;
newarray int;
astore_1; // arr = new int[25]
HEAD:
aload_1;
iload_0;
iconst_1;
iastore; // arr[i] = 1
goto SECOND;
// second block - the only one -> head block can be copied: one before, one on backedge
// must have some material before inc, else it is partial peeled away
// And if we set -XX:-PartialPeelLoop, then the counted loop is never detected
SECOND:
aload_1;
iload_0;
aload_1;
iload_0;
iaload;
iastore; // arr[i] = arr[i]
iinc 0, 1; // i++
iload_0;
ldc 21;
if_icmplt HEAD; // if i < 21
// write array
aload_1;
putstatic Field TestBackedgeLoadArrayFillMain.intA:"[I";
return;
}
static Method test_103:"()V"
stack 20 locals 20
{
// test_002 in jasm: without try-catch, and second array
ldc 7;
istore_0; // i = 7
ldc 25;
newarray int;
astore_1; // arr = new int[25]
ldc 25;
newarray int;
astore_2; // arr2 = new int[25]
HEAD:
aload_1;
iload_0;
iconst_1;
iastore; // arr[i] = 1
goto SECOND;
// second block - the only one -> head block can be copied: one before, one on backedge
SECOND:
// we can also do the identity read-write on another array - it just has to eventually disappear
aload_2;
iload_0;
aload_2;
iload_0;
iaload;
iastore; // arr2[i] = arr2[i]
iinc 0, 1; // i++
iload_0;
ldc 21;
if_icmplt HEAD; // if i < 21
// write array
aload_1;
putstatic Field TestBackedgeLoadArrayFillMain.intA:"[I";
return;
}
static Method test_104:"()V"
stack 20 locals 20
{
ldc 9;
istore_0; // i = 9
ldc 25;
newarray int;
astore_1; // arr = new int[25]
HEAD:
aload_1;
iload_0;
iconst_1;
iastore; // arr[i] = 1
goto SECOND;
// second block - the only one -> head block can be copied: one before, one on backedge
SECOND:
// CFG leads to partial peel -> load moved into loop body, then intrinsified
iload_0;
ldc 2;
irem;
ifeq SKIP;
SKIP:
iinc 0, 1; // i++
iload_0;
ldc 21;
if_icmplt HEAD; // if i < 21
// write array
aload_1;
putstatic Field TestBackedgeLoadArrayFillMain.intA:"[I";
return;
}
}
|
