File: oauth.prf

package info (click to toggle)
qoauth 2.0.1~1-3
  • links: PTS, VCS
  • area: main
  • in suites: bookworm, bullseye, buster, sid
  • size: 404 kB
  • ctags: 183
  • sloc: cpp: 1,619; ansic: 11; sh: 10; makefile: 9
file content (42 lines) | stat: -rw-r--r-- 1,179 bytes parent folder | download
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
QOAUTH_INCDIR = /usr/include
QOAUTH_LIBDIR = $$[QT_INSTALL_LIBS]

CONFIG *= qt
CONFIG += crypto

# if we are including oauth.prf from the qoauth tree (and not utilizing it as
# an installed qmake CONFIG feature), then point to the tree.  this allows our
# qoauth tree apps to build before qoauth itself is installed.
exists($$PWD/qoauth.pro) {
    QOAUTH_INCDIR = $$PWD/include
    QOAUTH_LIBDIR = $$PWD/lib
}

LINKAGE =

# on mac, if qoauth was built as a framework, link against it
mac: {
    framework_dir = $${QOAUTH_LIBDIR}
    exists($$framework_dir/qoauth.framework) {
        LIBS += -F$$framework_dir
        exists($$PWD/qoauth.pro): INCLUDEPATH += $$QOAUTH_INCDIR
        else: INCLUDEPATH += $$framework_dir/qoauth.framework/Headers
        LINKAGE = -framework qoauth
    }
}

# else, link normally
isEmpty(LINKAGE) {
    exists($$PWD/qoauth.pro): INCLUDEPATH += $$QOAUTH_INCDIR
    else: INCLUDEPATH += $$QOAUTH_INCDIR/QtOAuth
    LIBS += -L$$QOAUTH_LIBDIR
    LINKAGE = -lqoauth
    CONFIG(debug, debug|release) {
        windows:LINKAGE = -lqoauthd1
        mac:LINKAGE = -lqoauth_debug
    } else {
        windows:LINKAGE = -lqoauth1
    }
}

LIBS += $$LINKAGE