1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
TARGET = Qt3DRender
MODULE = 3drender
QT = core-private gui-private 3dcore-private
QT_PRIVATE = openglextensions
QT_FOR_PRIVATE = concurrent
include (backend/render-backend.pri)
include (geometry/geometry.pri)
include (framegraph/framegraph.pri)
include (frontend/render-frontend.pri)
include (jobs/jobs.pri)
include (lights/lights.pri)
include (materialsystem/materialsystem.pri)
include (renderstates/renderstates.pri)
include (io/io.pri)
include (picking/picking.pri)
include (raycasting/raycasting.pri)
include (services/services.pri)
include (texture/texture.pri)
include (renderers/renderers.pri)
# Qt3D is free of Q_FOREACH - make sure it stays that way:
DEFINES += QT_NO_FOREACH
gcov {
QMAKE_CXXFLAGS += -fprofile-arcs -ftest-coverage
QMAKE_LFLAGS += -fprofile-arcs -ftest-coverage
}
qtConfig(qt3d-simd-avx2) {
CONFIG += simd
QMAKE_CXXFLAGS += $$QMAKE_CFLAGS_AVX2
}
qtConfig(qt3d-simd-sse2):!qtConfig(qt3d-simd-avx2) {
CONFIG += simd
QMAKE_CXXFLAGS += $$QMAKE_CFLAGS_SSE2
}
HEADERS += \
renderlogging_p.h \
qt3drender_global.h \
qt3drender_global_p.h \
aligned_malloc_p.h
SOURCES += \
renderlogging.cpp
MODULE_PLUGIN_TYPES = \
sceneparsers \
geometryloaders \
renderplugins
load(qt_module)
|
