File: configure.in

package info (click to toggle)
pinot 0.95-1
  • links: PTS, VCS
  • area: main
  • in suites: squeeze
  • size: 6,860 kB
  • ctags: 4,511
  • sloc: cpp: 39,387; sh: 9,973; ansic: 4,174; makefile: 657; xml: 372; python: 260
file content (474 lines) | stat: -rw-r--r-- 14,352 bytes parent folder | download
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
# generated 2005/12/14 20:48:47 SGT by fabrice@amra.dyndns.org.(none)
# using glademm V2.6.0

AC_PREREQ(2.50)
AC_INIT(pinot, 0.95,[fabricecolin@users.berlios.de])
AM_INIT_AUTOMAKE
AC_CONFIG_HEADERS(config.h)

AC_ISC_POSIX
AC_PROG_CC
AM_PROG_CC_STDC
AC_HEADER_STDC
AC_PROG_CPP
AC_PROG_CXX
AC_PROG_CXXCPP
AM_PROG_LIBTOOL

dnl An index with a version older than this should be upgraded
AC_DEFINE_UNQUOTED(PINOT_INDEX_MIN_VERSION,"0.92",
    [Minimum index version])

dnl gettext support
GETTEXT_PACKAGE=pinot
AC_SUBST(GETTEXT_PACKAGE)
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",
		[the gettext domain])

dnl Add the languages which your application supports here.
ALL_LINGUAS="de es fr he it ja nl pt pt_BR ru sv zh_CN zh_TW"
#AM_GNU_GETTEXT([external]) 
AM_GLIB_GNU_GETTEXT

dnl Set PACKAGE_LOCALE_DIR in config.h.
if test "x${prefix}" = "xNONE"; then
  AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR, "${ac_default_prefix}/${DATADIRNAME}/locale",
		[Define to the location of locale files.])
else
  AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR, "${prefix}/${DATADIRNAME}/locale",
		[Define to the location of locale files.])
fi
dnl And set PREFIX in config.h.
if test "x${prefix}" = "xNONE"; then
  AC_DEFINE_UNQUOTED(PREFIX, "${ac_default_prefix}",
		[Define to the package prefix.])
else
  AC_DEFINE_UNQUOTED(PREFIX, "${prefix}",
		[Define to the package prefix.])
fi

AS_AC_EXPAND(DATADIR, $datadir)
AS_AC_EXPAND(BINDIR, $bindir)

dnl Location of system directories
AS_AC_EXPAND(SYSCONFDIR, $sysconfdir)
AC_DEFINE_UNQUOTED(SYSCONFDIR, "$SYSCONFDIR",
		[Define to the system configuration directory.])
AS_AC_EXPAND(LIBDIR, $libdir)
AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR",
		[Define to the libraries directory.])

dnl Set DBUS_SERVICES_DIR in de.berlios.Pinot.service.
DBUS_SERVICES_DIR="$DATADIR/dbus-1/services"
AC_SUBST(BINDIR)
AC_SUBST(DBUS_SERVICES_DIR)
AC_DEFINE_UNQUOTED(DBUS_SERVICES_DIR, "$DBUS_SERVICES_DIR",
		[Define to the DBUS services directory.])

AC_LANG_CPLUSPLUS

AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
AC_PATH_PROG(DESKTOP_INSTALL, desktop-file-install, no)

dnl DEBUG mode
CXXFLAGS="-fPIC $CXXFLAGS"
AC_MSG_CHECKING(whether to enable DEBUG mode)
AC_ARG_ENABLE(debug,
   [AS_HELP_STRING([--enable-debug], [enable debug [default=no]])],
   ,[enable_debug=no])
if test "x$enable_debug" = "xyes"; then
   if test "x$GCC" = "xyes"; then
      CXXFLAGS="$CXXFLAGS -ggdb3 -O0 -DDEBUG"
   fi
else
   CXXFLAGS="$CXXFLAGS -DNDEBUG"
   enable_debug="no"
fi
AC_MSG_RESULT($enable_debug)

