1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
|
// Copyright (C) 2021 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
pragma ComponentBehavior: Bound
import QtQuick
FocusScope {
id: menu
property alias interactive: gridView.interactive
required property Item keyUpTarget
required property Item keyDownTarget
required property Item keyLeftTarget
Rectangle {
anchors.fill: parent
clip: true
gradient: Gradient {
GradientStop {
position: 0.0
color: "#193441"
}
GradientStop {
position: 1.0
color: Qt.darker("#193441")
}
}
GridView {
id: gridView
anchors.fill: parent
anchors.leftMargin: 20
anchors.rightMargin: 20
cellWidth: 152
cellHeight: 152
focus: true
model: 12
KeyNavigation.up: menu.keyUpTarget
KeyNavigation.down: menu.keyDownTarget
KeyNavigation.left: menu.keyLeftTarget
delegate: Item {
id: container
width: gridView.cellWidth
height: gridView.cellHeight
required property int index
Rectangle {
id: content
color: "transparent"
antialiasing: true
anchors.fill: parent
anchors.margins: 20
radius: 10
Rectangle {
color: "#91AA9D"
anchors.fill: parent
anchors.margins: 3
radius: 8
antialiasing: true
}
Image {
source: "images/qt-logo.png"
anchors.centerIn: parent
}
}
MouseArea {
id: mouseArea
anchors.fill: parent
hoverEnabled: true
onClicked: {
container.GridView.view.currentIndex = container.index
container.forceActiveFocus()
}
}
states: State {
name: "active"
when: container.activeFocus
PropertyChanges {
content {
color: "#FCFFF5"
scale: 1.1
}
}
}
transitions: Transition {
NumberAnimation {
properties: "scale"
duration: 100
}
}
}
}
}
}
|
