1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
find_package(CURL REQUIRED)
add_library(push
src/curl_wrapper.cc
src/curl_wrapper.h
src/gateway.cc
)
add_library(${PROJECT_NAME}::push ALIAS push)
target_link_libraries(push
PUBLIC
${PROJECT_NAME}::core
PRIVATE
Threads::Threads
CURL::libcurl
$<$<AND:$<BOOL:UNIX>,$<NOT:$<BOOL:APPLE>>>:rt>
)
target_include_directories(push
PUBLIC
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
$<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}/include>
)
set_target_properties(push
PROPERTIES
OUTPUT_NAME ${PROJECT_NAME}-push
DEFINE_SYMBOL PROMETHEUS_CPP_PUSH_EXPORTS
VERSION "${PROJECT_VERSION}"
SOVERSION "${PROJECT_VERSION_MAJOR}.${PROJECT_VERSION_MINOR}"
)
generate_export_header(push
BASE_NAME ${PROJECT_NAME}-push
EXPORT_FILE_NAME include/prometheus/detail/push_export.h
)
install(
TARGETS push
EXPORT ${PROJECT_NAME}-targets
RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
)
install(
DIRECTORY include/ ${CMAKE_CURRENT_BINARY_DIR}/include/
DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
)
if(GENERATE_PKGCONFIG)
set(PKGCONFIG_LIBS)
set(PKGCONFIG_REQUIRES)
string(APPEND PKGCONFIG_REQUIRES " libcurl")
configure_file(
${PROJECT_SOURCE_DIR}/cmake/prometheus-cpp-push.pc.in
${CMAKE_CURRENT_BINARY_DIR}/prometheus-cpp-push.pc
@ONLY
)
install(
FILES ${CMAKE_CURRENT_BINARY_DIR}/prometheus-cpp-push.pc
DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig
)
unset(PKGCONFIG_LIBS)
unset(PKGCONFIG_REQUIRES)
endif()
if(ENABLE_TESTING)
add_subdirectory(tests)
endif()
|