dnl Set compiler specific flags
VISIB_CFLAGS=""
if test "x$GCC" = "xyes"; then
gxx_version=`$CXX --version 2>&1 | head -1 | $SED 's/^[[^ ]]* (GCC) //;s/ .*//'`
case $gxx_version in
4.*)
VISIB_CFLAGS="-fvisibility=hidden"
;;
*)
dnl Other versions
;;
esac
fi

dnl SOAP API support
AC_MSG_CHECKING(whether to enable SOAP support)
AC_ARG_ENABLE(soap,
   [AS_HELP_STRING([--enable-soap], [enable SOAP support [default=no]])],
   ,[enable_soap=no])
if test "x$enable_soap" != "xyes"; then
   SOAP_CFLAGS=""
   SOAP_LIBS=""
   enable_soap=no
fi
AC_MSG_RESULT($enable_soap)
AM_CONDITIONAL(HAVE_SOAP, false)
if test "x$enable_soap" = "xyes"; then
   PKG_CHECK_MODULES(SOAP, gsoap)
   SOAP_CFLAGS="-DHAVE_GOOGLEAPI $SOAP_CFLAGS"
   AM_CONDITIONAL(HAVE_SOAP, true)
fi
AC_SUBST(SOAP_CFLAGS)
AC_SUBST(SOAP_LIBS)

dnl Xesam GLib
AC_MSG_CHECKING(whether to enable Xesam GLib support)
AC_ARG_ENABLE(xesam-glib,
   [AS_HELP_STRING([--enable-xesam-glib], [enable Xesam GLib support [default=no]])],
   ,[enable_xesam_glib=no])
if test "x$enable_xesam_glib" != "xyes"; then
   XESAMGLIB_CFLAGS=""
   XESAMGLIB_LIBS=""
   enable_xesam_glib=no
fi
AC_MSG_RESULT($enable_xesam_glib)
AM_CONDITIONAL(HAVE_XESAM_GLIB, false)
if test "x$enable_xesam_glib" = "xyes"; then
   PKG_CHECK_MODULES(XESAMGLIB, xesam-glib)
   AM_CONDITIONAL(HAVE_XESAM_GLIB, true)
fi
AC_SUBST(XESAMGLIB_CFLAGS)
AC_SUBST(XESAMGLIB_LIBS)

dnl DBus
AC_MSG_CHECKING(whether to enable DBus support)
AC_ARG_ENABLE(dbus,
   [AS_HELP_STRING([--enable-dbus], [enable DBus support [default=yes]])],
   ,[enable_dbus=yes])
if test "x$enable_dbus" != "xyes"; then
   DBUS_CFLAGS=""
   DBUS_LIBS=""
   enable_dbus=no
fi
AC_MSG_RESULT($enable_dbus)
AM_CONDITIONAL(HAVE_DBUS, false)
if test "x$enable_dbus" = "xyes"; then
   PKG_CHECK_MODULES(DBUS, dbus-glib-1)
   DBUS_NUM_VERSION=`pkg-config --modversion dbus-1 | $AWK 'BEGIN { FS = "."; } { printf "%d", ($1 * 1000 + $2) * 1000 + $3;}'`
   AC_DEFINE_UNQUOTED(DBUS_NUM_VERSION,$DBUS_NUM_VERSION, [DBus version number])
   AM_CONDITIONAL(HAVE_DBUS, true)
fi
AC_SUBST(DBUS_CFLAGS)
AC_SUBST(DBUS_LIBS)

dnl Neon or Curl ?
AC_MSG_CHECKING(which HTTP library to use)
AC_ARG_WITH(http,
   [AS_HELP_STRING([--with-http=@<:@neon|curl@:>@], [which HTTP library to use [default=curl]])])
httplibrary=$with_http
if test "x$httplibrary" = "x"; then
   httplibrary="curl"
fi
AC_MSG_RESULT($httplibrary)

