File: meson.build

package info (click to toggle)
peek 1.5.1-1
  • links: PTS, VCS
  • area: main
  • in suites: bullseye, sid
  • size: 3,768 kB
  • sloc: xml: 234; sh: 85; python: 69; makefile: 14
file content (56 lines) | stat: -rw-r--r-- 1,688 bytes parent folder | download | duplicates (2)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
desktop_file = i18n.merge_file(
  input: 'com.uploadedlobster.peek.desktop.in',
  output: 'com.uploadedlobster.peek.desktop',
  type: 'desktop',
  po_dir: '../po',
  install: true,
  install_dir: join_paths(get_option('datadir'), 'applications')
)

desktop_utils = find_program('desktop-file-validate', required: false)
if desktop_utils.found()
  test('Validate desktop file', desktop_utils,
    args: [desktop_file]
  )
endif

appstream_file = i18n.merge_file(
  input: 'com.uploadedlobster.peek.appdata.xml.in',
  output: 'com.uploadedlobster.peek.appdata.xml',
  po_dir: '../po',
  install: true,
  install_dir: join_paths(get_option('datadir'), 'metainfo')
)

appstream_util = find_program('appstream-util', required: false)
if appstream_util.found()
  test('Validate appstream file', appstream_util,
    args: ['validate', appstream_file]
  )
endif

install_data('com.uploadedlobster.peek.gschema.xml',
  install_dir: join_paths(get_option('datadir'), 'glib-2.0/schemas')
)

compile_schemas = find_program('glib-compile-schemas', required: false)
if compile_schemas.found()
  test('Validate schema file', compile_schemas,
    args: ['--strict', '--dry-run', meson.current_source_dir()]
  )
endif

configuration_data = configuration_data()
# FIXME: That variable name is used as long as we have both cmake and meson builds
configuration_data.set(
  'CMAKE_INSTALL_FULL_BINDIR',
  join_paths(get_option('prefix'), get_option('bindir')))
configure_file(
  input: 'com.uploadedlobster.peek.service.in',
  output: 'com.uploadedlobster.peek.service',
  configuration: configuration_data,
  install_dir: join_paths(get_option('datadir'), 'dbus-1/services')
)

subdir('icons')
subdir('man')