1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
|
// POV-Ray 3.6 / 3.7 Scene File "function3_derived.pov"
// by Friedrich A. Lohmueller, Feb-2013
//------------------------------------------------------------------------
// Choose image_size by
// adding to the command line:
//
// +w700 +h700
//
//------------------------------------------------------------------------
#version 3.7;
global_settings{ assumed_gamma 1.0 }
#default{ finish{ ambient 0.1 diffuse 0.9 }}
//------------------------------------------------------------------------
//------------------------------------------------------------------------
#include "colors.inc"
#include "textures.inc"
//------------------------------------------------------------------------
#declare Camera_0 = camera { perspective
location < 0.00, 0.00,-40.0>
look_at < 0.00, 0.00, 0.00>
angle 15.7
right x*image_width/image_height
}
camera{Camera_0}
//------------------------------------------------------------------------
// sun -------------------------------------------------------------------
light_source{<1000,1000,-2500> color White}
// sky -------------------------------------------------------------------
sky_sphere{ pigment{ gradient <0,1,0>
color_map{ [0 color rgb<1,1,1> ]//White
[0.4 color rgb<0.14,0.14,0.56>]//~Navy
[0.6 color rgb<0.14,0.14,0.56>]//~Navy
[1.0 color rgb<1,1,1> ]//White
}
scale 2 }
} // end of sky_sphere
//------------------------------------------------------------------------
//------------------------------ the Axes --------------------------------
//------------------------------------------------------------------------
#macro Axis( AxisLen, Dark_Texture, Light_Texture)
union{
cylinder{ <0,-AxisLen-0.5,0>,<0,AxisLen,0>,0.035
texture{checker texture{Dark_Texture }
texture{Light_Texture}
translate<0.1,0,0.1>}
}
cone{ <0,AxisLen,0>,0.15,<0,AxisLen+0.45,0>,0
texture{Dark_Texture}
}
} // end of union
#end // of macro "Axis()"
//------------------------------------------------------------------------
#macro AxisXY( AxisLenX, AxisLenY, Tex_Dark, Tex_Light)
//--------------------- drawing of 3 Axes --------------------------------
union{
#if (AxisLenX != 0)
object { Axis(AxisLenX, Tex_Dark, Tex_Light) rotate< 0,0,-90>}// x-Axis
text { ttf "arial.ttf", "x", 0.15, 0 texture{Tex_Dark}
scale 0.5 translate <AxisLenX+0.15,0.2,-0.05>}
text { ttf "arial.ttf", "1", 0.15, 0 texture{Tex_Dark}
scale <0.6,0.35,0.6> translate <1.05,-0.35,-0.02>}
text { ttf "arial.ttf", "5", 0.15, 0 texture{Tex_Dark}
scale <0.6,0.35,0.6> translate <5.05,-0.4,-0.02>}
text { ttf "arial.ttf", "-5", 0.15, 0 texture{Tex_Dark}
scale <0.6,0.35,0.6> translate <-5.20,-0.35,-0.02>}
#end // of #if
#if (AxisLenY != 0)
object { Axis(AxisLenY, Tex_Dark, Tex_Light) rotate< 0,0, 0>}// y-Axis
text { ttf "arial.ttf", "y", 0.15, 0 texture{Tex_Dark}
scale 0.5 translate <-0.35,AxisLenY+0.15,-0.05>}
text { ttf "arial.ttf", "1", 0.15, 0 texture{Tex_Dark}
scale <0.6,0.35,0.6> translate <-0.25,0.7,-0.02>}
text { ttf "arial.ttf", "5", 0.15, 0 texture{Tex_Dark}
scale <0.6,0.35,0.6> translate <-0.35,4.7,-0.02>}
text { ttf "arial.ttf", "-5", 0.15, 0 texture{Tex_Dark}
scale <0.6,0.35,0.6> translate <-0.65,-5.3,-0.02>}
#end // of #if
} // end of union
#end// of macro "AxisXY( ... )"
//-------------------------------------------------------------------------
#declare Texture_A_Dark = texture {
pigment{color rgb<1,0.5,0>}
finish {ambient 0.1 diffuse 0.6 phong 1}
}
#declare Texture_A_Light = texture {
pigment{color rgb<1,0.55,0.3>}
finish {ambient 0.1 diffuse 0.6 phong 1}
}
object{ AxisXY( 5.0, 5.0, Texture_A_Dark, Texture_A_Light)}
//-------------------------------------------------- end of coordinate axes
// ground -----------------------------------------------------------------
//---------------------------------<<< settings of squared plane dimensions
#declare RasterScale = 0.5;
#declare RasterHalfLine = 0.05;
#declare RasterHalfLineY = 0.05;
//-------------------------------------------------------------------------
#macro Raster(RScale, HLine)
pigment{ gradient x scale RScale
color_map{[0.000 color rgbt<1,1,1,0>*0.9]
[0+HLine color rgbt<1,1,1,0>*0.9]
[0+HLine color rgbt<1,1,1,1>]
[1-HLine color rgbt<1,1,1,1>]
[1-HLine color rgbt<1,1,1,0>*0.9]
[1.000 color rgbt<1,1,1,0>*0.9]} }
finish { ambient 0.15 diffuse 0.85}
#end// of Raster(RScale, HLine)-macro
//-------------------------------------------------------------------------
plane { <0,1,0>, 0 // plane with layered textures
texture { pigment{color White*1.1}
finish {ambient 0.45 diffuse 0.85}}
texture { Raster(RasterScale,RasterHalfLine ) rotate<0,0,0> }
texture { Raster(RasterScale,RasterHalfLineY) rotate<0,90,0>}
rotate<-90,0,0>
}
//------------------------------------------------ end of squared plane XY
//--------------------------------------------------------------------------
//--------------------------- scenery objects ---------------------------
//--------------------------------------------------------------------------
//------------------------------------------------------------------------
// Choose image_size by
// adding to the command line:
// ( 2nd white field on top
// of the POV-Ray editor! )
//
// +w700 +h700
//
//------------------------------------------------------------------------
#default{ finish {ambient 0.15 diffuse 0.85} } //
//
//
union{
#declare X = -5.5; // start X attention: x != X use capital letter X
#declare EndX = 5.5; // end X
#while ( X < EndX )
// Drawing of the "points"< X / f(X) >:
// Zeichnen der "Punkte" ( X / f(X) ):
// Color - Farbe //< X, f(X) ,0>}
sphere{ <0,0,0>,0.045 pigment{ color rgb<1,0.65,0>} translate< X, 1/4*X*X*(X+4)/(X+2) ,0>}
sphere{ <0,0,0>,0.045 pigment{ color rgb<0.5,1,0> } translate< X, 1/2*X+1/2-2/((X+2)*(X+2)) ,0>}
sphere{ <0,0,0>,0.045 pigment{ color Green*0.5 } translate< X, 1/2+4/((X+2)*(X+2)*(X+2)) ,0>}
// next step:
#declare X = X + 0.005; // next Nr <<<- increase this value, if you have not enough RAM
// or if your computer is too slow!
#end // --------------- end of loop
} // end of union
//------------------------------------------------------------------------------------ end
|