testforssl="no"
case "$httplibrary" in
neon)
PKG_CHECK_MODULES(NEON, neon >= 0.24 )
testforssl="yes"
EXTRA_HTTP_CFLAGS="-DUSE_NEON -DUSE_SSL"
HTTP_DOWNLOADER="NeonDownloader"
;;
curl)
AC_PATH_PROG(CURL_CONFIG, curl-config, no)
if test "$CURL_CONFIG" = "no" ; then
   AC_MSG_ERROR([Can't find curl-config in $PATH.])
   exit 1
fi
CURL_CFLAGS=`$CURL_CONFIG --cflags`
CURL_LIBS=`$CURL_CONFIG --libs`
AC_MSG_CHECKING(whether curl needs OpenSSL)
CURL_SSL_FEATURE=`$CURL_CONFIG --features | grep -i SSL`
if test "x$CURL_SSL_FEATURE" = "x"; then
   EXTRA_HTTP_CFLAGS="-DUSE_CURL"
   AC_MSG_RESULT(no)
else
   EXTRA_HTTP_CFLAGS="-DUSE_CURL -DUSE_SSL"
   AC_MSG_RESULT(yes)
   testforssl="yes"
fi
HTTP_DOWNLOADER="CurlDownloader"
;;
esac
AC_SUBST(HTTP_DOWNLOADER)

dnl OpenSSL
dnl If no path is provided, fall back on pkg-config
if test "$testforssl" = "yes" ; then
   AC_ARG_WITH(ssl,
   [AS_HELP_STRING([--with-ssl=PATH], [where to look for OpenSSL [default=/usr/local/ssl]])])
   sslpath=$with_ssl
   dnl We want a prefix, not yes or no
   case "$sslpath" in
   yes)
   sslpath="/usr/local/ssl"
   ;;
   no)
   sslpath="/usr/local/ssl"
   ;;
   esac

   if test "x$sslpath" = "x"; then
      PKG_CHECK_MODULES(SSL, openssl >= 0.9.7 )
   else
      SSL_CFLAGS="-I$sslpath/include -I$sslpath/include/openssl"
      SSL_LIBS="-L$sslpath/lib -lssl -lcrypto"
   fi
fi

