File: x16f.f90

package info (click to toggle)
plplot 5.15.0%2Bdfsg-19
  • links: PTS, VCS
  • area: main
  • in suites: bullseye
  • size: 31,312 kB
  • sloc: ansic: 79,707; xml: 28,583; cpp: 20,033; ada: 19,456; tcl: 12,081; f90: 11,431; ml: 7,276; java: 6,863; python: 6,792; sh: 3,274; perl: 828; lisp: 75; makefile: 50; sed: 34; fortran: 5
file content (497 lines) | stat: -rw-r--r-- 18,410 bytes parent folder | download | duplicates (4)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
!      plshades demo, using color fill
!
!      Copyright (C) 2004-2016  Alan W. Irwin
!
!      This file is part of PLplot.
!
!      PLplot is free software; you can redistribute it and/or modify
!      it under the terms of the GNU Library General Public License as
!      published by the Free Software Foundation; either version 2 of the
!      License, or (at your option) any later version.
!
!      PLplot is distributed in the hope that it will be useful,
!      but WITHOUT ANY WARRANTY; without even the implied warranty of
!      MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
!      GNU Library General Public License for more details.
!
!      You should have received a copy of the GNU Library General Public
!      License along with PLplot; if not, write to the Free Software
!      Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA

!     N.B. the pl_test_flt parameter used in this code is only
!     provided by the plplot module to allow convenient developer
!     testing of either kind(1.0) or kind(1.0d0) floating-point
!     precision regardless of the floating-point precision of the
!     PLplot C libraries.  We do not guarantee the value of this test
!     parameter so it should not be used by users, and instead user
!     code should replace the pl_test_flt parameter by whatever
!     kind(1.0) or kind(1.0d0) precision is most convenient for them.
!     For further details on floating-point precision issues please
!     consult README_precision in this directory.
!
program x16f
    use plplot, double_PI => PL_PI
    use iso_c_binding, only: c_ptr, c_loc, c_f_pointer
    implicit none
    real(kind=pl_test_flt), parameter :: PI = double_PI
    real(kind=pl_test_flt) xx, yy, argx, argy, distort, r, t
    integer NLEVEL, NX, NY, PERIMETERPTS, xdim, ydim
    parameter(NLEVEL = 20)
    !      xdim and ydim are the static dimensions of the 2D arrays while
    !      NX and NY are the defined area.
    parameter(xdim=99, NX = 35)
    parameter(ydim=100, NY = 46)
    parameter(PERIMETERPTS = 100)
    real(kind=pl_test_flt) clevel(NLEVEL), shedge(NLEVEL+1), &
           z(xdim,ydim), w(xdim,ydim), xg1(xdim), yg1(ydim), &
           xg2(xdim,ydim), yg2(xdim,ydim), zmin, zmax, &
           px(PERIMETERPTS), py(PERIMETERPTS)
    integer cont_color
    real(kind=pl_test_flt) fill_width, cont_width
    real(kind=pl_test_flt) colorbar_width, colorbar_height
    integer NUM_AXES, NUM_LABELS
    parameter(NUM_AXES=1, NUM_LABELS=1)
    character(len=20) :: axis_opts(NUM_AXES)
    integer num_values(NUM_AXES)
    real(kind=pl_test_flt) values(NUM_AXES,NLEVEL+1)
    real(kind=pl_test_flt) axis_ticks(NUM_AXES)
    integer axis_subticks(NUM_AXES)
    character(len=100) :: labels(NUM_LABELS)
    integer label_opts(NUM_LABELS)

    integer i, j
    integer :: plparseopts_rc
    real(kind=pl_test_flt) tr(6)

    ! Global parameters to be used in mypltr callback
    real(kind=pl_test_flt), parameter :: xmin = -1.0_pl_test_flt
    real(kind=pl_test_flt), parameter :: xmax =  1.0_pl_test_flt
    real(kind=pl_test_flt), parameter :: ymin = -1.0_pl_test_flt
    real(kind=pl_test_flt), parameter :: ymax =  1.0_pl_test_flt

    ! Use no callback?
    logical, parameter :: no_callback = .false.

    ! Use tr callback? (only meaningful
    ! if no_callback is .false.).
    logical, parameter :: tr_callback = .false.

    ! Use Fortran callback with no data? (only meaningful
    ! if no_callback and tr_callback are .false.).
    logical, parameter :: mypltr_callback = .false.

    type mypltr_data_type
        ! Only contains data required by the mypltr_data callback
        integer :: xpts_data, ypts_data
        real(kind=pl_test_flt) :: xmin_data, xmax_data, ymin_data, ymax_data
    end type mypltr_data_type

    ! Global data type to be used in mypltr_data callback
    type(mypltr_data_type), target :: data

    data%xpts_data = NX
    data%ypts_data = NY
    data%xmin_data = xmin
    data%xmax_data = xmax
    data%ymin_data = ymin
    data%ymax_data = ymax

    tr = (/ (xmax-xmin)/real(NX-1,kind=pl_test_flt), 0.0_pl_test_flt, xmin, &
           0.0_pl_test_flt, (ymax-ymin)/real(NY-1,kind=pl_test_flt), ymin /)

    !      Process command-line arguments
    plparseopts_rc = plparseopts(PL_PARSE_FULL)
    if(plparseopts_rc .ne. 0) stop "plparseopts error"

    !      Load color palettes
    call plspal0('cmap0_black_on_white.pal')
    call plspal1('cmap1_gray.pal', .true.)

    !      Reduce colors in cmap 0 so that cmap 1 is useful on a 16-color display
    call plscmap0n(3)

    !      Initialize plplot

    call plinit()

    !      Calculate the data matrices.
    do i=1,NX
        xx = real(i-1-(NX/2),kind=pl_test_flt)/real(NX/2,kind=pl_test_flt)
        do j=1,NY
            yy = real(j-1-(NY/2),kind=pl_test_flt)/real(NY/2,kind=pl_test_flt) - 1.0_pl_test_flt
            z(i,j) = - sin(7._pl_test_flt*xx) * cos(7._pl_test_flt*yy) + xx*xx - yy*yy
            w(i,j) = - cos(7._pl_test_flt*xx) * sin(7._pl_test_flt*yy) + 2._pl_test_flt*xx*yy
        enddo
    enddo

    call a2mnmx(z, NX, NY, zmin, zmax, xdim)
    do i = 1, NLEVEL
        clevel(i) = zmin + (zmax - zmin) * (i - 0.5_pl_test_flt) / real(NLEVEL,kind=pl_test_flt)
    enddo
    do i = 1, NLEVEL+1
        shedge(i) = zmin + (zmax - zmin) * real(i-1,kind=pl_test_flt) / real(NLEVEL,kind=pl_test_flt)
    enddo

    !      Build the 1-d coord arrays.
    distort = 0.4_pl_test_flt
    do i=1,NX
        xx = -1._pl_test_flt + real(i-1,kind=pl_test_flt)*2._pl_test_flt/real(NX-1,kind=pl_test_flt)
        xg1(i) = xx + distort*cos(0.5_pl_test_flt*PI*xx)
    enddo

    do j=1,NY
        yy = -1._pl_test_flt + real(j-1,kind=pl_test_flt)*2._pl_test_flt/real(NY-1,kind=pl_test_flt)
        yg1(j) = yy - distort*cos(0.5_pl_test_flt*PI*yy)
    enddo

    !      Build the 2-d coord arrays.
    do i=1,NX
        xx = -1._pl_test_flt + real(i-1,kind=pl_test_flt)*2._pl_test_flt/real(NX-1,kind=pl_test_flt)
        argx = 0.5_pl_test_flt*PI*xx
        do j=1,NY
            yy = -1._pl_test_flt + real(j-1,kind=pl_test_flt)*2._pl_test_flt/real(NY-1,kind=pl_test_flt)
            argy = 0.5_pl_test_flt*PI*yy
            xg2(i,j) = xx + distort*cos(argx)*cos(argy)
            yg2(i,j) = yy - distort*cos(argx)*cos(argy)
        enddo
    enddo

    !      Plot using transform of index range to xmin, xmax, ymin, ymax
    call pladv(0)
    call plvpor(0.1_pl_test_flt, 0.9_pl_test_flt, 0.1_pl_test_flt, 0.9_pl_test_flt)
    call plwind(-1.0_pl_test_flt, 1.0_pl_test_flt, -1.0_pl_test_flt, 1.0_pl_test_flt)

    call plpsty(0)

    fill_width = 2
    cont_color = 0
    cont_width = 0
    axis_opts(1) = 'bcvtm'
    axis_ticks(1) = 0.0_pl_test_flt
    axis_subticks(1) = 0
    label_opts(1) = PL_COLORBAR_LABEL_BOTTOM
    labels(1) = 'Magnitude'

    if(no_callback) then
        call plshades(z(:NX,:NY), -1._pl_test_flt, 1._pl_test_flt, -1._pl_test_flt, &
               1._pl_test_flt, &
               shedge, fill_width, &
               cont_color, cont_width, .true. )
    elseif(tr_callback) then
        call plshades(z(:NX,:NY), -1._pl_test_flt, 1._pl_test_flt, -1._pl_test_flt, &
               1._pl_test_flt, &
               shedge, fill_width, &
               cont_color, cont_width, .true., tr )
    elseif(mypltr_callback) then
        call plshades(z(:NX,:NY), -1._pl_test_flt, 1._pl_test_flt, -1._pl_test_flt, &
               1._pl_test_flt, &
               shedge, fill_width, &
               cont_color, cont_width, .true., mypltr )
    else
        call plshades(z(:NX,:NY), -1._pl_test_flt, 1._pl_test_flt, -1._pl_test_flt, &
               1._pl_test_flt, &
               shedge, fill_width, &
               cont_color, cont_width, .true., mypltr_data, c_loc(data) )
    endif

    ! Smaller text
    call  plschr( 0.0_pl_test_flt, 0.75_pl_test_flt )
    ! Small ticks on the vertical axis
    call plsmaj( 0.0_pl_test_flt, 0.5_pl_test_flt )
    call plsmin( 0.0_pl_test_flt, 0.5_pl_test_flt )

    num_values(1) = NLEVEL + 1;
    values(1,:)   = shedge;
    call plcolorbar( colorbar_width, colorbar_height, &
           ior(PL_COLORBAR_SHADE, PL_COLORBAR_SHADE_LABEL), 0, &
           0.005_pl_test_flt, 0.0_pl_test_flt, 0.0375_pl_test_flt, 0.875_pl_test_flt, 0, 1, 1, &
           0.0_pl_test_flt, 0.0_pl_test_flt, &
           cont_color, cont_width, &
           label_opts, labels, &
           axis_opts, &
           axis_ticks, axis_subticks, &
           num_values, values )

    ! Reset text and tick sizes
    call plschr( 0.0_pl_test_flt, 1.0_pl_test_flt )
    call plsmaj( 0.0_pl_test_flt, 1.0_pl_test_flt )
    call plsmin( 0.0_pl_test_flt, 1.0_pl_test_flt )

    call plcol0(1)
    call plbox('bcnst', 0.0_pl_test_flt, 0, 'bcnstv', 0.0_pl_test_flt, 0)
    call plcol0(2)
    call pllab('distance', 'altitude', 'Bogon density')

    !      Plot using 1d coordinate transform

    call plspal0('cmap0_black_on_white.pal')
    call plspal1('cmap1_blue_yellow.pal', .true.)
    call plscmap0n(3)

    call pladv(0)
    call plvpor(0.1_pl_test_flt, 0.9_pl_test_flt, 0.1_pl_test_flt, 0.9_pl_test_flt)
    call plwind(-1.0_pl_test_flt, 1.0_pl_test_flt, -1.0_pl_test_flt, 1.0_pl_test_flt)

    call plpsty(0)

    fill_width = 2
    cont_color = 0
    cont_width = 0
    call plshades(z(:NX,:NY), -1._pl_test_flt, 1._pl_test_flt, -1._pl_test_flt, &
           1._pl_test_flt, &
           shedge, fill_width, &
           cont_color, cont_width, .true., xg1(:NX), yg1(:NY))

    ! Smaller text
    call  plschr( 0.0_pl_test_flt, 0.75_pl_test_flt )
    ! Small ticks on the vertical axis
    call plsmaj( 0.0_pl_test_flt, 0.5_pl_test_flt )
    call plsmin( 0.0_pl_test_flt, 0.5_pl_test_flt )

    num_values(1) = NLEVEL + 1;
    values(1,:)   = shedge;
    call plcolorbar( colorbar_width, colorbar_height, &
           ior(PL_COLORBAR_SHADE, PL_COLORBAR_SHADE_LABEL), 0, &
           0.005_pl_test_flt, 0.0_pl_test_flt, 0.0375_pl_test_flt, 0.875_pl_test_flt, 0, 1, 1, &
           0.0_pl_test_flt, 0.0_pl_test_flt, &
           cont_color, cont_width, &
           label_opts, labels, &
           axis_opts, &
           axis_ticks, axis_subticks, &
           num_values, values )

    ! Reset text and tick sizes
    call plschr( 0.0_pl_test_flt, 1.0_pl_test_flt )
    call plsmaj( 0.0_pl_test_flt, 1.0_pl_test_flt )
    call plsmin( 0.0_pl_test_flt, 1.0_pl_test_flt )

    call plcol0(1)
    call plbox('bcnst', 0.0_pl_test_flt, 0, 'bcnstv', 0.0_pl_test_flt, 0)
    call plcol0(2)
    call pllab('distance', 'altitude', 'Bogon density')

    !      Plot using 2d coordinate transform

    call plspal0('cmap0_black_on_white.pal')
    call plspal1('cmap1_blue_red.pal', .true.)
    call plscmap0n(3)

    call pladv(0)
    call plvpor(0.1_pl_test_flt, 0.9_pl_test_flt, 0.1_pl_test_flt, 0.9_pl_test_flt)
    call plwind(-1.0_pl_test_flt, 1.0_pl_test_flt, -1.0_pl_test_flt, 1.0_pl_test_flt)

    call plpsty(0)

    fill_width = 2
    cont_color = 0
    cont_width = 0
    call plshades(z(:NX,:NY), -1._pl_test_flt, 1._pl_test_flt, -1._pl_test_flt, &
           1._pl_test_flt, &
           shedge, fill_width, &
           cont_color, cont_width, .false., xg2(:NX,:NY), yg2(:NX,:NY) )

    ! Smaller text
    call  plschr( 0.0_pl_test_flt, 0.75_pl_test_flt )
    ! Small ticks on the vertical axis
    call plsmaj( 0.0_pl_test_flt, 0.5_pl_test_flt )
    call plsmin( 0.0_pl_test_flt, 0.5_pl_test_flt )

    num_values(1) = NLEVEL + 1;
    values(1,:)   = shedge;
    call plcolorbar( colorbar_width, colorbar_height, &
           ior(PL_COLORBAR_SHADE, PL_COLORBAR_SHADE_LABEL), 0, &
           0.005_pl_test_flt, 0.0_pl_test_flt, 0.0375_pl_test_flt, 0.875_pl_test_flt, 0, 1, 1, &
           0.0_pl_test_flt, 0.0_pl_test_flt, &
           cont_color, cont_width, &
           label_opts, labels, &
           axis_opts, &
           axis_ticks, axis_subticks, &
           num_values, values )

    ! Reset text and tick sizes
    call plschr( 0.0_pl_test_flt, 1.0_pl_test_flt )
    call plsmaj( 0.0_pl_test_flt, 1.0_pl_test_flt )
    call plsmin( 0.0_pl_test_flt, 1.0_pl_test_flt )

    call plcol0(1)
    call plbox('bcnst', 0.0_pl_test_flt, 0, 'bcnstv', 0.0_pl_test_flt, 0)
    call plcol0(2)
    call plcont(w, 1, nx, 1, ny, clevel, xg2, yg2)
    call pllab('distance', 'altitude', &
           'Bogon density, with streamlines')

    !      Plot using 2d coordinate transform and plshades contours.
    call plspal0('')
    call plspal1('', .true. )
    call plscmap0n(3)

    call pladv(0)
    call plvpor(0.1_pl_test_flt, 0.9_pl_test_flt, 0.1_pl_test_flt, 0.9_pl_test_flt)
    call plwind(-1.0_pl_test_flt, 1.0_pl_test_flt, -1.0_pl_test_flt, 1.0_pl_test_flt)

    call plpsty(0)

    fill_width = 2
    cont_color = 2
    cont_width = 3
    call plshades(z(:NX,:NY), -1._pl_test_flt, 1._pl_test_flt, -1._pl_test_flt, &
           1._pl_test_flt, &
           shedge, fill_width, &
           cont_color, cont_width, .false., xg2(:NX,:NY), yg2(:NX,:NY) )

    ! Smaller text
    call  plschr( 0.0_pl_test_flt, 0.75_pl_test_flt )
    ! Small ticks on the vertical axis
    call plsmaj( 0.0_pl_test_flt, 0.5_pl_test_flt )
    call plsmin( 0.0_pl_test_flt, 0.5_pl_test_flt )

    num_values(1) = NLEVEL + 1;
    values(1,:)   = shedge;
    call plcolorbar( colorbar_width, colorbar_height, &
           ior(PL_COLORBAR_SHADE, PL_COLORBAR_SHADE_LABEL), 0, &
           0.005_pl_test_flt, 0.0_pl_test_flt, 0.0375_pl_test_flt, 0.875_pl_test_flt, 0, 1, 1, &
           0.0_pl_test_flt, 0.0_pl_test_flt, &
           2, 3._pl_test_flt, &
           label_opts, labels, &
           axis_opts, &
           axis_ticks, axis_subticks, &
           num_values, values )

    ! Reset text and tick sizes
    call plschr( 0.0_pl_test_flt, 1.0_pl_test_flt )
    call plsmaj( 0.0_pl_test_flt, 1.0_pl_test_flt )
    call plsmin( 0.0_pl_test_flt, 1.0_pl_test_flt )

    call plcol0(1)
    call plbox('bcnst', 0.0_pl_test_flt, 0, 'bcnstv', 0.0_pl_test_flt, 0)
    call plcol0(2)
    call pllab('distance', 'altitude', 'Bogon density')

    !      Example with polar coordinates.
    call plspal0('cmap0_black_on_white.pal')
    call plspal1('cmap1_gray.pal', .true. )
    call plscmap0n(3)

    call pladv(0)
    call plvpor(0.1_pl_test_flt, 0.9_pl_test_flt, 0.1_pl_test_flt, 0.9_pl_test_flt)
    call plwind(-1._pl_test_flt, 1._pl_test_flt, -1._pl_test_flt, 1._pl_test_flt)

    call plpsty(0)

    !      Build new coordinate matrices.
    do i = 1, NX
        r = real(i-1,kind=pl_test_flt)/real(NX-1,kind=pl_test_flt)
        do j = 1, NY
            t = (2._pl_test_flt*PI/real(NY-1,kind=pl_test_flt))*real(j-1,kind=pl_test_flt)
            xg2(i,j) = r*cos(t)
            yg2(i,j) = r*sin(t)
            z(i,j) = exp(-r*r)*cos(5._pl_test_flt*PI*r)*cos(5._pl_test_flt*t)
        enddo
    enddo

    !      Need a new shedge to go along with the new data set.
    call a2mnmx(z, NX, NY, zmin, zmax, xdim)
    do i = 1, NLEVEL+1
        shedge(i) = zmin + (zmax - zmin) * real(i-1,kind=pl_test_flt) / real(NLEVEL,kind=pl_test_flt)
    enddo

    !      Now we can shade the interior region.
    fill_width = 2
    cont_color = 0
    cont_width = 0
    call plshades(z(:NX,:NY), -1._pl_test_flt, 1._pl_test_flt, -1._pl_test_flt, &
           1._pl_test_flt, &
           shedge, fill_width, &
           cont_color, cont_width, .false., xg2(:NX,:NY), yg2(:NX,:NY) )

    ! Smaller text
    call  plschr( 0.0_pl_test_flt, 0.75_pl_test_flt )
    ! Small ticks on the vertical axis
    call plsmaj( 0.0_pl_test_flt, 0.5_pl_test_flt )
    call plsmin( 0.0_pl_test_flt, 0.5_pl_test_flt )

    num_values(1) = NLEVEL + 1;
    values(1,:)   = shedge;
    call plcolorbar( colorbar_width, colorbar_height, &
           ior(PL_COLORBAR_SHADE, PL_COLORBAR_SHADE_LABEL), 0, &
           0.005_pl_test_flt, 0.0_pl_test_flt, 0.0375_pl_test_flt, 0.875_pl_test_flt, 0, 1, 1, &
           0.0_pl_test_flt, 0.0_pl_test_flt, &
           cont_color, cont_width, &
           label_opts, labels, &
           axis_opts, &
           axis_ticks, axis_subticks, &
           num_values, values )

    ! Reset text and tick sizes
    call plschr( 0.0_pl_test_flt, 1.0_pl_test_flt )
    call plsmaj( 0.0_pl_test_flt, 1.0_pl_test_flt )
    call plsmin( 0.0_pl_test_flt, 1.0_pl_test_flt )

    !      Now we can draw the perimeter.  (If do before, shade stuff may overlap.)
    do i = 1, PERIMETERPTS
        t = (2._pl_test_flt*PI/real(PERIMETERPTS-1,kind=pl_test_flt))*real(i-1,kind=pl_test_flt)
        px(i) = cos(t)
        py(i) = sin(t)
    enddo

    call plcol0(1)
    call plline(px, py)

    !      And label the plot.
    call plcol0(2)
    call pllab( '', '',  'Tokamak Bogon Instability' )

    call plend

