File: FindSixenseSdk.cmake

package info (click to toggle)
opensurgsim 0.7.0-5
  • links: PTS, VCS
  • area: main
  • in suites: stretch
  • size: 23,600 kB
  • ctags: 16,440
  • sloc: cpp: 135,427; ansic: 4,247; python: 3,934; makefile: 36
file content (195 lines) | stat: -rw-r--r-- 6,540 bytes parent folder | download | duplicates (3)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
# - Try to find the Sixense SDK, used by the Razer Hydra gaming controller.
#
# Once done this will define
#  SIXENSESDK_FOUND - system has the Sixense SDK directory
#  SIXENSESDK_INCLUDE_DIR - the Sixense SDK include directory
#  SIXENSESDK_LIBRARIES - the Sixense SDK libraries

# This file is a part of the OpenSurgSim project.
# Copyright 2013, SimQuest Solutions Inc.


# Cache settings and Sixense SDK environment variables take
# precedence, or we try to fall back to the default search.

find_path(SIXENSESDK_INCLUDE_DIR
	NAMES sixense.h
	PATHS "$ENV{SIXENSESDK_PATH}" "$ENV{SIXENSE_ROOT}"
	PATH_SUFFIXES "include"
	NO_CMAKE_ENVIRONMENT_PATH NO_SYSTEM_ENVIRONMENT_PATH NO_CMAKE_SYSTEM_PATH
)
if(WIN32)
	# Shake down some usual suspects under Windows.
	#
	# This is far from exhaustive-- Steam may not be installed in
	# C:\Program Files, and even if it is, you can install apps into
	# alternate locations.  But this does covers the most common case.
	#
	# Alternately, we could look at examining the registry; on my
	# machine, there's some interesting stuff in
	# HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\Steam App 42300.
	find_path(SIXENSESDK_INCLUDE_DIR
		NAMES sixense.h
		PATHS
			"C:/Program Files (x86)/Steam/steamapps/common/sixense sdk/SixenseSDK"
			"C:/Program Files/Steam/steamapps/common/sixense sdk/SixenseSDK"
		PATH_SUFFIXES "include"
		NO_CMAKE_ENVIRONMENT_PATH NO_SYSTEM_ENVIRONMENT_PATH NO_CMAKE_SYSTEM_PATH
	)
endif(WIN32)
if(${CMAKE_SYSTEM_NAME} STREQUAL "Linux")
	# Shake down some usual suspects under Linux.
	# This is largely hypothetical.
	find_path(SIXENSESDK_INCLUDE_DIR
		NAMES sixense.h
		PATHS
			"$ENV{HOME}/.local/share/Steam/SteamApps/common/sixense sdk/SixenseSDK"
			"/usr/local"
		PATH_SUFFIXES "include"
		NO_CMAKE_ENVIRONMENT_PATH NO_SYSTEM_ENVIRONMENT_PATH NO_CMAKE_SYSTEM_PATH
	)
endif(${CMAKE_SYSTEM_NAME} STREQUAL "Linux")
find_path(SIXENSESDK_INCLUDE_DIR
	NAMES sixense.h
	PATH_SUFFIXES "include"
)


# Look for shared libraries.  Static linking is not currently supported.
set(LIB_SUFFIX "")
#set(LIB_SUFFIX "_s")

set(LIB_ARCH "unknown")
set(LIB_SYSDIR "lib_unknown")
if(WIN32 AND MSVC)
	if(CMAKE_CL_64)
		set(LIB_ARCH "x64")
		set(LIB_SUFFIX "${LIB_SUFFIX}_x64")
	else()
		set(LIB_ARCH "win32")
	endif()
	if(MSVC_VERSION LESS "1800")
		set(LIB_ARCH "${LIB_ARCH}/VS2010")
	else()
		set(LIB_ARCH "${LIB_ARCH}/VS2013")
	endif()
endif(WIN32 AND MSVC)
if(${CMAKE_SYSTEM_NAME} STREQUAL "Linux")
	if("${CMAKE_SIZEOF_VOID_P}" STREQUAL "8") # 64 bit
		set(LIB_ARCH "linux_x64")
		set(LIB_SYSDIR "lib64")
		set(LIB_SUFFIX "${LIB_SUFFIX}_x64")
	else("${CMAKE_SIZEOF_VOID_P}" STREQUAL "8") # 32 bit
		set(LIB_ARCH "linux")
		set(LIB_SYSDIR "lib")
	endif("${CMAKE_SIZEOF_VOID_P}" STREQUAL "8")
endif(${CMAKE_SYSTEM_NAME} STREQUAL "Linux")

if(SIXENSESDK_INCLUDE_DIR)
	get_filename_component(SIXENSESDK_ROOT_DIR
		${SIXENSESDK_INCLUDE_DIR} PATH)
endif(SIXENSESDK_INCLUDE_DIR)


macro(sixense_shared_from_link OUTPUT)
	set(SHARED_LIST)
	foreach(FILE ${ARGN})
		if(WIN32)
			string(REPLACE "/lib/" "/bin/" SHARED "${FILE}")
			string(REPLACE ".lib" ".dll" SHARED "${SHARED}")
		else()
			set(SHARED "${FILE}")
		endif()
		if(EXISTS "${SHARED}")
			list(APPEND SHARED_LIST "${SHARED}")
		else()
			message(SEND_ERROR "Could not find dynamic library for ${FILE}")
		endif()
	endforeach(FILE ${ARGN})
	set(${OUTPUT} ${SHARED_LIST}
		CACHE STRING "DLLs/SOs from the Sixense SDK.")
	mark_as_advanced(${OUTPUT})
