1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
|
// Copyright (C) 2021 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
import QtQuick
import QtCore
import QtQuick.Controls
import QtQuick.Window
import QtQuick.Dialogs
import Qt.labs.platform as Platform
import io.qt.examples.texteditor
// TODO:
// - make designer-friendly
ApplicationWindow {
id: window
width: 1024
height: 600
visible: true
title: document.fileName + " - Text Editor Example"
Component.onCompleted: {
x = Screen.width / 2 - width / 2
y = Screen.height / 2 - height / 2
}
Action {
id: openAction
shortcut: StandardKey.Open
onTriggered: openDialog.open()
}
Action {
id: saveAsAction
shortcut: StandardKey.SaveAs
onTriggered: saveDialog.open()
}
Action {
id: quitAction
shortcut: StandardKey.Quit
onTriggered: close()
}
Action {
id: copyAction
shortcut: StandardKey.Copy
onTriggered: textArea.copy()
}
Action {
id: cutAction
shortcut: StandardKey.Cut
onTriggered: textArea.cut()
}
Action {
id: pasteAction
shortcut: StandardKey.Paste
onTriggered: textArea.paste()
}
Action {
id: boldAction
shortcut: StandardKey.Bold
onTriggered: document.bold = !document.bold
}
Action {
id: italicAction
shortcut: StandardKey.Italic
onTriggered: document.italic = !document.italic
}
Action {
id: underlineAction
shortcut: StandardKey.Underline
onTriggered: document.underline = !document.underline
}
Platform.MenuBar {
Platform.Menu {
title: qsTr("&File")
Platform.MenuItem {
text: qsTr("&Open")
onTriggered: openDialog.open()
}
Platform.MenuItem {
text: qsTr("&Save As...")
onTriggered: saveDialog.open()
}
Platform.MenuItem {
text: qsTr("&Quit")
onTriggered: close()
}
}
Platform.Menu {
title: qsTr("&Edit")
Platform.MenuItem {
text: qsTr("&Copy")
enabled: textArea.selectedText
onTriggered: textArea.copy()
}
Platform.MenuItem {
text: qsTr("Cu&t")
enabled: textArea.selectedText
onTriggered: textArea.cut()
}
Platform.MenuItem {
text: qsTr("&Paste")
enabled: textArea.canPaste
onTriggered: textArea.paste()
}
}
Platform.Menu {
title: qsTr("F&ormat")
Platform.MenuItem {
text: qsTr("&Bold")
checkable: true
checked: document.bold
onTriggered: document.bold = !document.bold
}
Platform.MenuItem {
text: qsTr("&Italic")
checkable: true
checked: document.italic
onTriggered: document.italic = !document.italic
}
Platform.MenuItem {
text: qsTr("&Underline")
checkable: true
checked: document.underline
onTriggered: document.underline = !document.underline
}
Platform.MenuItem {
text: qsTr("&Strikeout")
checkable: true
checked: document.strikeout
onTriggered: document.strikeout = !document.strikeout
}
}
}
FileDialog {
id: openDialog
fileMode: FileDialog.OpenFile
selectedNameFilter.index: 1
nameFilters: ["Text files (*.txt)", "HTML files (*.html *.htm)", "Markdown files (*.md *.markdown)"]
currentFolder: StandardPaths.writableLocation(StandardPaths.DocumentsLocation)
onAccepted: document.load(selectedFile)
}
FileDialog {
id: saveDialog
fileMode: FileDialog.SaveFile
defaultSuffix: document.fileType
nameFilters: openDialog.nameFilters
selectedNameFilter.index: document.fileType === "txt" ? 0 : 1
currentFolder: StandardPaths.writableLocation(StandardPaths.DocumentsLocation)
onAccepted: document.saveAs(selectedFile)
}
FontDialog {
id: fontDialog
onAccepted: document.font = selectedFont
}
ColorDialog {
id: colorDialog
selectedColor: "black"
onAccepted: document.textColor = selectedColor
}
MessageDialog {
title: qsTr("Error")
id: errorDialog
}
MessageDialog {
id : quitDialog
title: qsTr("Quit?")
text: qsTr("The file has been modified. Quit anyway?")
buttons: MessageDialog.Yes | MessageDialog.No
onButtonClicked: function (button, role) { if (role === MessageDialog.YesRole) Qt.quit() }
}
header: ToolBar {
leftPadding: 8
Flow {
id: flow
width: parent.width
Row {
id: fileRow
ToolButton {
id: openButton
text: "\uF115" // icon-folder-open-empty
font.family: "fontello"
action: openAction
focusPolicy: Qt.TabFocus
}
ToolSeparator {
contentItem.visible: fileRow.y === editRow.y
}
}
Row {
id: editRow
ToolButton {
id: copyButton
text: "\uF0C5" // icon-docs
font.family: "fontello"
focusPolicy: Qt.TabFocus
enabled: textArea.selectedText
action: copyAction
}
ToolButton {
id: cutButton
text: "\uE802" // icon-scissors
font.family: "fontello"
focusPolicy: Qt.TabFocus
enabled: textArea.selectedText
action: cutAction
}
ToolButton {
id: pasteButton
text: "\uF0EA" // icon-paste
font.family: "fontello"
focusPolicy: Qt.TabFocus
enabled: textArea.canPaste
action: pasteAction
}
ToolSeparator {
contentItem.visible: editRow.y === formatRow.y
}
}
Row {
id: formatRow
ToolButton {
id: boldButton
text: "\uE800" // icon-bold
font.family: "fontello"
focusPolicy: Qt.TabFocus
checkable: true
checked: document.bold
action: boldAction
}
ToolButton {
id: italicButton
text: "\uE801" // icon-italic
font.family: "fontello"
focusPolicy: Qt.TabFocus
checkable: true
checked: document.italic
action: italicAction
}
ToolButton {
id: underlineButton
text: "\uF0CD" // icon-underline
font.family: "fontello"
focusPolicy: Qt.TabFocus
checkable: true
checked: document.underline
action: underlineAction
}
ToolButton {
id: strikeoutButton
text: "\uF0CC"
font.family: "fontello"
focusPolicy: Qt.TabFocus
checkable: true
checked: document.strikeout
onClicked: document.strikeout = !document.strikeout
}
ToolButton {
id: fontFamilyToolButton
text: qsTr("\uE808") // icon-font
font.family: "fontello"
font.bold: document.bold
font.italic: document.italic
font.underline: document.underline
font.strikeout: document.strikeout
focusPolicy: Qt.TabFocus
onClicked: function () {
fontDialog.selectedFont = document.font
fontDialog.open()
}
}
ToolButton {
id: textColorButton
text: "\uF1FC" // icon-brush
font.family: "fontello"
focusPolicy: Qt.TabFocus
onClicked: function () {
colorDialog.selectedColor = document.textColor
colorDialog.open()
}
Rectangle {
width: aFontMetrics.width + 3
height: 2
color: document.textColor
parent: textColorButton.contentItem
anchors.horizontalCenter: parent.horizontalCenter
anchors.baseline: parent.baseline
anchors.baselineOffset: 6
TextMetrics {
id: aFontMetrics
font: textColorButton.font
text: textColorButton.text
}
}
}
ToolSeparator {
contentItem.visible: formatRow.y === alignRow.y
}
}
Row {
id: alignRow
ToolButton {
id: alignLeftButton
text: "\uE803" // icon-align-left
font.family: "fontello"
focusPolicy: Qt.TabFocus
checkable: true
checked: document.alignment == Qt.AlignLeft
onClicked: document.alignment = Qt.AlignLeft
}
ToolButton {
id: alignCenterButton
text: "\uE804" // icon-align-center
font.family: "fontello"
focusPolicy: Qt.TabFocus
checkable: true
checked: document.alignment == Qt.AlignHCenter
onClicked: document.alignment = Qt.AlignHCenter
}
ToolButton {
id: alignRightButton
text: "\uE805" // icon-align-right
font.family: "fontello"
focusPolicy: Qt.TabFocus
checkable: true
checked: document.alignment == Qt.AlignRight
onClicked: document.alignment = Qt.AlignRight
}
ToolButton {
id: alignJustifyButton
text: "\uE806" // icon-align-justify
font.family: "fontello"
focusPolicy: Qt.TabFocus
checkable: true
checked: document.alignment == Qt.AlignJustify
onClicked: document.alignment = Qt.AlignJustify
}
}
}
}
DocumentHandler {
id: document
document: textArea.textDocument
cursorPosition: textArea.cursorPosition
selectionStart: textArea.selectionStart
selectionEnd: textArea.selectionEnd
property alias family: document.font.family
property alias bold: document.font.bold
property alias italic: document.font.italic
property alias underline: document.font.underline
property alias strikeout: document.font.strikeout
property alias size: document.font.pointSize
Component.onCompleted: {
if (Qt.application.arguments.length === 2)
document.load("file:" + Qt.application.arguments[1]);
else
document.load("qrc:/texteditor.html")
}
onLoaded: function (text, format) {
textArea.textFormat = format
textArea.text = text
}
onError: function (message) {
errorDialog.text = message
errorDialog.open()
}
}
Flickable {
id: flickable
flickableDirection: Flickable.VerticalFlick
anchors.fill: parent
TextArea.flickable: TextArea {
id: textArea
textFormat: Qt.RichText
wrapMode: TextArea.Wrap
focus: true
selectByMouse: true
persistentSelection: true
// Different styles have different padding and background
// decorations, but since this editor is almost taking up the
// entire window, we don't need them.
leftPadding: 6
rightPadding: 6
topPadding: 0
bottomPadding: 0
background: null
MouseArea {
acceptedButtons: Qt.RightButton
anchors.fill: parent
onClicked: contextMenu.open()
}
onLinkActivated: function (link) {
Qt.openUrlExternally(link)
}
}
ScrollBar.vertical: ScrollBar {}
}
Platform.Menu {
id: contextMenu
Platform.MenuItem {
text: qsTr("Copy")
enabled: textArea.selectedText
onTriggered: textArea.copy()
}
Platform.MenuItem {
text: qsTr("Cut")
enabled: textArea.selectedText
onTriggered: textArea.cut()
}
Platform.MenuItem {
text: qsTr("Paste")
enabled: textArea.canPaste
onTriggered: textArea.paste()
}
Platform.MenuSeparator {}
Platform.MenuItem {
text: qsTr("Font...")
onTriggered: function () {
fontDialog.selectedFont = document.font
fontDialog.open()
}
}
Platform.MenuItem {
text: qsTr("Color...")
onTriggered: function () {
colorDialog.selectedColor = document.textColor
colorDialog.open()
}
}
}
onClosing: function (close) {
if (document.modified) {
quitDialog.open()
close.accepted = false
}
}
}
|
