1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
|
# This file is part of Projecteur - https://github.com/jahnf/projecteur - See LICENSE.md and README.md
cmake_minimum_required(VERSION 3.6)
include(LinuxDistributionInfo)
set(_LinuxPackaging_DIRECTORY "${CMAKE_CURRENT_LIST_DIR}")
set(_LinuxPackaging_cpack_template "LinuxPkgCPackConfig.cmake.in")
list(APPEND _LinuxPackaging_MAP_dist_pkgtype
"debian::DEB"
"ubuntu::DEB"
"opensuse::RPM"
"opensuse-leap::RPM"
"fedora::RPM"
"centos::RPM"
"rhel::RPM"
"arch::PKGBUILD"
"archlinux::PKGBUILD"
)
set(_LinuxPackaging_default_pkgtype "TGZ")
# Function that adds 'dist-package' target
# Arguments:
# PROJECT : Project name to package
# TARGET : Main executable target with version information
# DESCRIPTION_BRIEF : Brief package description.
# DESCRIPTION_FULL : Full package description.
# CONTACT : Package maintainer/contact.
# HOMEAPGE : The project homepage
# DEBIAN_SECTION.....: A valid debian package section (default=devel)
function(add_dist_package_target)
set(oneValueArgs
PROJECT # project name to package
TARGET # main executable build target that has version information attached to it
DESCRIPTION_BRIEF
DESCRIPTION_FULL
CONTACT # Maintainer / contact person
HOMEPAGE
DEBIAN_SECTION
PREINST_SCRIPT
POSTINST_SCRIPT
PRERM_SCRIPT
POSTRM_SCRIPT
)
set(requiredArgs PROJECT TARGET)
cmake_parse_arguments(PKG "" "${oneValueArgs}" "" ${ARGN})
foreach(arg IN LISTS requiredArgs)
if("${PKG_${arg}}" STREQUAL "")
message(FATAL_ERROR "Required argument '${arg}' is not set.")
endif()
endforeach()
if(NOT TARGET ${PKG_TARGET})
message(FATAL_ERROR "Argument 'TARGET' needs to be a valid target.")
endif()
get_target_property(PKG_VERSION_STRING_FULL ${PKG_TARGET} VERSION_STRING_FULL)
get_target_property(PKG_VERSION_STRING ${PKG_TARGET} VERSION_STRING)
get_target_property(PKG_VERSION_MAJOR ${PKG_TARGET} VERSION_MAJOR)
get_target_property(PKG_VERSION_MINOR ${PKG_TARGET} VERSION_MINOR)
get_target_property(PKG_VERSION_PATCH ${PKG_TARGET} VERSION_PATCH)
get_target_property(PKG_VERSION_FLAG ${PKG_TARGET} VERSION_FLAG)
get_target_property(PKG_VERSION_DISTANCE ${PKG_TARGET} VERSION_DISTANCE)
get_target_property(PKG_VERSION_BRANCH ${PKG_TARGET} VERSION_BRANCH)
if("${PKG_VERSION_MAJOR}" STREQUAL "")
set(PKG_VERSION_MAJOR 0)
endif()
if("${PKG_VERSION_MINOR}" STREQUAL "")
set(PKG_VERSION_MINOR 0)
endif()
if("${PKG_VERSION_PATCH}" STREQUAL "")
set(PKG_VERSION_PATCH 0)
endif()
set(PKG_VERSION_STRING_BASE "${PKG_VERSION_MAJOR}.${PKG_VERSION_MINOR}.${PKG_VERSION_PATCH}")
if("${PKG_VERSION_FLAG}" STREQUAL "")
set(PKG_VERSION_IDENTIFIERS "1")
else()
set(PKG_VERSION_IDENTIFIERS "0${PKG_VERSION_FLAG}.${PKG_VERSION_DISTANCE}")
endif()
# Set defaults if not set
if("${PKG_CONTACT}" STREQUAL "")
set(PKG_CONTACT "Generic Maintainer <generic@main.tainer>")
endif()
if("${PKG_DEBIAN_SECTION}" STREQUAL "")
set(PKG_DEBIAN_SECTION "devel")
endif()
find_program(CPACK_COMMAND cpack)
if(NOT CPACK_COMMAND)
message(FATAL_ERROR "CPack command was not found.")
endif()
get_linux_distribution(LINUX_DIST_NAME LINUX_DIST_VERSION)
# Get the package type to be generated by the target from our map variable
set(PKG_TYPE "${_LinuxPackaging_default_pkgtype}")
set(PKG_TYPE_FOUND 0)
foreach(v "${LINUX_DIST_NAME}-${LINUX_DIST_VERSION}" "${LINUX_DIST_NAME}")
foreach(pair ${_LinuxPackaging_MAP_dist_pkgtype})
if( "${pair}" MATCHES "${v}::(.*)")
set(PKG_TYPE "${CMAKE_MATCH_1}")
set(PKG_TYPE_FOUND 1)
break()
endif()
endforeach()
if(PKG_TYPE_FOUND)
break()
endif()
endforeach()
# Check if project package dependencies exist
include(PkgDependencies${PKG_PROJECT} OPTIONAL RESULT_VARIABLE INCLUDED_PROJECT_DEPENDENCIES)
if(INCLUDED_PROJECT_DEPENDENCIES AND PkgDependencies_MAP_${PKG_PROJECT})
set(PKG_DEPENDENCY_FOUND 0)
# Find dependencies for Linux distribution (and version)
foreach(v "${LINUX_DIST_NAME}-${LINUX_DIST_VERSION}" "${LINUX_DIST_NAME}")
foreach(pair ${PkgDependencies_MAP_${PKG_PROJECT}})
if( "${pair}" MATCHES "${v}::(.*)")
if("${PKG_TYPE}" STREQUAL "PKGBUILD")
unset(_install_deps)
foreach(_dep ${${CMAKE_MATCH_1}})
list(APPEND _install_deps "'${_dep}'")
endforeach()
string(REPLACE ";" " " PKG_DEPENDENCIES "${_install_deps}")
else()
string(REPLACE ";" ", " PKG_DEPENDENCIES "${${CMAKE_MATCH_1}}")
endif()
set(PKG_DEPENDENCY_FOUND 1)
break()
endif()
endforeach()
if(PKG_DEPENDENCY_FOUND)
break()
endif()
endforeach()
endif()
if(INCLUDED_PROJECT_DEPENDENCIES AND PkgDependenciesMake_MAP_${PKG_PROJECT})
set(PKG_BUILD_DEPENDENCY_FOUND 0)
# Find dependencies for Linux distribution (and version)
foreach(v "${LINUX_DIST_NAME}-${LINUX_DIST_VERSION}" "${LINUX_DIST_NAME}")
foreach(pair ${PkgDependenciesMake_MAP_${PKG_PROJECT}})
if( "${pair}" MATCHES "${v}::(.*)")
if("${PKG_TYPE}" STREQUAL "PKGBUILD")
unset(_install_deps)
foreach(_dep ${${CMAKE_MATCH_1}})
list(APPEND _install_deps "'${_dep}'")
endforeach()
string(REPLACE ";" " " PKG_BUILD_DEPENDENCIES "${_install_deps}")
else()
string(REPLACE ";" ", " PKG_BUILD_DEPENDENCIES "${${CMAKE_MATCH_1}}")
endif()
set(PKG_BUILD_DEPENDENCY_FOUND 1)
break()
endif()
endforeach()
if(PKG_BUILD_DEPENDENCY_FOUND)
break()
endif()
endforeach()
endif()
string(TOLOWER "${PKG_PROJECT}" PKG_NAME)
set(PKG_LICENSE "MIT")
set(PKG_DIST "${LINUX_DIST_NAME}-${LINUX_DIST_VERSION}")
string(TIMESTAMP PKG_DATE "%Y-%m-%d")
if("${PKG_TYPE}" STREQUAL "PKGBUILD")
_makepkg_packaging()
else()
_cpack_default_packaging()
endif()
configure_file(
"${_LinuxPackaging_DIRECTORY}/travis-ci-bintray-deploy.json.in"
"${CMAKE_CURRENT_BINARY_DIR}/travis-ci-bintray-deploy.json" @ONLY)
message(STATUS "Configured target 'dist-package' with Linux '${PKG_DIST}' and package type '${PKG_TYPE}'")
# Make some information available to parent scope
set(PKG_DIST "${PKG_DIST}" PARENT_SCOPE)
set(PKG_TYPE "${PKG_TYPE}" PARENT_SCOPE)
endfunction()
# makepg packaging (arch linux/pacman)
function(_makepkg_packaging)
get_target_property(PKG_SOURCE_ARCHIVE_PATH source-archive OUTPUT_ARCHIVE)
get_filename_component(PKG_SOURCE_ARCHIVE_DIR "${PKG_SOURCE_ARCHIVE_PATH}" DIRECTORY)
get_filename_component(PKG_SOURCE_ARCHIVE_FILE "${PKG_SOURCE_ARCHIVE_PATH}" NAME)
set(PKG_PKGBUILD_PKGREL 1)
set(PKG_PKGBUILD_ARCH "${CMAKE_SYSTEM_PROCESSOR}")
set(PKG_PKGBUILD_INSTALL_FILE "${PKG_NAME}.install")
set(PKG_PKGBUILD_INSTALL_FILE_PATH "${PKG_SOURCE_ARCHIVE_DIR}/${PKG_PKGBUILD_INSTALL_FILE}")
file(MAKE_DIRECTORY "${PKG_SOURCE_ARCHIVE_DIR}")
file(WRITE "${PKG_PKGBUILD_INSTALL_FILE_PATH}" "# generated install file\n\n")
if(PKG_PREINST_SCRIPT)
file(READ "${PKG_PREINST_SCRIPT}" _pkg_preinst_script_content)
file(APPEND "${PKG_PKGBUILD_INSTALL_FILE_PATH}"
"pre_install() {\n"
" : # null operation in case the preinst file is empty\n"
" ${_pkg_preinst_script_content}"
"}\n\n"
"pre_upgrade() {\n"
" : # null operation in case the preinst file is empty\n"
" ${_pkg_preinst_script_content}"
"}\n\n"
)
endif()
if(PKG_POSTINST_SCRIPT)
file(READ "${PKG_POSTINST_SCRIPT}" _pkg_postinst_script_content)
file(APPEND "${PKG_PKGBUILD_INSTALL_FILE_PATH}"
"post_install() {\n"
" : # null operation in case the preinst file is empty\n"
" ${_pkg_postinst_script_content}"
"}\n\n"
"post_upgrade() {\n"
" : # null operation in case the preinst file is empty\n"
" ${_pkg_postinst_script_content}"
"}\n\n"
)
endif()
if(PKG_PRERM_SCRIPT)
file(READ "${PKG_PRERM_SCRIPT}" _pkg_prerm_script_content)
file(APPEND "${PKG_PKGBUILD_INSTALL_FILE_PATH}"
"pre_remove() {\n"
" : # null operation in case the preinst file is empty\n"
" ${_pkg_prerm_script_content}"
"}\n\n"
)
endif()
if(PKG_POSTRM_SCRIPT)
file(READ "${PKG_POSTRM_SCRIPT}" _pkg_postrm_script_content)
file(APPEND "${PKG_PKGBUILD_INSTALL_FILE_PATH}"
"post_remove() {\n"
" : # null operation in case the preinst file is empty\n"
" ${_pkg_postrm_script_content}"
"}\n\n"
)
endif()
# makepkg: '-' is not allowed in version number
string(REPLACE "-" "" PKG_PKGBUILD_VER "${PKG_VERSION_STRING_FULL}")
set(PKG_CONFIG_TEMPLATE "${_LinuxPackaging_DIRECTORY}/PKGBUILD.in")
set(PKG_CONFIG_FILE "${PKG_SOURCE_ARCHIVE_DIR}/PKGBUILD")
configure_file("${PKG_CONFIG_TEMPLATE}" "${PKG_CONFIG_FILE}" @ONLY)
find_program(MAKEPKG_EXECUTABLE makepkg)
set(PKGBUILD_OUTPUT_FILE "${PKG_NAME}-${PKG_PKGBUILD_VER}-${PKG_PKGBUILD_PKGREL}-${PKG_PKGBUILD_ARCH}.pkg.tar.xz")
set(PKGBUILD_OUTPUT_PATH "${PKG_SOURCE_ARCHIVE_DIR}/${PKGBUILD_OUTPUT_FILE}")
set(PKGBUILD_FINAL_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/dist-pkg")
set(PKGBUILD_FINAL_FILE "${PKG_NAME}-${PKG_PKGBUILD_VER}-${PKG_PKGBUILD_PKGREL}_${LINUX_DIST_NAME}-${PKG_PKGBUILD_ARCH}.pkg.tar.xz")
add_custom_target(dist-package
COMMAND ${MAKEPKG_EXECUTABLE} -f --log --skipinteg
WORKING_DIRECTORY "${PKG_SOURCE_ARCHIVE_DIR}"
VERBATIM
)
add_custom_command(TARGET dist-package PRE_BUILD
COMMAND ${CMAKE_COMMAND} ARGS -E make_directory "${PKGBUILD_FINAL_OUTPUT_DIR}"
)
add_custom_command(TARGET dist-package POST_BUILD
COMMAND ${CMAKE_COMMAND} ARGS -E copy_if_different "${PKGBUILD_OUTPUT_PATH}" "${PKGBUILD_FINAL_OUTPUT_DIR}/${PKGBUILD_FINAL_FILE}"
)
add_dependencies(dist-package source-archive)
endfunction()
# Default cpack packaging (DEB, RPM, TGZ)
function(_cpack_default_packaging)
set(PKG_CPACK_PKG_FILENAME "${PKG_NAME}-${PKG_VERSION_STRING}_${PKG_DIST}-${CMAKE_SYSTEM_PROCESSOR}")
set(PKG_CPACK_PKG_FILE_PREFIX "dist-pkg")
set(PKG_CONFIG_TEMPLATE "${_LinuxPackaging_DIRECTORY}/LinuxPkgCPackConfig.cmake.in")
set(PKG_CONFIG_FILE "${CMAKE_CURRENT_BINARY_DIR}/CPackConfig-${PKG_TYPE}.cmake")
configure_file("${PKG_CONFIG_TEMPLATE}" "${PKG_CONFIG_FILE}" @ONLY)
add_custom_target(dist-package
COMMAND ${CPACK_COMMAND} --config "${PKG_CONFIG_FILE}"
WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
VERBATIM
)
endfunction()
## Add 'source-archive' target
function(add_source_archive_target target)
find_package(Git)
find_program(TAR_EXECUTABLE tar)
find_program(GZIP_EXECUTABLE gzip)
if(GIT_FOUND)
get_target_property(VERSION_STRING ${target} VERSION_STRING)
execute_process(COMMAND ${GIT_EXECUTABLE} describe --always
RESULT_VARIABLE result
OUTPUT_VARIABLE GIT_TREEISH
ERROR_VARIABLE error_out
OUTPUT_STRIP_TRAILING_WHITESPACE
WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
)
if(NOT result EQUAL 0)
set(GIT_TREEISH "HEAD")
endif()
# Write
set(ARCHIVE_STAGE_DIR "${PROJECT_BINARY_DIR}/archive_stage")
set(FILE_BASENAME "${target}-${VERSION_STRING}_source")
set(GIT_TAR_FILE_PATH "${ARCHIVE_STAGE_DIR}/${FILE_BASENAME}.git-stage.tar")
add_custom_command(OUTPUT "${GIT_TAR_FILE_PATH}"
COMMAND ${CMAKE_COMMAND} ARGS -E make_directory "${ARCHIVE_STAGE_DIR}"
COMMAND ${GIT_EXECUTABLE} ARGS archive --format=tar --prefix=${target}-${VERSION_STRING}/ --output="${GIT_TAR_FILE_PATH}" ${GIT_TREEISH}
WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
COMMENT "Running git archive (${target})..."
)
set(ARCHIVE_OUTPUT_DIR "${PROJECT_BINARY_DIR}/archive_output")
set(TAR_FILE_PATH "${ARCHIVE_OUTPUT_DIR}/${FILE_BASENAME}.tar")
set(TARGZ_FILE_PATH "${TAR_FILE_PATH}.gz")
set(TARGZ_FILE_NAME "${FILE_BASENAME}.tar.gz")
set(TAR_APPEND_DIR "${PROJECT_BINARY_DIR}/archive_append")
add_custom_command(OUTPUT "${TARGZ_FILE_PATH}"
DEPENDS "${GIT_TAR_FILE_PATH}"
COMMAND ${CMAKE_COMMAND} ARGS -E copy "${GIT_TAR_FILE_PATH}" "${TAR_FILE_PATH}"
COMMAND ${CMAKE_COMMAND} ARGS -E create_symlink "${PROJECT_BINARY_DIR}/archive_append" "${ARCHIVE_STAGE_DIR}/${target}-${VERSION_STRING}"
COMMAND ${TAR_EXECUTABLE} ARGS -rf "${TAR_FILE_PATH}" "${target}-${VERSION_STRING}/*"
COMMAND ${GZIP_EXECUTABLE} ARGS -9f "${TAR_FILE_PATH}"
WORKING_DIRECTORY ${ARCHIVE_STAGE_DIR}
COMMENT "Add version information to git archive (${target})..."
)
set(ARCHIVE_FINAL_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/dist-pkg")
add_custom_target(source-archive DEPENDS "${TARGZ_FILE_PATH}")
set_target_properties(source-archive PROPERTIES OUTPUT_ARCHIVE "${TARGZ_FILE_PATH}")
add_custom_command(TARGET source-archive PRE_BUILD
COMMAND ${CMAKE_COMMAND} ARGS -E make_directory "${ARCHIVE_FINAL_OUTPUT_DIR}")
add_custom_command(TARGET source-archive POST_BUILD
COMMAND ${CMAKE_COMMAND} ARGS -E copy_if_different "${TARGZ_FILE_PATH}" "${ARCHIVE_FINAL_OUTPUT_DIR}/${TARGZ_FILE_NAME}")
else()
message(STATUS "Cannot add 'source-archive' target, git not found.")
endif()
endfunction()
|
