1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
|
# == Class: openstack_extras::repo::redhat::redhat
#
# This class sets up repositories for use with the supported
# operating systems in the RedHat OS family.
#
# === Parameters:
#
# [*release*]
# (Optional) The OpenStack release to use.
# Defaults to 'flamingo'
#
# [*manage_rdo*]
# (Optional) Whether to create a yumrepo resource for the
# RDO OpenStack repository.
# Defaults to true
#
# [*repo_hash*]
# (Optional) A hash of yumrepo resources that will be passed to
# create_resource. See examples folder for some useful examples.
# Defaults to {}
#
# [*repo_source_hash*]
# (Optional) A hash of repo files.
# Defaults to {}
#
# [*repo_replace*]
# (Optional) Replace repo files when their contents are changed.
# Defaults to true
#
# [*repo_defaults*]
# (Optional) The defaults for the yumrepo resources that will be
# created using create_resource.
# Defaults to {}
#
# [*gpgkey_hash*]
# (Optional) A hash of file resources that will be passed to
# create_resources. See examples folder for some useful examples.
# Defaults to {}
#
# [*gpgkey_defaults*]
# (Optional) The default resource attributes to create gpgkeys with.
# Defaults to {}
#
# [*purge_unmanaged*]
# (Optional) Purge the yum.repos.d directory of all repositories
# not managed by Puppet.
# Defaults to false
#
# [*package_require*]
# (Optional) Set all packages to require all yumrepos be set.
# Defaults to false
#
# [*centos_mirror_url*]
# (Optional) URL of CentOS mirror.
# Defaults to 'http://mirror.stream.centos.org'
#
# [*update_packages*]
# (Optional) Whether to update all packages after yum repositories are
# configured.
# Defaults to false
#
# [*update_timeout*]
# (Optional) Timeout for package update.
# Defaults to 600
#
# DEPRECATED PARAMETER
#
# [*manage_epel*]
# (Optional) Whether to create a predefined yumrepo resource for
# the EPEL repository. Note EPEL is not required for deploying
# OpenStack with RDO.
# Defaults to false
#
class openstack_extras::repo::redhat::redhat (
String[1] $release = 'flamingo',
Boolean $manage_rdo = true,
Hash $repo_hash = {},
Hash $repo_source_hash = {},
Boolean $repo_replace = true,
Hash $repo_defaults = {},
Hash $gpgkey_hash = {},
Hash $gpgkey_defaults = {},
Boolean $purge_unmanaged = false,
Boolean $package_require = false,
String[1] $centos_mirror_url = 'http://mirror.stream.centos.org',
Boolean $update_packages = false,
Integer[0] $update_timeout = 600,
# DEPRECATED PARAMETERS
Boolean $manage_epel = false,
) {
validate_yum_hash($repo_hash)
$_repo_defaults = stdlib::merge({
'enabled' => '1',
'gpgcheck' => '1',
'mirrorlist' => 'absent',
'notify' => 'Exec[yum_refresh]',
'tag' => 'openstack-extras-repo',
}, $repo_defaults)
$_gpgkey_defaults = stdlib::merge({
'owner' => 'root',
'group' => 'root',
'mode' => '0644',
'tag' => 'openstack-extras-repo',
}, $gpgkey_defaults)
if $manage_rdo {
$release_cap = capitalize($release)
$rdo_baseurl = "${centos_mirror_url}/SIGs/\$stream/cloud/\$basearch/openstack-${release}/"
$rdo_hash = {
'rdo-release' => {
'baseurl' => $rdo_baseurl,
'descr' => "OpenStack ${release_cap} Repository",
'gpgkey' => 'file:///etc/pki/rpm-gpg/RPM-GPG-KEY-CentOS-SIG-Cloud',
'module_hotfixes' => true,
},
}
$rdokey_hash = {
'/etc/pki/rpm-gpg/RPM-GPG-KEY-CentOS-SIG-Cloud' => {
'source' => 'puppet:///modules/openstack_extras/RPM-GPG-KEY-CentOS-SIG-Cloud',
},
}
create_resources('file', $rdokey_hash, $_gpgkey_defaults)
create_resources('yumrepo', $rdo_hash, $_repo_defaults)
}
if $manage_epel {
warning('The manage_epel parameter has been deprecated and will be removed in a future release')
$epel_hash = {
'epel' => {
'metalink' => "https://mirrors.fedoraproject.org/metalink?repo=epel-${facts['os']['release']['major']}&arch=\$basearch",
'descr' => "Extra Packages for Enterprise Linux ${facts['os']['release']['major']} - \$basearch",
'gpgkey' => "file:///etc/pki/rpm-gpg/RPM-GPG-KEY-EPEL-${facts['os']['release']['major']}",
'failovermethod' => 'priority',
},
}
$epelkey_hash = {
"/etc/pki/rpm-gpg/RPM-GPG-KEY-EPEL-${facts['os']['release']['major']}" => {
'source' => "puppet:///modules/openstack_extras/RPM-GPG-KEY-EPEL-${facts['os']['release']['major']}",
},
}
create_resources('file', $epelkey_hash, $_gpgkey_defaults)
create_resources('yumrepo', $epel_hash, $_repo_defaults)
}
create_resources('yumrepo', $repo_hash, $_repo_defaults)
create_resources('file', $gpgkey_hash, $_gpgkey_defaults)
File<| tag == 'openstack-extras-repo' |> -> Yumrepo<| tag == 'openstack-extras-repo' |>
$repo_source_hash.each |$filename, $url| {
file { $filename:
ensure => file,
path => "/etc/yum.repos.d/${filename}",
source => $url,
replace => $repo_replace,
notify => Exec['yum_refresh'],
}
}
if $purge_unmanaged {
resources { 'yumrepo':
purge => true,
}
}
if $package_require {
Yumrepo<||> -> Package<||>
}
exec { 'yum_refresh':
command => '/usr/bin/dnf clean all',
refreshonly => true,
}
if $update_packages {
exec { 'yum_update':
command => '/usr/bin/dnf update -y',
refreshonly => true,
timeout => $update_timeout,
}
Exec['yum_refresh'] ~> Exec['yum_update'] -> Package <||>
}
else {
Exec['yum_refresh'] -> Package <||>
}
}
|