dnl Xapian
AC_PATH_PROG(XAPIAN_CONFIG, xapian-config, no)
if test "$XAPIAN_CONFIG" = "no" ; then
   AC_MSG_ERROR([Can't find xapian-config in $PATH.])
   exit 1
fi
XAPIAN_CFLAGS=`$XAPIAN_CONFIG --cxxflags`
XAPIAN_LIBS=`$XAPIAN_CONFIG --libs`
XAPIAN_NUM_VERSION=`xapian-config --version | $SED -e "s/xapian-config - xapian-core //g" | $AWK 'BEGIN { FS = "."; } { printf "%d", ($1 * 1000 + $2) * 1000 + $3;}'`
AC_DEFINE_UNQUOTED(XAPIAN_NUM_VERSION,$XAPIAN_NUM_VERSION,
    [Xapian version number])
AC_MSG_CHECKING(for Xapian >= 1.0.4)
if test $XAPIAN_NUM_VERSION -gt 1000002; then
   AC_MSG_RESULT(yes)
else
   AC_MSG_RESULT(no)
   AC_MSG_ERROR([You need at least Xapian 1.0.4])
   exit 1
fi

dnl inotify
AM_CONDITIONAL(HAVE_LINUX_INOTIFY, false)
AC_CHECK_HEADERS([sys/inotify.h],
   [AM_CONDITIONAL(HAVE_LINUX_INOTIFY, true)
   ])

dnl boost
AM_CONDITIONAL(HAVE_BOOST_SPIRIT, false)
AC_CHECK_HEADERS([boost/spirit/core.hpp],
   [AM_CONDITIONAL(HAVE_BOOST_SPIRIT, true)
   ])
AC_MSG_CHECKING(whether to enable the memory pool)
AC_ARG_ENABLE(mempool,
   [AS_HELP_STRING([--enable-mempool], [enable memory pool [default=yes]])],
   ,[enable_mempool=yes])
if test "x$enable_mempool" != "xno"; then
   enable_mempool="yes"
fi
AC_MSG_RESULT($enable_mempool)
if test "x$enable_mempool" = "xyes"; then
   AC_CHECK_HEADERS([boost/pool/poolfwd.hpp])
fi

dnl TextCat
AC_CHECK_HEADERS([textcat.h],,
   [AC_CHECK_HEADERS([libtextcat/textcat.h])
   ])
AC_CHECK_LIB(textcat, textcat_Cat,
   [AM_CONDITIONAL(HAVE_TEXTCAT_CAT, true)],
   [AM_CONDITIONAL(HAVE_TEXTCAT_CAT, false)]
   )

dnl libarchive
AC_MSG_CHECKING(whether to enable the libarchive filter)
AC_ARG_ENABLE(libarchive,
   [AS_HELP_STRING([--enable-libarchive], [enable the libarchive filter [default=no]])],
   ,[enable_libarchive=no])
if test "x$enable_libarchive" != "xyes"; then
   enable_libarchive=no
   AM_CONDITIONAL(HAVE_LIBARCHIVE, false)
else
   AM_CONDITIONAL(HAVE_LIBARCHIVE, true)
fi
AC_MSG_RESULT($enable_libarchive)

dnl pthreads
pthreadlib=""
AC_SUBST(PTHREAD_LIBS)
AC_MSG_CHECKING(if pthreads is available)
ORIG_LIBS="$LIBS"
for candidatelib in '' '-pthread' '-lc_r' '-lthr'; do
   if test -z "$use_posix_mutex" ; then
      LIBS="$candidatelib $ORIG_LIBS"
      AC_TRY_LINK([#include <pthread.h>],
         [pthread_mutex_t lck;
         pthread_mutex_init(&lck, 0);
         pthread_mutex_lock(&lck);
         pthread_mutex_unlock(&lck);
         pthread_mutex_destroy(&lck);],
         [PTHREAD_LIBS="$candidatelib"
         pthreadlib=candidatelib]
      )
   fi
done
LIBS="$ORIG_LIBS"
if test "$pthreadlib" ; then
   if test -z "$PTHREAD_LIBS" ; then
      AC_MSG_RESULT(yes)
   else
      AC_MSG_RESULT([yes with $PTHREAD_LIBS])
   fi
else
   AC_MSG_RESULT(no)
   AC_CHECK_LIB(pthreadGCE2, pthread_mutex_lock,
      [PTHREAD_CFLAGS="-Ipthread"
       PTHREAD_LIBS="-lpthreadGCE2"])

   if test -z "$PTHREAD_LIBS" ; then
      AC_MSG_ERROR([Can't find pthreads.])
      exit 1
   fi
fi

dnl Check whether we can use GIO instead of xdgmime
AM_CONDITIONAL(HAVE_GIO_MIME, false)
AC_MSG_CHECKING([if gio can sniff png])
AC_ARG_ENABLE(gio,
   [AS_HELP_STRING([--enable-gio], [enable gio [default=test]])],
   ,[enable_gio=test])
if test "x$enable_gio" = "xyes"; then
   gio_can_sniff=yes
   AM_CONDITIONAL(HAVE_GIO_MIME, true)
else if test "x$enable_gio" = "xno"; then
   gio_can_sniff=no
   AM_CONDITIONAL(HAVE_GIO_MIME, false)
else
   dnl This test is from gtk's configure.in, with some modifications
   gtk_save_LIBS="$LIBS"
   gtk_save_CFLAGS="$CFLAGS"
   gtk_save_CXXFLAGS="$CXXFLAGS"
   LIBS="`$PKG_CONFIG --libs gio-2.0`"
   CFLAGS="`$PKG_CONFIG --cflags gio-2.0`"
   CXXFLAGS="`$PKG_CONFIG --cflags gio-2.0`"
   AC_RUN_IFELSE([AC_LANG_SOURCE([[
  #include <string.h>
  #include <gio/gio.h>
  static const gsize data_size = 159;
  static const guint8 data[] = 
  {
    0x89, 0x50, 0x4e, 0x47, 0x0d, 0x0a, 0x1a, 0x0a, 0x00, 0x00, 0x00, 0x0d, 
    0x49, 0x48, 0x44, 0x52, 0x00, 0x00, 0x00, 0x01, 0x00, 0x00, 0x00, 0x01, 
    0x08, 0x02, 0x00, 0x00, 0x00, 0x90, 0x77, 0x53, 0xde, 0x00, 0x00, 0x00, 
    0x01, 0x73, 0x52, 0x47, 0x42, 0x00, 0xae, 0xce, 0x1c, 0xe9, 0x00, 0x00, 
    0x00, 0x09, 0x70, 0x48, 0x59, 0x73, 0x00, 0x00, 0x0b, 0x13, 0x00, 0x00, 
    0x0b, 0x13, 0x01, 0x00, 0x9a, 0x9c, 0x18, 0x00, 0x00, 0x00, 0x07, 0x74, 
    0x49, 0x4d, 0x45, 0x07, 0xd8, 0x07, 0x0f, 0x10, 0x08, 0x15, 0x61, 0xd8, 
    0x35, 0x37, 0x00, 0x00, 0x00, 0x19, 0x74, 0x45, 0x58, 0x74, 0x43, 0x6f, 
    0x6d, 0x6d, 0x65, 0x6e, 0x74, 0x00, 0x43, 0x72, 0x65, 0x61, 0x74, 0x65, 
    0x64, 0x20, 0x77, 0x69, 0x74, 0x68, 0x20, 0x47, 0x49, 0x4d, 0x50, 0x57, 
    0x81, 0x0e, 0x17, 0x00, 0x00, 0x00, 0x0c, 0x49, 0x44, 0x41, 0x54, 0x08, 
    0xd7, 0x63, 0xf8, 0xff, 0xff, 0x3f, 0x00, 0x05, 0xfe, 0x02, 0xfe, 0xdc, 
    0xcc, 0x59, 0xe7, 0x00, 0x00, 0x00, 0x00, 0x49, 0x45, 0x4e, 0x44, 0xae, 
    0x42, 0x60, 0x82
  };
  int
  main (int argc, char **argv)
  {
    char *content_type;
    char *mime_type;
    content_type = g_content_type_guess (NULL, data, data_size, NULL);  
    mime_type = g_content_type_get_mime_type (content_type);
    return !!strcmp (mime_type, "image/png");
  }]])],
  [gio_can_sniff=yes
   AM_CONDITIONAL(HAVE_GIO_MIME, true)],
  [gio_can_sniff=no])
   LIBS="$gtk_save_LIBS"
   CFLAGS="$gtk_save_CFLAGS"
   CXXFLAGS="$gtk_save_CXXFLAGS"
fi
fi
AC_MSG_RESULT($gio_can_sniff)

dnl Other libraries
MISC_CFLAGS="$PTHREAD_CFLAGS $VISIB_CFLAGS -D_FILE_OFFSET_BITS=64"
MISC_LIBS="$PTHREAD_LIBS"
AC_SUBST(MISC_CFLAGS)
AC_SUBST(MISC_LIBS)
AC_CHECK_HEADERS([sys/vfs.h sys/statfs.h sys/mount.h sys/statvfs.h attr/xattr.h dlfcn.h regex.h fnmatch.h pwd.h ext/malloc_allocator.h])
PKG_CHECK_MODULES(MIMEINFO, shared-mime-info )
SHARED_MIME_INFO_PREFIX=`pkg-config --variable=prefix shared-mime-info`
AC_SUBST(SHARED_MIME_INFO_PREFIX)
AC_DEFINE_UNQUOTED(SHARED_MIME_INFO_PREFIX,"$SHARED_MIME_INFO_PREFIX",
    [the shared-mime-info prefix])
PKG_CHECK_MODULES(EXIF, libexif >= 0.6 )
AC_SUBST(EXIF_CFLAGS)
AC_SUBST(EXIF_LIBS)
PKG_CHECK_MODULES(TAGLIB, taglib >= 1.4 )
AC_SUBST(TAGLIB_CFLAGS)
AC_SUBST(TAGLIB_LIBS)
PKG_CHECK_MODULES(SQL, sqlite3 >= 3.1 )
AC_SUBST(SQL_CFLAGS)
AC_SUBST(SQL_LIBS)
HTTP_CFLAGS="$NEON_CFLAGS $CURL_CFLAGS $SSL_CFLAGS $EXTRA_HTTP_CFLAGS"
HTTP_LIBS="$NEON_LIBS $CURL_LIBS $SSL_LIBS"
AC_SUBST(HTTP_CFLAGS)
AC_SUBST(HTTP_LIBS)
PKG_CHECK_MODULES(GMIME, gmime-2.4 >= 2.0 )
AC_SUBST(GMIME_CFLAGS)
AC_SUBST(GMIME_LIBS)
PKG_CHECK_MODULES(XML, libxml++-2.6 >= 2.12 )
AC_SUBST(XML_CFLAGS)
AC_SUBST(XML_LIBS)
INDEX_CFLAGS="$XAPIAN_CFLAGS"
INDEX_LIBS="$XAPIAN_LIBS -ltextcat"
AC_SUBST(INDEX_CFLAGS)
AC_SUBST(INDEX_LIBS)
PKG_CHECK_MODULES(SIGCPP, sigc++-2.0 >= 2.0 )
AC_SUBST(SIGCPP_CFLAGS)
AC_SUBST(SIGCPP_LIBS)
PKG_CHECK_MODULES(GTHREAD, gthread-2.0 >= 2.6 )
AC_SUBST(GTHREAD_CFLAGS)
AC_SUBST(GTHREAD_LIBS)
PKG_CHECK_MODULES(GLIBMM, glibmm-2.4 >= 2.6 )
AC_SUBST(GLIBMM_CFLAGS)
AC_SUBST(GLIBMM_LIBS)
PKG_CHECK_MODULES(GTKMM, gtkmm-2.4 >= 2.10 )
AC_SUBST(GTKMM_CFLAGS)
AC_SUBST(GTKMM_LIBS)
if test "$gio_can_sniff" = "yes" ; then
PKG_CHECK_MODULES(GIO, gio-2.0)
GLIBMM_CFLAGS=" -DUSE_GIO $GIO_CFLAGS $GLIBMM_CFLAGS"
GLIBMM_LIBS="$GIO_LIBS $GLIBMM_LIBS"
GTKMM_CFLAGS=" -DUSE_GIO $GIO_CFLAGS $GTKMM_CFLAGS"
GTKMM_LIBS="$GIO_LIBS $GTKMM_LIBS"
fi

dnl Check for specific functions
AC_CHECK_FUNCS(fork)
AC_CHECK_FUNCS(getloadavg)
AC_CHECK_FUNCS(gettimeofday)
AC_CHECK_FUNCS(gmtime_r)
AC_CHECK_FUNCS(kill)
AC_CHECK_FUNCS(localtime_r)
AC_CHECK_FUNCS(lstat)
AC_CHECK_FUNCS(madvise)
AC_CHECK_FUNCS(mallinfo)
AC_CHECK_FUNCS(malloc_trim)
AC_CHECK_FUNCS(mkstemp)
AC_CHECK_FUNCS(mmap)
AC_CHECK_FUNCS(pipe)
AC_CHECK_FUNCS(setrlimit)
AC_CHECK_FUNCS(sigaction)
AC_CHECK_FUNCS(socketpair)
AC_CHECK_FUNCS(statfs)
AC_CHECK_FUNCS(statvfs)
AC_CHECK_FUNCS(strptime)
AC_CHECK_FUNCS(sysconf)
AC_CHECK_FUNCS(sysctlbyname)
AC_CHECK_FUNCS(timegm)
AC_CHECK_FUNCS(vsnprintf)

AC_OUTPUT( pinot.spec Core/de.berlios.Pinot.service Makefile \
	Utils/Makefile Tokenize/Makefile SQL/Makefile po/Makefile.in Collect/Makefile \
	IndexSearch/Google/Makefile IndexSearch/Xapian/Makefile IndexSearch/XesamGLib/Makefile \
	IndexSearch/Makefile Monitor/Makefile Core/Makefile UI/GTK2/src/Makefile )