1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
|
<well-known text representation> ::=
<point text representation> |
<curve text representation> |
<surface text representation> |
<collection text representation>
<point text representation> ::= POINT [ <z m> ] <point text>
<curve text representation> ::=
<linestring text representation> |
<circularstring text representation> |
<compoundcurve text representation>
<linestring text representation> ::=
LINESTRING [ <z m> ] <linestring text body>
<circularstring text representation> ::=
CIRCULARSTRING [ <z m> ] <circularstring text>
<compoundcurve text representation> ::=
COMPOUNDCURVE [ <z m> ] <compoundcurve text>
<surface text representation> ::=
<curvepolygon text representation>
<curvepolygon text representation> ::=
CURVEPOLYGON [ <z m> ] <curvepolygon text body> |
<polygon text representation> |
<triangle text representation>
<polygon text representation> ::=
POLYGON [ <z m> ] <polygon text body>
<triangle text representation> ::=
TRIANGLE [ <z m> ] <triangle text body>
<collection text representation> ::=
<multipoint text representation> |
<multicurve text representation> |
<multisurface text representation> |
<geometrycollection text representation>
<multipoint text representation> ::=
MULTIPOINT [ <z m> ] <multipoint text>
<multicurve text representation> ::=
MULTICURVE [ <z m> ] <multicurve text> |
<multilinestring text representation>
<multilinestring text representation> ::=
MULTILINESTRING [ <z m> ] <multilinestring text>
<multisurface text representation> ::=
MULTISURFACE [ <z m> ] <multisurface text> |
<multipolygon text representation> |
<polyhedralsurface text representation> |
<tin text representation>
<multipolygon text representation> ::=
MULTIPOLYGON [ <z m> ] <multipolygon text>
<polyhedralsurface text representation> ::=
POLYHEDRALSURFACE [ <z m> ] <polyhedralsurface text>
<tin text representation> ::=
TIN [ <z m> ] <tin text>
<geometrycollection text representation> ::=
GEOMETRYCOLLECTION [ <z m> ] <geometrycollection text>
<linestring text body> ::=
<linestring text>
<curvepolygon text body> ::=
<curvepolygon text>
<polygon text body> ::=
<polygon text>
<triangle text body> ::=
<triangle text>
<point text> ::=
<empty set> |
<left paren> <point> <right paren>
<point> ::= <x> <y> [ <z> ] [ <m> ]
<x> ::= <number>
<y> ::= <number>
<z> ::= <number>
<m> ::= <number>
<linestring text> ::=
<empty set> |
<left paren> <point> { <comma> <point> }... <right paren>
<circularstring text> ::=
<empty set> |
<left paren> <point> { <comma> <point> }... <right paren>
<compoundcurve text> ::=
<empty set> |
<left paren> <single curve text> { <comma> <single curve text> }... <right paren>
<single curve text> ::=
<linestring text body> |
<circularstring text representation>
<curve text> ::=
<linestring text body> |
<circularstring text representation> |
<compoundcurve text representation>
<ring text> ::=
<linestring text body> |
<circularstring text representation> |
<compoundcurve text representation>
<surface text> ::=
CURVEPOLYGON <curvepolygon text body> |
<polygon text body>
<curvepolygon text> ::=
<empty set> |
<left paren> <ring text> { <comma> <ring text> }... <right paren>
<polygon text> ::=
<empty set> |
<left paren> <linestring text> { <comma> <linestring text> }... <right paren>
<triangle text> ::=
<empty set> |
<left paren> <linestring text> <right paren>
<multipoint text> ::=
<empty set> |
<left paren> <point text> { <comma> <point text > }... <right paren>
<multicurve text> ::=
<empty set> |
<left paren> <curve text> { <comma> <curve text> }... <right paren>
<multilinestring text> ::=
<empty set> |
<left paren> <linestring text body> { <comma> <linestring text body> }... <right paren>
<multisurface text> ::=
<empty set> |
<left paren> <surface text> { <comma> <surface text> }... <right paren>
<multipolygon text> ::=
<empty set> |
<left paren> <polygon text body> { <comma> <polygon text body> }... <right paren>
<polyhedralsurface text> ::=
<empty set> |
<left paren> <polygon text body> { <comma> <polygon text body> }... <right paren>
<tin text> ::=
<empty set> |
<left paren> <triangle text body> { <comma> <triangle text body> }... <right paren>
<geometrycollection text> ::=
<empty set> |
<left paren> <well-known text representation> { <comma> <well-known text representation> }... <right paren>
<empty set> ::= EMPTY
<z m> ::= ZM | Z | M
<left paren> ::= (
<right paren> ::= )
|
