1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
|
/*
SPDX-FileCopyrightText: 2022 Aditya Mehra <aix.m@outlook.com>
SPDX-FileCopyrightText: 2019 Marco Martin <mart@kde.org>
SPDX-License-Identifier: GPL-2.0-or-later
*/
import QtQuick 2.14
import QtQuick.Layouts 1.14
import QtGraphicalEffects 1.14
import QtQuick.Controls 2.14
import org.kde.plasma.core 2.0 as PlasmaCore
import org.kde.plasma.components 3.0 as PlasmaComponents
import org.kde.kirigami 2.13 as Kirigami
import org.kde.mycroft.bigscreen 1.0 as BigScreen
AbstractDelegate {
id: delegate
implicitWidth: listView.cellWidth
implicitHeight: listView.height
property var iconImage
property string comment
property bool useIconColors: true
property bool compactMode: false
property bool hasComment: commentLabel.text.length > 5 ? 1 : 0
Kirigami.Theme.inherit: !imagePalette.useColors
Kirigami.Theme.textColor: imagePalette.textColor
Kirigami.Theme.backgroundColor: imagePalette.backgroundColor
Kirigami.Theme.highlightColor: imagePalette.accentColor
Kirigami.ImageColors {
id: imagePalette
source: iconItem.source
property bool useColors: useIconColors
property color backgroundColor: useColors ? dominantContrast : PlasmaCore.ColorScope.backgroundColor
property color accentColor: useColors ? highlight : PlasmaCore.ColorScope.highlightColor
property color textColor: useColors
? (Kirigami.ColorUtils.brightnessForColor(dominantContrast) === Kirigami.ColorUtils.Light ? imagePalette.closestToBlack : imagePalette.closestToWhite)
: PlasmaCore.ColorScope.textColor
}
contentItem: Item {
id: content
GridLayout {
id: topArea
width: parent.width
height: parent.height * 0.25
anchors.top: parent.top
columns: 2
Behavior on columns {
PauseAnimation {
duration: Kirigami.Units.longDuration / 2
}
}
PlasmaCore.IconItem {
id: iconItem
Layout.preferredWidth: topArea.columns > 1 ? parent.height * 0.75 : (delegate.compactMode ? parent.height / 2 : parent.height)
Layout.preferredHeight: width
source: delegate.iconImage || delegate.icon.name || delegate.icon.source ? delegate.iconImage || delegate.icon.name || delegate.icon.source : "application-x-executable"
Behavior on Layout.preferredWidth {
ParallelAnimation {
NumberAnimation {
duration: Kirigami.Units.longDuration / 2;
easing.type: Easing.InOutQuad
}
NumberAnimation {
target: textLabel
from: 0
to: 1
properties: "opacity"
duration: delegate.hasComment ? Kirigami.Units.longDuration * 3 : 0
easing.type: Easing.InOutQuad
}
}
}
}
Rectangle {
Layout.fillWidth: true
Layout.fillHeight: true
color: "transparent"
Label {
id: textLabel
width: parent.width
height: parent.height
wrapMode: Text.WordWrap
verticalAlignment: Text.AlignVCenter
font.pixelSize: delegate.compactMode ? width * 0.2 : height * 0.9
font.bold: true
fontSizeMode: Text.Fit
minimumPixelSize: 2
maximumLineCount: 1
elide: Text.ElideRight
text: delegate.text
color: imagePalette.textColor
}
}
}
Label {
id: commentLabel
anchors.top: topArea.bottom
anchors.bottom: parent.bottom
anchors.topMargin: Kirigami.Units.largeSpacing
verticalAlignment: Text.AlignTop
width: parent.width
height: parent.height
font.pixelSize: height * 0.25
maximumLineCount: 2
elide: Text.ElideRight
wrapMode: Text.WordWrap
text: delegate.comment
color: imagePalette.textColor
Behavior on opacity {
NumberAnimation { duration: Kirigami.Units.longDuration * 2.5; easing.type: Easing.InOutQuad }
}
}
}
states: [
State {
name: "selectedNoComment"
when: delegate.isCurrent && !hasComment
PropertyChanges {
target: delegate
implicitWidth: delegate.compactMode ? listView.cellWidth + (listView.cellWidth / 1.25) : listView.cellWidth
}
PropertyChanges {
target: topArea
height: content.height
columns: 1
rows: 2
}
PropertyChanges {
target: iconItem
Layout.preferredHeight: parent.height * 0.75
Layout.preferredWidth: height
Layout.alignment: Qt.AlignHCenter
}
PropertyChanges {
target: textLabel
horizontalAlignment: Text.AlignHCenter
}
PropertyChanges {
target: commentLabel
opacity: 0
}
},
State {
name: "selectedWithComment"
when: delegate.isCurrent && hasComment
PropertyChanges {
target: delegate
implicitWidth: delegate.compactMode ? listView.cellWidth + (listView.cellWidth / 1.25) : listView.cellWidth
}
PropertyChanges {
target: topArea
height: parent.height * 0.25
columns: 2
}
PropertyChanges {
target: commentLabel
opacity: 1
}
},
State {
name: "normal"
when: !delegate.isCurrent
PropertyChanges {
target: topArea
height: content.height
columns: 1
rows: 2
}
PropertyChanges {
target: iconItem
Layout.preferredHeight: delegate.compactMode ? parent.height / 2 : parent.height * 0.75
Layout.preferredWidth: height
Layout.alignment: Qt.AlignHCenter
}
PropertyChanges {
target: textLabel
horizontalAlignment: Text.AlignHCenter
}
PropertyChanges {
target: commentLabel
opacity: 0
}
}
]
}
|
