dnl Process this file with autoconf to produce a configure script.

AC_INIT(configure.in)
AM_INIT_AUTOMAKE(pbbuttonsd, 0.7.9)
AM_CONFIG_HEADER(config.h)
AM_MAINTAINER_MODE

dnl Checks for programs.
AC_ISC_POSIX
AC_PROG_CC
AC_PROG_CXX
AM_PROG_CC_STDC
AC_PROG_AWK
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET
AC_PROG_RANLIB

AC_SUBST(localstatedir, "/var/lib")

echo -n "checking for system: "
ac_laptop=powerbook
if test "x$laptop" != "x"; then
    ac_laptop=$laptop
elif test "x$LAPTOP" != "x"; then
    ac_laptop=$LAPTOP
fi
case "$ac_laptop" in
    POWERBOOK | powerbook | pb | PB )
	AC_DEFINE_UNQUOTED(SYS_POWERBOOK, "", [machine to build the package for])
	ac_laptop="Apple PowerBook"
	;;
    I386ACPI | i386acpi | acpi | ACPI )
	AC_DEFINE_UNQUOTED(SYS_I386_ACPI, "", [machine to build the package for])
	ac_laptop="Intel based laptop with ACPI"
	;;
    I386 | i386)
	AC_DEFINE_UNQUOTED(SYS_I386_GENERIC, "", [machine to build the package for])
	ac_laptop="Intel based laptop"
	;;
    *)
        echo -e "\nOption 'laptop' not set or unknown. Please call 'configure laptop=<target>'"
        echo "Possible targets are: powerbook"
        AC_MSG_ERROR(unknown target system)
	;;
esac
echo "$ac_laptop"

dnl Checks for libraries.
AC_CHECK_LIB([dl], [dlopen])

pkg_modules="glib-2.0 >= 2.0.0"
PKG_CHECK_MODULES(PACKAGE, [$pkg_modules])
AC_SUBST(PACKAGE_CFLAGS)
AC_SUBST(PACKAGE_LIBS)

PB_OBJECTS=
PB_LIBS=

pbb_with_pmud=no
AC_ARG_WITH(pmud, [  --with-pmud             use pmud as low level power manager (default=no)],
	pbb_with_pmud=$withval, )
if test "$pbb_with_pmud" == "yes"; then
	AC_DEFINE_UNQUOTED(WITH_PMUD, 1, [use pmud as basement])
	PB_OBJECTS+="tcp.$OBJEXT"
fi

pbb_with_oss=yes
AC_ARG_WITH(oss,  [  --with-oss              enable OSS support in pbbuttonsd (default=yes)],
	pbb_with_oss=$withval, )
if test "$pbb_with_oss" == "yes"; then
	AC_DEFINE_UNQUOTED(WITH_OSS, 1, [enable OSS support])
fi

pbb_with_alsa=yes
AC_ARG_WITH(alsa, [  --with-alsa             enable ALSA support in pbbuttonsd (default=yes)],
	pbb_with_alsa=$withval, )
if test "$pbb_with_alsa" == "yes"; then
	AM_PATH_ALSA(1.0.0, [pbb_have_alsa=yes], [pbb_have_alsa=no]) 
	if test "$pbb_have_alsa" == "yes"; then
		AC_DEFINE_UNQUOTED(WITH_ALSA, 1, [enable ALSA support])
	fi
fi

pbb_with_ibam=yes
AC_ARG_WITH(ibam, [  --with-ibam             enable IBAM support in pbbuttonsd (default=yes)],
	pbb_with_ibam=$withval, )
if test "$pbb_with_ibam" == "yes"; then
	AC_DEFINE_UNQUOTED(WITH_IBAM, 1, [enable IBAM support])
	PB_OBJECTS+=" ibam_stub.$OBJEXT"
	PB_LIBS+=" -lstdc++"
fi

AM_CONDITIONAL(DEBUG, test "$enable_debug" = yes)
if test "$enable_debug" == "yes"; then
	PB_OBJECTS+=" module_peep.$OBJEXT"
fi

AC_SUBST([PB_OBJECTS])
AC_SUBST([PB_LIBS])

dnl Checks for header files.
AC_HEADER_STDC
AC_CHECK_HEADERS([initreq.h alloca.h argz.h errno.h fcntl.h langinfo.h libintl.h limits.h locale.h malloc.h stddef.h stdlib.h string.h strings.h sys/ioctl.h sys/param.h unistd.h])

dnl defining some constants
dnl Add the languages which your application supports here.
ALL_LINGUAS="de ca es"
AM_GNU_GETTEXT

dnl hell, is that really what we have to do, when we want to support
dnl gettext versions before autopoint was introduced to gettext (0.11.3)?
dnl bastard autopoint script checks for "^AM_GNU_GETTEXT_VERSION(x.y.z)"
ifdef(AM_GNU_GETTEXT_VERSION,
AM_GNU_GETTEXT_VERSION(0.13.1)
, )

dnl Set SYS_CONF_DIR in config.h.
if test "x${sysconfdir}" = 'x${prefix}/etc'; then
  if test "x${prefix}" = "xNONE"; then
    pbb_sysconfdir="${ac_default_prefix}/etc"
  else
    pbb_sysconfdir="${prefix}/etc"
  fi
else
  pbb_sysconfdir=${sysconfdir}
fi
AC_DEFINE_UNQUOTED(SYS_CONF_DIR, "${pbb_sysconfdir}", [place for configuration files])

dnl Set PACKAGE_DATA_DIR in config.h.
if test "x${datadir}" = 'x${prefix}/share'; then
  if test "x${prefix}" = "xNONE"; then
    pbb_datadir="${ac_default_prefix}/share"
  else
    pbb_datadir="${prefix}/share"
  fi
else
  pbb_datadir=${datadir}
fi
AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${pbb_datadir}", [place for data files])

pbb_localedir="${pbb_datadir}/locale"
AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR, "${pbb_localedir}", [target dir for package])

AC_OUTPUT([
Makefile
src/Makefile
po/Makefile.in
po/Makefile
libpbbipc/Makefile
pbbcmd/Makefile
intl/Makefile
])

echo -e "------------------------------------------------------"
echo -e "PBButtonsd configuration summary\n"
echo -e "System: $ac_laptop\n"
echo -e "Options:"
echo -n "   pmud support "
if test "$pbb_with_pmud" == "yes"; then
	echo "enabled"
else
	echo "disabled"
fi
echo -n "   OSS  support "
if test "$pbb_with_oss" == "yes"; then
	echo "enabled"
else
	echo "disabled"
fi
echo -n "   ALSA support "
if test "$pbb_have_alsa" == "yes"; then
	echo "enabled"
elif test "$pbb_with_alsa" == "yes"; then
	echo "not available (development files?)"
else
	echo "disabled"
fi
echo -n "   IBAM support "
if test "$pbb_with_ibam" == "yes"; then
	echo "enabled"
else
	echo "disabled"
fi	
echo -n "   Debug mode "
if test "$enable_debug" == "yes"; then
	echo "enabled"
else
	echo "disabled"
fi

echo -e "\nPaths:"
echo -e "   config:   $pbb_sysconfdir"
echo -e "   data:     $pbb_datadir"
echo -e "   locale:   $pbb_localedir"
echo -e "   batlog:   /var/lib/pbbuttons            (hardcoded)"
echo -e "   ibam:     /var/lib/ibam                 (hardcoded)" 
echo -e "\nCompiler:"
echo -e "   CFLAGS:   $CFLAGS"
echo -e "   CXXFLAGS: $CXXFLAGS"
echo -e "------------------------------------------------------"