1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
|
PHP_ARG_WITH([iconv],
[for iconv support],
[AS_HELP_STRING([[--without-iconv[=DIR]]],
[Exclude iconv support])],
[yes])
if test "$PHP_ICONV" != "no"; then
PHP_SETUP_ICONV([ICONV_SHARED_LIBADD],,
[AC_MSG_FAILURE([The iconv not found.])])
save_LIBS=$LIBS
save_CFLAGS=$CFLAGS
LIBS="$LIBS $ICONV_SHARED_LIBADD"
CFLAGS="$INCLUDES $CFLAGS"
AC_CACHE_CHECK([for iconv implementation], [php_cv_iconv_implementation], [
AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <gnu/libc-version.h>],
[gnu_get_libc_version();])],
[php_cv_iconv_implementation=glibc],
[php_cv_iconv_implementation=unknown])
AS_VAR_IF([php_cv_iconv_implementation], [unknown],
[AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <iconv.h>],
[(void) _libiconv_version])],
[php_cv_iconv_implementation="GNU libiconv"],
[php_cv_iconv_implementation=unknown])])
dnl BSD iconv by Konstantin Chuguev.
AS_VAR_IF([php_cv_iconv_implementation], [unknown],
[AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <iconv.h>],
[iconv_ccs_init(NULL, NULL);])],
[php_cv_iconv_implementation=BSD],
[php_cv_iconv_implementation=unknown])])
AS_VAR_IF([php_cv_iconv_implementation], [unknown],
[AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <iconv.h>],
[cstoccsid("");])],
[php_cv_iconv_implementation=IBM],
[php_cv_iconv_implementation=unknown])])
])
AH_TEMPLATE([PHP_ICONV_IMPL], [The iconv implementation.])
AS_CASE([$php_cv_iconv_implementation],
[glibc], [
AC_DEFINE([HAVE_GLIBC_ICONV], [1],
[Define to 1 if iconv implementation is glibc.])
AC_DEFINE([PHP_ICONV_IMPL], ["glibc"])
],
["GNU libiconv"], [
AC_DEFINE([PHP_ICONV_IMPL], ["libiconv"])
AC_DEFINE([HAVE_LIBICONV], [1])
],
[BSD], [AC_DEFINE([PHP_ICONV_IMPL], ["BSD iconv"])],
[IBM], [
AC_DEFINE([HAVE_IBM_ICONV], [1],
[Define to 1 if iconv implementation is IBM.])
AC_DEFINE([PHP_ICONV_IMPL], ["IBM iconv"])
])
AC_CACHE_CHECK([if iconv supports errno], [php_cv_iconv_errno],
[AC_RUN_IFELSE([AC_LANG_SOURCE([
#include <iconv.h>
#include <errno.h>
int main(void) {
iconv_t cd;
cd = iconv_open( "*blahblah*", "*blahblahblah*" );
if (cd == (iconv_t)(-1)) {
if (errno == EINVAL) {
return 0;
} else {
return 1;
}
}
iconv_close( cd );
return 2;
}
])],
[php_cv_iconv_errno=yes],
[php_cv_iconv_errno=no],
[php_cv_iconv_errno=yes])])
AS_VAR_IF([php_cv_iconv_errno], [yes],,
[AC_MSG_FAILURE([The iconv check failed, 'errno' is missing.])])
AC_CACHE_CHECK([if iconv supports //IGNORE], [php_cv_iconv_ignore],
[AC_RUN_IFELSE([AC_LANG_SOURCE([
#include <iconv.h>
#include <stdlib.h>
int main(void) {
iconv_t cd = iconv_open( "UTF-8//IGNORE", "UTF-8" );
if(cd == (iconv_t)-1) {
return 1;
}
char *in_p = "\xC3\xC3\xC3\xB8";
size_t in_left = 4, out_left = 4096;
char *out = malloc(out_left);
char *out_p = out;
size_t result = iconv(cd, (char **) &in_p, &in_left, (char **) &out_p, &out_left);
if(result == (size_t)-1) {
return 1;
}
return 0;
}
])],
[php_cv_iconv_ignore=yes],
[php_cv_iconv_ignore=no],
[php_cv_iconv_ignore=no])])
AS_VAR_IF([php_cv_iconv_ignore], [no],
[AC_DEFINE([ICONV_BROKEN_IGNORE], [1],
[Define to 1 if iconv has broken IGNORE.])])
LIBS=$save_LIBS
CFLAGS=$save_CFLAGS
AC_DEFINE([HAVE_ICONV], [1],
[Define to 1 if the PHP extension 'iconv' is available.])
PHP_NEW_EXTENSION([iconv],
[iconv.c],
[$ext_shared],,
[-DZEND_ENABLE_STATIC_TSRMLS_CACHE=1])
PHP_SUBST([ICONV_SHARED_LIBADD])
PHP_INSTALL_HEADERS([ext/iconv], [php_iconv.h])
fi
|
