File: dh-make-node

package info (click to toggle)
pkg-js-tools 0.15.23
  • links: PTS, VCS
  • area: main
  • in suites: forky, sid, trixie
  • size: 1,980 kB
  • sloc: perl: 4,921; sh: 842; makefile: 36; javascript: 22
file content (255 lines) | stat: -rwxr-xr-x 6,047 bytes parent folder | download | duplicates (2)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
#!/usr/bin/perl

use strict;
use warnings;
use Debian::Copyright;
use Debian::PkgJs::Lib;
use Debian::PkgJs::Npm;
use Debian::PkgJs::Version;
use File::Basename qw(basename);
use POSIX qw(strftime);

my $basename = basename($0);

sub usage {
    print <<EOF;
Usage: $basename

$basename prepares a debian/ directory by reading package.json of a node package.

Launch it in a debian/node source repository.

Copyright (C) 2019 Andrius Merkys <merkys\@debian.org>

Licensed under GPL-2+ (see /usr/share/common-licenses/GPL-2)
EOF
}

if (@ARGV) {
    if ( $ARGV[0] eq '--version' ) {
        print $VERSION, "\n";
    }
    else {
        usage();
    }
    exit;
}

my $package = pjson('.') || die "$basename: no 'package.json'";

my $name        = $package->{name};
my $source      = "node-$name";
my $version     = $package->{version};
my $license     = $package->{license};
my $author      = $package->{author};
my $description = $package->{description};
my $homepage    = $package->{homepage};
my $test        = $package->{scripts}{test};

my $debfullname = $ENV{DEBFULLNAME};
my $debemail    = $ENV{DEBEMAIL};

my $date = strftime( "%a, %d %b %Y %H:%M:%S %z", localtime( time() ) );

my $upstream_vcs_url;
my $upstream_vcs_type;
if ( $package->{repository} && ref $package->{repository} eq 'HASH' ) {
    $upstream_vcs_url  = $package->{repository}{url};
    $upstream_vcs_type = $package->{repository}{type};
}

# Using GitHub's anonymous HTTPS cloning URLs instead of git@github.com:
if ( $upstream_vcs_type && $upstream_vcs_type eq 'git' ) {
    $upstream_vcs_url =~ s|^git\@(github\.com):|https://$1/|;
    $upstream_vcs_url =~ s|\.git$||;
}

mkdir('debian');

my $out;

#-------------- debian/changelog -----------

if ( !-e 'debian/changelog' ) {
    system( 'dch', '--create', '--newversion', "$version-1",
        '--package', $source, 'Initial release (Closes: #nnnn)' );
}

#-------------- debian/rules ---------------

open( $out, '>', 'debian/rules' );
print $out <<END;
#!/usr/bin/make -f

%:
\tdh \$@ --buildsystem nodejs
END
close $out;
chmod 0755, 'debian/rules';

#-------------- debian/copyright -----------

my $copyright = Debian::Copyright->new();
my $header    = Debian::Copyright::Stanza::Header->new(
    {
        Disclaimer => 'Autogenerated by dh-make-node',
        Format     =>
          'https://www.debian.org/doc/packaging-manuals/copyright-format/1.0/',
        Source             => $upstream_vcs_url,
        'Upstream-Contact' => $author,
        'Upstream-Name'    => $name,
    }
);
$copyright->header($header);

if ( !$license ) {
    warn "$basename: license information is not found in package.json\n";
}

$copyright->files->Push(
    '*',
    Debian::Copyright::Stanza::Files->new(
        {
            Files     => '*',
            Copyright => $author,
            License   => $license,
        }
    )
);

$copyright->files->Push(
    'debian/*',
    Debian::Copyright::Stanza::Files->new(
        {
            Files     => 'debian/*',
            Copyright => "$debfullname <$debemail>",
            License   => $license,
        }
    )
);

$copyright->licenses->Push(
    $license,
    Debian::Copyright::Stanza::License->new(
        {
            License => $license,
        }
    )
);

$copyright->write('debian/copyright');

#-------------- debian/control ---------------

my @dependencies = resolve_dependencies( $package->{dependencies} );
push @dependencies, resolve_dependencies( $package->{peerDependencies} );
my @devDependencies = resolve_dependencies( $package->{devDependencies} );

my @build_depends = (
    'debhelper-compat (= 12)',
    'pkg-js-tools', @dependencies, map { "$_ <!nocheck>" } @devDependencies
);

my @depends = ( '${misc:Depends}', @dependencies );

my $build_depends = join "\n", map { " $_," } sort @build_depends;
my $depends       = join "\n", map { " $_," } sort @depends;

my $homepage_line = 'Homepage: ';
if ($homepage) {
    $homepage_line .= $homepage;
}
else {
    $homepage_line = "#$homepage_line<insert URL if applicable>";
}

open( $out, '>', 'debian/control' );
print $out <<END;
Source: $source
Section: javascript
Priority: optional
Maintainer: Debian Javascript Maintainers <pkg-javascript-devel\@lists.alioth.debian.org>
Uploaders:
 $debfullname <$debemail>,
Build-Depends:
$build_depends
Standards-Version: 4.4.0
Rules-Requires-Root: no
$homepage_line
Vcs-Browser: https://salsa.debian.org/js-team/$source
Vcs-Git: https://salsa.debian.org/js-team/$source.git
END

print $out "Testsuite: autopkgtest-pkg-nodejs\n" if $test;

print $out <<END;

Package: $source
Architecture: all
Depends:
$depends
Description: $description
END
close $out;

#-------------- debian/watch -----------------

if (   $upstream_vcs_type
    && $upstream_vcs_type eq 'git'
    && $upstream_vcs_url =~ /github/ )
{
    open( $out, '>', 'debian/watch' );
    print $out "version=4\n";
    print $out git_watch($upstream_vcs_url);
    close $out;
}

#-------------- debian/source/format ---------

mkdir('debian/source');
open( $out, '>', 'debian/source/format' );
print $out "3.0 (quilt)\n";
close $out;

#------------ debian/tests/pkg-js/test ---------

if ($test) {
    mkdir('debian/tests');
    mkdir('debian/tests/pkg-js');

    # Using system-provided test runners:
    $test =~ s|^\./node_modules/\.bin/||;

    open( $out, '>', 'debian/tests/pkg-js/test' );
    print $out <<END;
#!/bin/bash

$test
END
    close $out;
}

sub resolve_dependencies {
    my ($dependencies) = @_;
    return () if !$dependencies;

    my @deb_dependencies;
    for my $dep ( sort keys %$dependencies ) {
        if ( $dep !~ /^[a-z0-9\-\.]+$/ ) {
            warn
              "$basename: dependency name '$dep' looks suspicious, skipping\n";
            next;
        }
        my $pkg = `nodepath -o $dep 2>/dev/null`;
        if ( !$pkg ) {
            warn
"$basename: dependency '$dep' cannot be found, is it installed?\n";
            next;
        }

        $pkg =~ s/\n$//;
        push @deb_dependencies, $pkg if $pkg;
    }

    return sort @deb_dependencies;
}