File: meson.build

package info (click to toggle)
parlatype 1.6.2-1
  • links: PTS, VCS
  • area: main
  • in suites: sid
  • size: 3,792 kB
  • sloc: ansic: 9,936; xml: 275; python: 272; makefile: 28; sh: 15
file content (88 lines) | stat: -rw-r--r-- 2,440 bytes parent folder | download
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
project('parlatype', 'c',
	version: '1.6.2',
	#meson_version: '>= 0.47.2', # oldest working tested version
	license: 'GPL3+',
)

app_id = 'com.github.gkarsay.parlatype'

libreoffice = get_option('libreoffice')
asr =         get_option('asr')

conf = configuration_data()
conf.set_quoted('VERSION', meson.project_version())
conf.set_quoted('PACKAGE_VERSION', meson.project_version())
conf.set_quoted('PACKAGE', meson.project_name())
conf.set_quoted('PACKAGE_NAME', meson.project_name())
conf.set_quoted('PACKAGE_URL', 'https://gkarsay.github.io/parlatype/')
conf.set('HAVE_ASR', asr)
configure_file(output: 'config.h', configuration: conf)
conf_inc = include_directories('.', 'libparlatype/src')

prefix = get_option('prefix')
bindir = join_paths(prefix, get_option('bindir'))
libdir = join_paths(prefix, get_option('libdir'))
datadir = join_paths(prefix, get_option('datadir'))
pkgdatadir = join_paths(datadir, meson.project_name())
localedir = join_paths(prefix, get_option('localedir'))
add_global_arguments('-DLOCALEDIR="@0@"'.format(localedir), language : 'c')

gnome = import('gnome')
i18n = import('i18n')

gettext_package = 'parlatype'

# Checks for libraries.
gtk = dependency('gtk+-3.0', version: '>= 3.22')
gmodule = dependency('gmodule-2.0')
atspi = dependency('atspi-2')

# GLib versioned dependency is for the build system,
# see https://bugzilla.gnome.org/show_bug.cgi?id=774368
glib = dependency('glib-2.0', version: '>= 2.50.2')

subdir('libparlatype')
subdir('data')
subdir('docs')
subdir('help')
subdir('po')
subdir('src')

if libreoffice
	subdir('libreoffice')
endif

status = [
  '', '',
  'Parlatype @0@'.format(meson.project_version()),
  '',
  'Prefix ................... : @0@'.format(prefix),
  'With ASR ................. : @0@'.format(asr),
  'With LibreOffice helpers . : @0@'.format(libreoffice)
]

if libreoffice
	status += [
  'Script folder ............ : @0@'.format(get_option('libreoffice-dir'))
	]
endif

status += [
  '',
  'With GObject Introspection : @0@'.format(gir),
  'With API reference ....... : @0@'.format(gtk_doc),
  'With Glade catalog ....... : @0@'.format(glade),
  ''
]

if (prefix != '/usr')
	status += ['Command to run parlatype:']
	if (asr)
		status += ['LD_LIBRARY_PATH=@0@ GST_PLUGIN_PATH=@0@/gstreamer-1.0 @1@/parlatype'.format(libdir, bindir)]
	else
		status += ['LD_LIBRARY_PATH=@0@ @1@/parlatype'.format(libdir, bindir)]
	endif
	status += ['']
endif

message('\n '.join(status))