1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
|
#!/usr/bin/tcsh -f
#----------------------------------------------------------
# Route script using qrouter
#----------------------------------------------------------
# Tim Edwards, 5/16/11, for Open Circuit Design
# Modified April 2013 for use with qflow
#----------------------------------------------------------
if ($#argv < 2) then
echo Usage: router.sh [options] <project_path> <source_name>
exit 1
endif
# Split out options from the main arguments
set argline=(`getopt "nr" $argv[1-]`)
set options=`echo "$argline" | awk 'BEGIN {FS = "-- "} END {print $1}'`
set cmdargs=`echo "$argline" | awk 'BEGIN {FS = "-- "} END {print $2}'`
set argc=`echo $cmdargs | wc -w`
if ($argc >= 2) then
set argv1=`echo $cmdargs | cut -d' ' -f1`
set argv2=`echo $cmdargs | cut -d' ' -f2`
if ($argc == 3) then
set statusin = `echo $cmdargs | cut -d' ' -f3`
if ($statusin == 2) then
echo "Qrouter completed on first iteration, no need to run again."
exit 0
endif
endif
else
echo Usage: router.sh [options] <project_path> <source_name>
echo where
echo <project_path> is the name of the project directory containing
echo a file called qflow_vars.sh.
echo <source_name> is the root name of the verilog file
exit 1
endif
set projectpath=$argv1
set sourcename=$argv2
set rootname=${sourcename:h}
# This script is called with the first argument <project_path>, which should
# have file "qflow_vars.sh". Get all of our standard variable definitions
# from the qflow_vars.sh file.
if (! -f ${projectpath}/qflow_vars.sh ) then
echo "Error: Cannot find file qflow_vars.sh in path ${projectpath}"
exit 1
endif
source ${projectpath}/qflow_vars.sh
source ${techdir}/${techname}.sh
cd ${projectpath}
if (-f project_vars.sh) then
source project_vars.sh
endif
if (! ${?qrouter_options} ) then
set qrouter_options = ${options}
endif
# logfile should exist, but just in case. . .
touch ${synthlog}
# Check if last line of log file says "error condition"
set errcond = `tail -1 ${synthlog} | grep "error condition" | wc -l`
if ( ${errcond} == 1 ) then
echo "Synthesis flow stopped on error condition. Detail routing"
echo "will not proceed until error condition is cleared."
exit 1
endif
# Prepend techdir to leffile unless leffile begins with "/"
set abspath=`echo ${leffile} | cut -c1`
if ( "${abspath}" == "/" ) then
set lefpath=${leffile}
else
set lefpath=${techdir}/${leffile}
endif
#----------------------------------------------------------
# Done with initialization
#----------------------------------------------------------
cd ${layoutdir}
#------------------------------------------------------------------
# Determine the version number and availability of scripting
#------------------------------------------------------------------
set version=`${bindir}/qrouter -v 0 -h | tail -1`
set major=`echo $version | cut -d. -f1`
set minor=`echo $version | cut -d. -f2`
set subv=`echo $version | cut -d. -f3`
set scripting=`echo $version | cut -d. -f4`
# If there is a file called (project)_unroute.def, copy it
# to the primary .def file to be used by the router. This
# overwrites any previously generated route solution.
if ( -f ${rootname}_unroute.def ) then
cp ${rootname}_unroute.def ${rootname}.def
endif
if (${scripting} == "T") then
#------------------------------------------------------------------
# Scripted qrouter. Given qrouter with Tcl/Tk scripting capability,
# create a script to perform the routing. The script will allow
# the graphics to display, keep the output to the console at a
# minimum, and generate a file with congestion information in the
# case of route failure.
#------------------------------------------------------------------
echo "Running qrouter $version"
${bindir}/qrouter -noc -s ${rootname}.cfg ${qrouter_options} \
|& tee -a ${synthlog} | \
grep - -e fail -e Progress -e remaining.\*00\$ \
-e remaining:\ \[1-9\]0\\\?\$
else
#------------------------------------------------------------------
# Create the detailed route. Monitor the output and print errors
# to the output, as well as writing the "commit" line for every
# 100th route, so the end-user can track the progress.
#------------------------------------------------------------------
echo "Running qrouter $version"
${bindir}/qrouter -c ${rootname}.cfg -p ${vddnet} -g ${gndnet} \
${qrouter_options} ${rootname} |& tee -a ${synthlog} | \
grep - -e fail -e Progress -e remaining.\*00\$ \
-e remaining:\ \[1-9\]0\\\?\$
endif
#---------------------------------------------------------------------
# Spot check: Did qrouter produce file ${rootname}_route.def?
#---------------------------------------------------------------------
if ( !( -f ${rootname}_route.def || ( -M ${rootname}_route.def \
< -M ${rootname}.def ))) then
echo "qrouter failure: No file ${rootname}_route.def." |& tee -a ${synthlog}
echo "Premature exit." |& tee -a ${synthlog}
echo "Synthesis flow stopped due to error condition." >> ${synthlog}
exit 1
endif
#---------------------------------------------------------------------
# If qrouter generated a ".cinfo" file, then annotate the ".cel"
# file, re-run placement, and re-run routing.
#---------------------------------------------------------------------
if (${scripting} == "T") then
if ( -f ${rootname}.cinfo && ( -M ${rootname}.cinfo \
> -M ${rootname}.def )) then
${scriptdir}/decongest.tcl ${rootname} ${lefpath} \
${fillcell} |& tee -a ${synthlog}
endif
endif
if ( -f ${rootname}_route.def ) then
rm -f ${rootname}.def
mv ${rootname}_route.def ${rootname}.def
endif
#------------------------------------------------------------
# Done!
#------------------------------------------------------------
set endtime = `date`
echo "Router script ended on $endtime" >> $synthlog
exit 0
|