endmacro()

macro(sixense_find_library LIB_NAME)
	find_library(SIXENSESDK_${LIB_NAME}_LIBRARY_RELEASE
		NAMES ${LIB_NAME}${LIB_SUFFIX}
		HINTS "${SIXENSESDK_ROOT_DIR}"
		PATH_SUFFIXES "lib/${LIB_ARCH}/release_dll" "lib/${LIB_ARCH}/release"
		NO_CMAKE_ENVIRONMENT_PATH NO_SYSTEM_ENVIRONMENT_PATH NO_CMAKE_SYSTEM_PATH
	)
	find_library(SIXENSESDK_${LIB_NAME}_LIBRARY_RELEASE
		NAMES ${LIB_NAME}${LIB_SUFFIX}
		PATH_SUFFIXES "lib/${LIB_ARCH}/release_dll" "lib/${LIB_ARCH}/release"
			"${LIB_SYSDIR}"
	)

	find_library(SIXENSESDK_${LIB_NAME}_LIBRARY_DEBUG
		NAMES ${LIB_NAME}d${LIB_SUFFIX}
		HINTS "${SIXENSESDK_ROOT_DIR}"
		PATH_SUFFIXES "lib/${LIB_ARCH}/debug_dll" "lib/${LIB_ARCH}/debug"
		NO_CMAKE_ENVIRONMENT_PATH NO_SYSTEM_ENVIRONMENT_PATH NO_CMAKE_SYSTEM_PATH
	)
	find_library(SIXENSESDK_${LIB_NAME}_LIBRARY_DEBUG
		NAMES ${LIB_NAME}d${LIB_SUFFIX}
		PATH_SUFFIXES "lib/${LIB_ARCH}/debug_dll" "lib/${LIB_ARCH}/debug"
			"${LIB_SYSDIR}"
	)

	if(SIXENSESDK_${LIB_NAME}_LIBRARY_RELEASE AND
			SIXENSESDK_${LIB_NAME}_LIBRARY_DEBUG AND
			NOT SIXENSESDK_${LIB_NAME}_LIBRARY)
		set(SIXENSESDK_${LIB_NAME}_LIBRARY
			optimized ${SIXENSESDK_${LIB_NAME}_LIBRARY_RELEASE}
			debug     ${SIXENSESDK_${LIB_NAME}_LIBRARY_DEBUG}
			CACHE STRING "The ${LIB_NAME} library from the Sixense SDK.")
		mark_as_advanced(SIXENSESDK_${LIB_NAME}_LIBRARY)
	endif()

	if(SIXENSESDK_${LIB_NAME}_LIBRARY_RELEASE AND
			NOT SIXENSESDK_${LIB_NAME}_SHARED_RELEASE)
		sixense_shared_from_link(SIXENSESDK_${LIB_NAME}_SHARED_RELEASE
			"${SIXENSESDK_${LIB_NAME}_LIBRARY_RELEASE}")
	endif()
	if(SIXENSESDK_${LIB_NAME}_LIBRARY_DEBUG AND
			NOT SIXENSESDK_${LIB_NAME}_SHARED_DEBUG)
		sixense_shared_from_link(SIXENSESDK_${LIB_NAME}_SHARED_DEBUG
			"${SIXENSESDK_${LIB_NAME}_LIBRARY_DEBUG}")
	endif()
endmacro()

sixense_find_library(sixense)
sixense_find_library(sixense_utils)

include(FindPackageHandleStandardArgs)
find_package_handle_standard_args(SixenseSdk
	DEFAULT_MSG SIXENSESDK_ROOT_DIR SIXENSESDK_INCLUDE_DIR
	SIXENSESDK_sixense_LIBRARY SIXENSESDK_sixense_utils_LIBRARY)

if(SIXENSESDK_FOUND)
	set(SIXENSESDK_LIBRARIES
		${SIXENSESDK_sixense_LIBRARY} ${SIXENSESDK_sixense_utils_LIBRARY})
endif(SIXENSESDK_FOUND)
mark_as_advanced(SIXENSESDK_LIBRARIES)

if(SIXENSESDK_FOUND)
	# HACK: for debug, we may also need the mysterious DeviceDLL.dll on Windows.
	if(WIN32)
		find_file(SIXENSESDK_DeviceDLL_SHARED_DEBUG
			NAMES DeviceDLL.dll
			HINTS "${SIXENSESDK_ROOT_DIR}"
			PATH_SUFFIXES "samples/${LIB_ARCH}/sixense_simple3d"
			NO_CMAKE_ENVIRONMENT_PATH NO_SYSTEM_ENVIRONMENT_PATH NO_CMAKE_SYSTEM_PATH
		)
		if(NOT SIXENSESDK_DeviceDLL_SHARED_DEBUG)
			# if not found, clear it and hope for the best...
			message("Warning: DeviceDLL.dll (from Sixense) not found; continuing.")
			set(SIXENSESDK_DeviceDLL_SHARED_DEBUG
				CACHE PATH "Path to DeviceDLL, if any." FORCE)
		endif(NOT SIXENSESDK_DeviceDLL_SHARED_DEBUG)
	else()
		set(SIXENSESDK_DeviceDLL_SHARED_DEBUG
			CACHE PATH "Path to DeviceDLL, if any.")
		mark_as_advanced(SIXENSESDK_DeviceDLL_SHARED_DEBUG)
	endif()
endif(SIXENSESDK_FOUND)