1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
|
/*
* Copyright 2014-2015 The University of Queensland
* http://www.uq.edu.au
*
* Licensed under the Apache License, Version 2.0 (the "License");
* you may not use this file except in compliance with the License.
* You may obtain a copy of the License at
*
* http://www.apache.org/licenses/LICENSE-2.0
*
* Unless required by applicable law or agreed to in writing, software
* distributed under the License is distributed on an "AS IS" BASIS,
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
* See the License for the specific language governing permissions and
* limitations under the License.
*/
#pragma once
#include <thrust/extrema.h>
#include <cusp/detail/device/arch.h>
#include <cusp/detail/device/common.h>
#include <cusp/detail/device/utils.h>
#include <cusp/detail/device/texture.h>
#include <thrust/device_ptr.h>
namespace cusp
{
namespace detail
{
namespace device
{
////////////////////////////////////////////////////////////////////////
// CDS symmetric SpMV kernels
///////////////////////////////////////////////////////////////////////
// generic version
template <typename IndexType, typename ValueType, unsigned int BLOCK_SIZE, bool UseCache>
__launch_bounds__(BLOCK_SIZE,1)
__global__ void
spmv_cds_symmetric_kernel(const IndexType num_rows,
const IndexType num_diagonals,
const IndexType block_size,
const IndexType pitch,
const IndexType* diagonal_offsets,
const ValueType* values,
const ValueType* x,
ValueType* y)
{
__shared__ IndexType offsets[BLOCK_SIZE];
__shared__ IndexType offsets2[BLOCK_SIZE];
const IndexType thread_id = BLOCK_SIZE * blockIdx.x + threadIdx.x;
const IndexType grid_size = BLOCK_SIZE * gridDim.x;
//const float bsf = (float)block_size;
const IndexType num_cols = num_diagonals * block_size;
const IndexType t_mod_bs = threadIdx.x % block_size;
// for BLOCK_SIZE=256 this is most likely only executed once
for (IndexType base = 0; base < num_cols; base += BLOCK_SIZE)
{
// read a chunk of the diagonal offsets into shared memory
const IndexType chunk_size = thrust::min(IndexType(BLOCK_SIZE), num_cols - base);
if (threadIdx.x < chunk_size) {
offsets[threadIdx.x] = diagonal_offsets[(base + threadIdx.x)/block_size] * block_size + t_mod_bs;
offsets2[threadIdx.x] = -diagonal_offsets[(base + threadIdx.x)/block_size] * block_size + t_mod_bs;
}
__syncthreads();
// process chunk
for (IndexType row = thread_id; row < num_rows; row += grid_size)
{
ValueType sum = (base == 0) ? ValueType(0) : y[row];
// for sm_10 this is faster than integer division
// block_size*(row/block_size)
//const IndexType colbase = block_size*(int)((row/bsf)+0.001f);
const IndexType colbase = block_size*(row/block_size);
// process subdiagonal blocks
for (IndexType n = block_size; n < chunk_size; n++)
{
const IndexType col = colbase + offsets2[n];
if (col >= 0 && col < num_rows)
{
const IndexType diagbase = block_size*(n/block_size) + t_mod_bs;
const ValueType& A_ij = values[col + pitch*(base+diagbase)];
sum += A_ij * fetch_x<UseCache>(col, x);
}
}
// index into values array
IndexType idx = row + pitch * base;
// process main and upper diagonal blocks
for (IndexType n = 0; n < chunk_size; n++)
{
const IndexType col = colbase + offsets[n];
if (col >= 0 && col < num_rows)
{
const ValueType& A_ij = values[idx];
sum += A_ij * fetch_x<UseCache>(col, x);
}
idx += pitch;
}
y[row] = sum;
}
// wait until all threads are done reading offsets
__syncthreads();
}
}
//
// diagonal block size 2
//
template <typename IndexType, typename ValueType, unsigned int BLOCK_SIZE, bool UseCache>
__launch_bounds__(BLOCK_SIZE,1)
__global__ void
spmv_cds_symmetric_bs2_kernel(const IndexType num_rows,
const IndexType num_diagonals,
const IndexType pitch,
const IndexType* diagonal_offsets,
const ValueType* values,
const ValueType* x,
ValueType* y)
{
__shared__ IndexType offsets[BLOCK_SIZE];
__shared__ IndexType offsets2[BLOCK_SIZE];
const IndexType thread_id = BLOCK_SIZE * blockIdx.x + threadIdx.x;
const IndexType grid_size = BLOCK_SIZE * gridDim.x;
const IndexType t_mod_bs = threadIdx.x % 2;
// for BLOCK_SIZE=256 this is most likely only executed once
for (IndexType base = 0; base < num_diagonals; base += BLOCK_SIZE)
{
// read a chunk of the diagonal offsets into shared memory
const IndexType chunk_size = thrust::min(IndexType(BLOCK_SIZE), num_diagonals - base);
if (threadIdx.x < chunk_size) {
offsets[threadIdx.x] = 2*diagonal_offsets[base + threadIdx.x];
offsets2[threadIdx.x] = -2*diagonal_offsets[num_diagonals - base - 1 - threadIdx.x];
}
__syncthreads();
// process chunk
for (IndexType row = thread_id; row < num_rows; row += grid_size)
{
const IndexType row_step = 2*(row/2);
ValueType sum1 = (base == 0) ? ValueType(0) : y[row];
// index into values array
IndexType idx = 2 * pitch * (num_diagonals - base - 1) + t_mod_bs*pitch;
// process subdiagonal blocks
for (IndexType n = 0; n < chunk_size-1; n++)
{
const IndexType col = row_step + offsets2[n];
if (col >= 0 && col <= num_rows-2)
{
sum1 += values[col + idx] * fetch_x<UseCache>(col, x);
sum1 += values[col+1 + idx] * fetch_x<UseCache>(col+1, x);
}
idx -= 2*pitch;
}
// index into values array
idx = row + 2 * pitch * base;
// process main and upper diagonal blocks
for (IndexType n = 0; n < chunk_size; n++)
{
const IndexType col = row_step + offsets[n];
if (col >= 0 && col <= num_rows-2)
{
sum1 += values[idx] * fetch_x<UseCache>(col, x);
sum1 += values[idx+pitch] * fetch_x<UseCache>(col+1, x);
}
idx += 2*pitch;
}
y[row] = sum1;
}
// wait until all threads are done reading offsets
__syncthreads();
}
}
//
// diagonal block size 3
//
template <typename IndexType, typename ValueType, unsigned int BLOCK_SIZE, bool UseCache>
__launch_bounds__(BLOCK_SIZE,1)
__global__ void
spmv_cds_symmetric_bs3_kernel(const IndexType num_rows,
const IndexType num_diagonals,
const IndexType pitch,
const IndexType* diagonal_offsets,
const ValueType* values,
const ValueType* x,
ValueType* y)
{
__shared__ IndexType offsets[BLOCK_SIZE];
__shared__ IndexType offsets2[BLOCK_SIZE];
const IndexType thread_id = BLOCK_SIZE * blockIdx.x + threadIdx.x;
const IndexType grid_size = BLOCK_SIZE * gridDim.x;
const IndexType t_mod_bs = threadIdx.x % 3;
// for BLOCK_SIZE=256 this is most likely only executed once
for (IndexType base = 0; base < num_diagonals; base += BLOCK_SIZE)
{
// read a chunk of the diagonal offsets into shared memory
const IndexType chunk_size = thrust::min(IndexType(BLOCK_SIZE), num_diagonals - base);
if (threadIdx.x < chunk_size) {
offsets[threadIdx.x] = 3*diagonal_offsets[base + threadIdx.x];
offsets2[threadIdx.x] = -3*diagonal_offsets[num_diagonals - base - 1 - threadIdx.x];
}
__syncthreads();
// process chunk
for (IndexType row = thread_id; row < num_rows; row += grid_size)
{
const IndexType row_step = 3*(row/3);
ValueType sum1 = (base == 0) ? ValueType(0) : y[row];
// index into values array
IndexType idx = 3 * pitch * (num_diagonals - base - 1) + t_mod_bs*pitch;
// process subdiagonal blocks
for (IndexType n = 0; n < chunk_size-1; n++)
{
const IndexType col = row_step + offsets2[n];
if (col >= 0 && col <= num_rows-3)
{
sum1 += values[col + idx] * fetch_x<UseCache>(col, x);
sum1 += values[col+1 + idx] * fetch_x<UseCache>(col+1, x);
sum1 += values[col+2 + idx] * fetch_x<UseCache>(col+2, x);
}
idx -= 3*pitch;
}
// index into values array
idx = row + 3 * pitch * base;
// process main and upper diagonal blocks
for (IndexType n = 0; n < chunk_size; n++)
{
const IndexType col = row_step + offsets[n];
if (col >= 0 && col <= num_rows-3)
{
sum1 += values[idx] * fetch_x<UseCache>(col, x);
sum1 += values[idx+pitch] * fetch_x<UseCache>(col+1, x);
sum1 += values[idx+2*pitch] * fetch_x<UseCache>(col+2, x);
}
idx += 3*pitch;
}
y[row] = sum1;
}
// wait until all threads are done reading offsets
__syncthreads();
}
}
template <bool UseCache,
typename Matrix,
typename ValueType>
void __spmv_cds_symmetric(const Matrix& A,
const ValueType* x,
ValueType* y)
{
using cusp::detail::device::arch::max_active_blocks;
typedef typename Matrix::index_type IndexType;
const size_t BLOCK_SIZE = 192;
const IndexType num_diagonals = A.values.num_cols / A.block_size;
const IndexType pitch = A.values.pitch;
if (UseCache)
bind_x(x);
switch (A.block_size) {
case 2: {
const size_t MAX_BLOCKS = max_active_blocks(
spmv_cds_symmetric_bs2_kernel<IndexType, ValueType,
BLOCK_SIZE, UseCache>, BLOCK_SIZE,
(size_t) sizeof(IndexType) * BLOCK_SIZE);
const size_t NUM_BLOCKS = std::min<size_t>(MAX_BLOCKS,
DIVIDE_INTO(A.num_rows, BLOCK_SIZE));
spmv_cds_symmetric_bs2_kernel<IndexType, ValueType, BLOCK_SIZE, UseCache>
<<<NUM_BLOCKS, BLOCK_SIZE>>>(A.num_rows, num_diagonals, pitch,
thrust::raw_pointer_cast(&A.diagonal_offsets[0]),
thrust::raw_pointer_cast(&A.values.values[0]), x, y);
}
break;
case 3: {
const size_t MAX_BLOCKS = max_active_blocks(
spmv_cds_symmetric_bs3_kernel<IndexType, ValueType,
BLOCK_SIZE, UseCache>, BLOCK_SIZE,
(size_t) sizeof(IndexType) * BLOCK_SIZE);
const size_t NUM_BLOCKS = std::min<size_t>(MAX_BLOCKS,
DIVIDE_INTO(A.num_rows, BLOCK_SIZE));
spmv_cds_symmetric_bs3_kernel<IndexType, ValueType, BLOCK_SIZE, UseCache>
<<<NUM_BLOCKS, BLOCK_SIZE>>>(A.num_rows, num_diagonals, pitch,
thrust::raw_pointer_cast(&A.diagonal_offsets[0]),
thrust::raw_pointer_cast(&A.values.values[0]), x, y);
}
break;
default: {
const size_t MAX_BLOCKS = max_active_blocks(
spmv_cds_symmetric_kernel<IndexType, ValueType, BLOCK_SIZE,
UseCache>, BLOCK_SIZE,
(size_t) sizeof(IndexType) * BLOCK_SIZE);
const size_t NUM_BLOCKS = std::min<size_t>(MAX_BLOCKS,
DIVIDE_INTO(A.num_rows, BLOCK_SIZE));
spmv_cds_symmetric_kernel<IndexType, ValueType, BLOCK_SIZE, UseCache>
<<<NUM_BLOCKS, BLOCK_SIZE>>>(A.num_rows, num_diagonals,
A.block_size, pitch,
thrust::raw_pointer_cast(&A.diagonal_offsets[0]),
thrust::raw_pointer_cast(&A.values.values[0]), x, y);
}
}
if (UseCache)
unbind_x(x);
}
} // end namespace device
} // end namespace detail
} // end namespace cusp
|
