1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
|
/*
SPDX-FileCopyrightText: 2016 Marco Martin <mart@kde.org>
SPDX-FileCopyrightText: 2020 Nate Graham <nate@kde.org>
SPDX-License-Identifier: LGPL-2.0-or-later
*/
import QtQuick
import QtQuick.Layouts
import org.kde.kirigami as Kirigami
import org.kde.plasma.components as PlasmaComponents
import org.kde.plasma.core as PlasmaCore
import org.kde.plasma.extras as PlasmaExtras
import org.kde.plasma.plasmoid
Item {
id: popup
Layout.minimumWidth: Kirigami.Units.gridUnit * 24
Layout.minimumHeight: Kirigami.Units.gridUnit * 24
property alias hiddenLayout: hiddenItemsView.layout
property alias plasmoidContainer: container
// Header
PlasmaExtras.PlasmoidHeading {
id: plasmoidHeading
anchors {
top: parent.top
left: parent.left
right: parent.right
}
height: trayHeading.height + bottomPadding + container.headingHeight
Behavior on height {
NumberAnimation { duration: Kirigami.Units.shortDuration / 2; easing.type: Easing.InOutQuad }
}
}
// Main content layout
ColumnLayout {
id: expandedRepresentation
anchors.fill: parent
// TODO: remove this so the scrollview fully touches the header;
// add top padding internally
spacing: plasmoidHeading.bottomPadding
// Header content layout
RowLayout {
id: trayHeading
Layout.fillWidth: true
PlasmaComponents.ToolButton {
id: backButton
visible: systemTrayState.activeApplet && systemTrayState.activeApplet.expanded && (hiddenLayout.itemCount > 0)
icon.name: mirrored ? "go-previous-symbolic-rtl" : "go-previous-symbolic"
display: PlasmaComponents.AbstractButton.IconOnly
text: i18nc("@action:button", "Go Back")
KeyNavigation.down: hiddenItemsView.visible ? hiddenLayout : container
onClicked: systemTrayState.setActiveApplet(null)
}
Kirigami.Heading {
Layout.fillWidth: true
leftPadding: systemTrayState.activeApplet ? 0 : Kirigami.Units.largeSpacing
level: 1
text: systemTrayState.activeApplet ? systemTrayState.activeApplet.plasmoid.title : i18n("Status and Notifications")
textFormat: Text.PlainText
elide: Text.ElideRight
}
Repeater {
id: primaryActionButtons
model: {
if (actionsButton.applet === null) {
return [];
}
return actionsButton.applet.plasmoid.contextualActions.filter(action => {
return !action.isSeparator && action.priority === PlasmaCore.Action.HighPriority;
});
}
delegate: PlasmaComponents.ToolButton {
// We cannot use `action` as it is already a QQuickAction property of the button
property QtObject qAction: model.modelData
visible: qAction && qAction.visible
// NOTE: it needs an IconItem because QtQuickControls2 buttons cannot load QIcons as their icon
contentItem: Kirigami.Icon {
anchors.centerIn: parent
active: parent.hovered
implicitWidth: Kirigami.Units.iconSizes.smallMedium
implicitHeight: implicitWidth
source: parent.qAction ? parent.qAction.icon.name : ""
}
enabled: qAction && qAction.enabled
checkable: qAction && qAction.checkable
checked: qAction && qAction.checked
display: PlasmaComponents.AbstractButton.IconOnly
text: qAction ? qAction.text : ""
KeyNavigation.down: backButton.KeyNavigation.down
KeyNavigation.left: (index > 0) ? primaryActionButtons.itemAt(index - 1) : backButton
KeyNavigation.right: (index < primaryActionButtons.count - 1) ? primaryActionButtons.itemAt(index + 1) :
actionsButton.visible ? actionsButton : actionsButton.KeyNavigation.right
PlasmaComponents.ToolTip {
text: parent.text
}
onClicked: {
if (qAction) {
qAction.trigger();
}
}
}
}
PlasmaComponents.ToolButton {
id: actionsButton
visible: visibleActions > 0
enabled: visibleActions > 1 || (singleAction && singleAction.enabled)
checked: visibleActions > 1 ? configMenu.status !== PlasmaExtras.Menu.Closed : singleAction && singleAction.checked
property QtObject applet: systemTrayState.activeApplet || root
property int visibleActions: menuItemFactory.count
property QtObject singleAction: visibleActions === 1 && menuItemFactory.object ? menuItemFactory.object.action : null
icon.name: "application-menu"
checkable: visibleActions > 1 || (singleAction && singleAction.checkable)
contentItem.opacity: visibleActions > 1
display: PlasmaComponents.AbstractButton.IconOnly
text: actionsButton.singleAction ? actionsButton.singleAction.text : i18n("More actions")
Accessible.role: actionsButton.singleAction ? Accessible.Button : Accessible.ButtonMenu
KeyNavigation.down: backButton.KeyNavigation.down
KeyNavigation.right: configureButton.visible ? configureButton : configureButton.KeyNavigation.right
// NOTE: it needs a Kirigami.Icon because QtQuickControls2 buttons cannot load QIcons as their icon
Kirigami.Icon {
parent: actionsButton
anchors.centerIn: parent
active: actionsButton.hovered
implicitWidth: Kirigami.Units.iconSizes.smallMedium
implicitHeight: implicitWidth
source: actionsButton.singleAction !== null ? actionsButton.singleAction.icon.name : ""
visible: actionsButton.singleAction
}
onToggled: {
if (visibleActions > 1) {
if (checked) {
configMenu.openRelative();
} else {
configMenu.close();
}
}
}
onClicked: {
if (singleAction) {
singleAction.trigger();
}
}
PlasmaComponents.ToolTip {
text: parent.text
}
PlasmaExtras.Menu {
id: configMenu
visualParent: actionsButton
placement: PlasmaExtras.Menu.BottomPosedLeftAlignedPopup
}
Instantiator {
id: menuItemFactory
model: {
configMenu.clearMenuItems();
if (!actionsButton.applet) {
return [];
}
return actionsButton.applet.plasmoid.contextualActions
.filter(action => {
return action.visible &&
action.priority === PlasmaCore.Action.NormalPriority &&
action !== actionsButton.applet.plasmoid.internalAction("configure");
})
// squash separators
.reduce((dstActions, action, i, srcActions) => {
if (!action.isSeparator) {
const prevAction = srcActions[i - 1];
if (prevAction?.isSeparator && dstActions.length > 0) {
dstActions.push(prevAction);
}
dstActions.push(action);
}
return dstActions;
}, []);
}
delegate: PlasmaExtras.MenuItem {
id: menuItem
action: modelData
}
onObjectAdded: (index, object) => {
configMenu.addMenuItem(object);
}
}
}
PlasmaComponents.ToolButton {
id: configureButton
icon.name: "configure"
visible: actionsButton.applet && actionsButton.applet.plasmoid.internalAction("configure")
display: PlasmaComponents.AbstractButton.IconOnly
text: actionsButton.applet.plasmoid.internalAction("configure") ? actionsButton.applet.plasmoid.internalAction("configure").text : ""
KeyNavigation.down: backButton.KeyNavigation.down
KeyNavigation.left: actionsButton.visible ? actionsButton : actionsButton.KeyNavigation.left
KeyNavigation.right: pinButton
PlasmaComponents.ToolTip {
text: parent.visible ? parent.text : ""
}
onClicked: actionsButton.applet.plasmoid.internalAction("configure").trigger();
}
PlasmaComponents.ToolButton {
id: pinButton
checkable: true
checked: Plasmoid.configuration.pin
onToggled: Plasmoid.configuration.pin = checked
icon.name: "window-pin"
display: PlasmaComponents.AbstractButton.IconOnly
text: i18n("Keep Open")
KeyNavigation.down: backButton.KeyNavigation.down
KeyNavigation.left: configureButton.visible ? configureButton : configureButton.KeyNavigation.left
KeyNavigation.tab: hiddenItemsView.visible ? hiddenItemsView.layout : container.currentItem?.nextItemInFocusChain() ?? null
PlasmaComponents.ToolTip {
text: parent.text
}
}
}
// Grid view of all available items
HiddenItemsView {
id: hiddenItemsView
Layout.fillWidth: true
Layout.fillHeight: true
Layout.topMargin: Kirigami.Units.smallSpacing
visible: !systemTrayState.activeApplet
KeyNavigation.up: pinButton
onVisibleChanged: {
if (visible) {
layout.forceActiveFocus();
systemTrayState.oldVisualIndex = systemTrayState.newVisualIndex = -1;
}
}
}
// Container for currently visible item
PlasmoidPopupsContainer {
id: container
Layout.fillWidth: true
Layout.fillHeight: true
visible: systemTrayState.activeApplet
// We need to add margin on the top so it matches the dialog's own margin
Layout.topMargin: mergeHeadings ? 0 : dialog.topPadding
KeyNavigation.up: pinButton
KeyNavigation.backtab: pinButton
onVisibleChanged: {
if (visible) {
forceActiveFocus();
}
}
}
}
// Footer
PlasmaExtras.PlasmoidHeading {
id: plasmoidFooter
position: PlasmaComponents.ToolBar.Footer
anchors {
bottom: parent.bottom
left: parent.left
right: parent.right
}
visible: container.appletHasFooter
height: container.footerHeight
// So that it doesn't appear over the content view, which results in
// the footer controls being inaccessible
z: -9999
}
}
|