contains

    ! Callback function that relies on global NX, NY, xmin, xmax, ymin, ymax
    subroutine mypltr( x, y, xt, yt )

        ! These callback arguments must have exactly these attributes.
        real(kind=pl_test_flt), intent(in) ::  x, y
        real(kind=pl_test_flt), intent(out) :: xt, yt

        xt = xmin + ((xmax-xmin)/real(NX-1,kind=pl_test_flt))*x
        yt = ymin + ((ymax-ymin)/real(NY-1,kind=pl_test_flt))*y

    end subroutine mypltr

    ! Callback function that uses data argument to pass required data.
    subroutine mypltr_data( x, y, xt, yt, data )

        ! These callback arguments must have exactly these attributes.
        real(kind=pl_test_flt), intent(in) ::  x, y
        real(kind=pl_test_flt), intent(out) :: xt, yt
        type(c_ptr), intent(in) :: data

        type(mypltr_data_type), pointer :: d
        call c_f_pointer(data, d)

        xt = d%xmin_data + ((d%xmax_data-d%xmin_data)/real(d%xpts_data-1,kind=pl_test_flt))*x
        yt = d%ymin_data + ((d%ymax_data-d%ymin_data)/real(d%ypts_data-1,kind=pl_test_flt))*y

    end subroutine mypltr_data


    !----------------------------------------------------------------------------
    !      Subroutine a2mnmx
    !      Minimum and the maximum elements of a 2-d array.

    subroutine a2mnmx(f, nx, ny, fmin, fmax, xdim)
        use plplot
        implicit none

        integer   i, j, nx, ny, xdim
        real(kind=pl_test_flt)    f(xdim, ny), fmin, fmax

        fmax = f(1, 1)
        fmin = fmax
        do j = 1, ny
            do  i = 1, nx
                fmax = max(fmax, f(i, j))
                fmin = min(fmin, f(i, j))
            enddo
        enddo
    end subroutine a2mnmx
end program x16f