File: template.xsl

package info (click to toggle)
pike7.8 7.8.866-7
  • links: PTS, VCS
  • area: main
  • in suites: stretch
  • size: 69,304 kB
  • ctags: 28,082
  • sloc: ansic: 252,877; xml: 36,537; makefile: 4,214; sh: 2,879; lisp: 655; asm: 591; objc: 212; pascal: 157; sed: 34
file content (409 lines) | stat: -rw-r--r-- 13,004 bytes parent folder | download | duplicates (11)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
<?xml version='1.0'?>

<!-- this template transforms the autodoc XML files to HTML -->
<!-- the results may be a lot short of pretty - but this is -->
<!-- supposed to be fixed before we release anything public -->

<xsl:stylesheet>
  <xsl:output method="html" />

  <xsl:param rxml:type="color" name="background" select="'white'"/>
  <xsl:param rxml:type="color" name="type" select="'#202020'"/>
  <xsl:param rxml:type="color" name="method-name" select="'#0000E0'"/>
  <xsl:param rxml:type="color" name="param-name" select="'#8000F0'"/>
  <xsl:param rxml:type="color" name="var-name" select="'#F000F0'"/>
  <xsl:param rxml:type="color" name="constant-name" select="'#F000F0'"/>
  <xsl:param rxml:type="color" name="program-name" select="'#005080'"/>

  <xsl:param name="ref" select="'red'"/>
  <xsl:param name="literal" select="'green'"/>
  <xsl:template match="text()"></xsl:template>

  <xsl:template match="*">
    <xsl:text>TEMPLATE ERROR, NOT HANDLED: <xsl:value-of select="name()"/></xsl:text>
  </xsl:template>

  <xsl:template match="/module">
    <html><head><title>Pike Reference Manual</title></head>
    <body bgcolor="{$background}">
    <h1>Pike Reference Manual - BETA</h1>
    <p><date type="iso" date="date" /></p>
      <xsl:apply-templates select="docgroup"/>
      <xsl:apply-templates select="module"/>
      <xsl:apply-templates select="class"/>
    </body></html>
  </xsl:template>

  <xsl:template match="module[@name != '']">
    <dl><dt>
        <table width="100%" cellpadding="3" cellspacing="0" border="0"><tr>
        <td bgcolor="#EEEEEE">
           <font size="+3">&nbsp; MODULE <b><xsl:value-of select="@name"/></b></font>
        </td></tr></table><br />
      </dt><dd>
        <dl><xsl:apply-templates select="./doc"/></dl>
        <xsl:for-each select="docgroup">
          <xsl:apply-templates select="."/>
        </xsl:for-each>
        <xsl:for-each select="class">
          <xsl:apply-templates select="."/>
        </xsl:for-each>
        <xsl:for-each select="module">
          <xsl:apply-templates select="."/>
        </xsl:for-each>
      </dd>
    </dl>
  </xsl:template>

  <xsl:template match="class">
    <dl>
      <dt><table width="100%" cellpadding="3" cellspacing="0" border="0"><tr>
        <td bgcolor="#EEEEEE">
        <font size="+3">&nbsp; CLASS <b>
            <font color="{$program-name}">
              <xsl:for-each select="ancestor::*[@name != '']"
                ><xsl:value-of select="@name"
                />.</xsl:for-each><xsl:value-of select="@name"/>
        </font></b></font>
        </td></tr></table><br />
      </dt>
      <dd>
        <dl><xsl:apply-templates select="doc"/></dl>
        <xsl:if test="inherit">
          <h3>Inherits:</h3>
          <ul><xsl:apply-templates select="inherit"/></ul>
        </xsl:if>
        <xsl:apply-templates select="docgroup"/>
        <xsl:apply-templates select="class"/>
      </dd>
    </dl>
  </xsl:template>

  <xsl:template match="inherit">
    <li><xsl:value-of select="classname"/></li>
  </xsl:template>

  <!-- DOCGROUPS -->

  <xsl:template name="show-class-path">
    <xsl:if test="count(ancestor::*[@name != '']) > 0">
      <font color="{$program-name}">
        <xsl:for-each select="ancestor::*[@name != '']">
          <xsl:value-of select="@name"/>
          <xsl:if test="position() != last()">.</xsl:if>
        </xsl:for-each>
      </font>
    </xsl:if>
  </xsl:template>

  <xsl:template name="show-class-path-arrow">
    <xsl:if test="count(ancestor::*[@name != '']) > 0">
      <xsl:call-template name="show-class-path"/>
      <xsl:choose>
        <xsl:when test="ancestor::class">
          <xsl:text>()-&gt;</xsl:text>
        </xsl:when>
        <xsl:when test="ancestor::module">
          <xsl:text>.</xsl:text>
        </xsl:when>
      </xsl:choose>
    </xsl:if>
  </xsl:template>

  <xsl:template match="docgroup">
    <hr clear="all" noshade="noshade" size="1"/>
    <dl>
      <dt>
        <xsl:choose>
          <xsl:when test="@homogen-type">
            <font face="Helvetica">
            <xsl:value-of select="translate(substring(@homogen-type,1,1),'cmvi','CMVI')"/>
            <xsl:value-of select="substring(@homogen-type,2)"/>
            </font>
            <xsl:choose>
              <xsl:when test="@homogen-name">
		<!-- FIXME: Should have the module path here. -->
                <font size="+1"><b><xsl:value-of select="concat(' ', concat(@belongs, @homogen-name))"/></b></font>
              </xsl:when>
              <xsl:when test="count(./*[name() != 'doc']) > 1">s
              </xsl:when>
            </xsl:choose>
          </xsl:when>
          <xsl:otherwise>syntax</xsl:otherwise>
        </xsl:choose>
      </dt>
      <dd><p><xsl:apply-templates select="*[name() != 'doc']"/></p></dd>
      <xsl:apply-templates select="doc"/>
    </dl>
  </xsl:template>

  <xsl:template match="constant">
    <xsl:if test="position() != 1"><br/></xsl:if>
    <tt>
      constant
      <xsl:call-template name="show-class-path-arrow"/> 
      <font color="{$constant-name}">
        <xsl:value-of select="@name"/>
      </font>
      <xsl:if test="typevalue">
        =
        <xsl:apply-templates select="typevalue/*" mode="type"/>
      </xsl:if>
    </tt>
  </xsl:template>

  <xsl:template match="variable">
    <xsl:if test="position() != 1"><br/></xsl:if>
    <tt>
      <xsl:apply-templates select="type/*" mode="type"/>
      <xsl:value-of select="' '"/>
      <xsl:call-template name="show-class-path-arrow"/> 
      <b><font color="{$var-name}"><xsl:value-of select="@name"/>
      </font></b>
    </tt>
  </xsl:template>

  <xsl:template match="method">
    <xsl:if test="position() != 1"><br/></xsl:if>
    <tt>
      <xsl:apply-templates select="returntype/*" mode="type"/>
      <xsl:value-of select="' '"/>
      <xsl:call-template name="show-class-path-arrow"/>
      <b><font color="{$method-name}"><xsl:value-of select="@name"/>
      </font>(</b>
        <xsl:for-each select="arguments/argument">
           <xsl:apply-templates select="."/>
           <xsl:if test="position() != last()">, </xsl:if>
        </xsl:for-each>
      <b>)</b></tt>
  </xsl:template>

  <xsl:template match="argument">
    <xsl:choose>
      <xsl:when test="value">
        <font color="{$literal}"><xsl:value-of select="value"/></font>
      </xsl:when>
      <xsl:when test="type and @name">
        <xsl:apply-templates select="type/*" mode="type"/>
        <xsl:value-of select="' '"/>
        <font color="{$param-name}"><xsl:value-of select="@name"/></font>
      </xsl:when>
    </xsl:choose>
  </xsl:template>

  <!-- TYPES -->

  <xsl:template match="object" mode="type">
    <xsl:choose>
      <xsl:when test="text()">
        <font color="{$program-name}">object(<xsl:value-of select="."/>)</font>
      </xsl:when>
      <xsl:otherwise>
        <font color="{$type}">object</font>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

  <xsl:template match="multiset" mode="type">
    <font color="{$type}">multiset</font>
    <xsl:if test="indextype"
    >(<xsl:apply-templates select="indextype/*" mode="type"
    />)</xsl:if>
  </xsl:template>

  <xsl:template match="array" mode="type">
    <font color="{$type}">array</font>
    <xsl:if test="valuetype"
    >(<xsl:apply-templates select="valuetype/*" mode="type"
    />)</xsl:if>
  </xsl:template>

  <xsl:template match="mapping" mode="type">
    <font color="{$type}">mapping</font>
    <xsl:if test="indextype and valuetype"
      >(<xsl:apply-templates select="indextype/*" mode="type"/>
       : <xsl:apply-templates select="valuetype/*" mode="type"
    />)</xsl:if>
  </xsl:template>

  <xsl:template match="function" mode="type">
    <font color="{$type}">function</font>
    <xsl:if test="argtype or returntype"
     >(<xsl:for-each select="argtype/*">
        <xsl:apply-templates select="." mode="type"/>
        <xsl:if test="position() != last()">, </xsl:if>
      </xsl:for-each>
      :
      <xsl:apply-templates select="returntype/*" mode="type"
    />)</xsl:if>
  </xsl:template>

  <xsl:template match="varargs"  mode="type">
    <xsl:apply-templates select="*" mode="type"/>
    <xsl:text> ... </xsl:text>
  </xsl:template>

  <xsl:template match="or" mode="type">
    <xsl:for-each select="./*">
      <xsl:apply-templates select="." mode="type"/>
      <xsl:if test="position() != last()">|</xsl:if>
    </xsl:for-each>
  </xsl:template>

  <xsl:template match="string|void|program|mixed|float" mode="type">
    <font color="{$type}">
      <xsl:value-of select="name()"/>
    </font>
  </xsl:template>

  <xsl:template match="int" mode="type">
    <font color="{$type}">int</font>
      <xsl:if test="min|max">(<font color="{$literal}">
        <xsl:value-of select="min"/>..<xsl:value-of select="max"/>
      </font>)</xsl:if>
  </xsl:template>

  <xsl:template match="p" mode="type"></xsl:template>

  <!-- DOC -->

  <xsl:template match="doc">
    <xsl:if test="text">
      <dt><font face="Helvetica">Description</font></dt>
      <xsl:apply-templates select="text" mode="doc"/>
    </xsl:if>
    <xsl:apply-templates select="group" mode="doc"/>
  </xsl:template>

  <xsl:template match="group" mode="doc">
    <xsl:apply-templates select="*[name(.) != 'text']" mode="doc"/>
    <xsl:apply-templates select="text" mode="doc"/>
  </xsl:template>

  <xsl:template match="param" mode="doc">
    <dt><font face="Helvetica">Parameter <tt>
        <font color="{$param-name}"><xsl:value-of select="@name"/></font>
    </tt></font></dt><dd></dd>
  </xsl:template>

  <xsl:template match="seealso" mode="doc">
    <dt><font face="Helvetica">See also</font></dt>
  </xsl:template>

  <xsl:template match="*" mode="doc">
    <xsl:if test="parent::*[name() = 'group']">
      <dt><font face="Helvetica">
	<xsl:value-of select="translate(substring(name(),1,1),'abcdefghijklmnopqrstuvwxyz','ABCDEFGHIJKLMNOPQRSTUVWXYZ')"/>
        <xsl:value-of select="substring(name(),2)"/>
      </font></dt>
      <xsl:apply-templates mode="doc"/>
    </xsl:if>
  </xsl:template>

  <xsl:template match="text" mode="doc">
    <dd><font face="Helvetica"><xsl:apply-templates mode="text"/></font></dd>
  </xsl:template>

  <!-- TEXT -->

  <xsl:template match="dl" mode="text">
    <dl>
      <xsl:for-each select="group">
        <xsl:apply-templates mode="text"/>
      </xsl:for-each>
    </dl>
  </xsl:template>

  <xsl:template match="item" mode="text">
    <dt><xsl:value-of select="@name"/></dt>
  </xsl:template>

  <xsl:template match="text" mode="text">
    <dd><xsl:apply-templates mode="text"/></dd>
  </xsl:template>

  <xsl:template match="mapping" mode="text">
    <dl>
      <xsl:for-each select="group">
        <xsl:for-each select="member">
          <dt>
            <tt>
              <font color="{$literal}"><xsl:value-of select="index"/></font>
              : <xsl:apply-templates select="type" mode="type"/>
            </tt>
          </dt><dd></dd>
        </xsl:for-each>
        <dd>
          <xsl:apply-templates select="text" mode="text"/>
        </dd>
      </xsl:for-each>
    </dl>
  </xsl:template>

  <xsl:template match="array" mode="text">
    <dl>
      <xsl:for-each select="group">
        <xsl:for-each select="elem">
          <dt>
            <tt>
              <xsl:apply-templates select="type" mode="type"/>
              <xsl:text> </xsl:text>
              <font color="{$literal}"><xsl:value-of select="index"/></font>
            </tt>
          </dt><dd></dd>
        </xsl:for-each>
        <dd>
          <xsl:apply-templates select="text" mode="text"/>
        </dd>
      </xsl:for-each>
    </dl>
  </xsl:template>

  <xsl:template match="int" mode="text">
    <dl>
      <xsl:for-each select="group">
        <xsl:for-each select="value">
          <dt>
            <tt>
              <font color="{$literal}"><xsl:value-of select="value"/></font>
            </tt>
          </dt><dd></dd>
        </xsl:for-each>
        <dd>
          <xsl:apply-templates select="text" mode="text"/>
        </dd>
      </xsl:for-each>
    </dl>
  </xsl:template>

  <xsl:template match="mixed" mode="text">
    <xsl:text><tt><xsl:value-of select="@name"/></tt> can have any of the following types:</xsl:text>
    <dl>
      <xsl:for-each select="group">
        <dt><tt><xsl:apply-templates select="type" mode="type"/></tt></dt>
	<dd><xsl:apply-templates select="text" mode="text"/></dd>
      </xsl:for-each>
    </dl>
  </xsl:template>

  <xsl:template match="ref" mode="text">
      <font face="courier" size="-1"><xsl:value-of select="."/></font>
  </xsl:template>

  <xsl:template match="i|p|b|tt" mode="text">
    <xsl:copy select=".">
      <xsl:apply-templates mode="text"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="pre|code" mode="text">
    <font face="courier"><xsl:copy select=".">
      <xsl:apply-templates mode="text"/>
    </xsl:copy></font>
  </xsl:template>

  <xsl:template match="text()" mode="text">
    <xsl:copy-of select="."/>
  </xsl:template>

</xsl:stylesheet>