1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
|
// Copyright (C) 2021 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
// This example shows how to create your own highlight delegate for a ListView
// that uses a SpringAnimation to provide custom movement when the
// highlight bar is moved between items.
import QtQuick
import QtQuick.Particles
Rectangle {
id: root
property real delegateHeight: 65
width: 200; height: 300
gradient: Gradient {
GradientStop { position: 0.0; color: "#EEEEFF" }
GradientStop { position: 1.0; color: "lightblue" }
}
// Define a delegate component. A component will be
// instantiated for each visible item in the list.
component PetDelegate: Item {
id: pet
width: 200; height: root.delegateHeight
z: 10
required property int index
required property string name
required property string type
required property int age
Column {
Text {color: "white"; text: pet.name; font.pixelSize: 18 }
Text {color: "white"; text: 'Type: ' + pet.type; font.pixelSize: 14 }
Text {color: "white"; text: 'Age: ' + pet.age; font.pixelSize: 14 }
}
MouseArea { anchors.fill: parent; onClicked: listView.currentIndex = pet.index; }
// indent the item if it is the current item
states: State {
name: "Current"
when: pet.ListView.isCurrentItem
PropertyChanges { pet.x: 20 }
}
transitions: Transition {
NumberAnimation { properties: "x"; duration: 200 }
}
}
// Define a highlight with customized movement between items.
component HighlightBar : Rectangle {
z: 0
width: 200; height: root.delegateHeight
gradient: Gradient {
GradientStop { position: 0.0; color: "#99FF99" }
GradientStop { position: 1.0; color: "#88FF88" }
}
y: listView.currentItem.y;
Behavior on y { SpringAnimation { spring: 2; damping: 0.2 } }
//! [1]
ImageParticle {
anchors.fill: parent
system: particles
source: "images/flower.png"
color: "red"
clip: true
alpha: 1.0
}
//! [1]
}
ListView {
id: listView
width: 200; height: parent.height
model: petsModel
delegate: PetDelegate {}
focus: true
// Set the highlight delegate. Note we must also set highlightFollowsCurrentItem
// to false so the highlight delegate can control how the highlight is moved.
highlight: HighlightBar {}
highlightFollowsCurrentItem: false
ParticleSystem { id: particles }
Emitter {
system: particles
anchors.fill: parent
emitRate: 0
lifeSpan: 10000
size: 24
sizeVariation: 8
velocity: AngleDirection { angleVariation: 360; magnitude: 3 }
maximumEmitted: 10
startTime: 5000
Timer { running: true; interval: 10; onTriggered: parent.emitRate = 1; }
}
//! [0]
ImageParticle {
anchors.fill: parent
system: particles
source: "images/flower.png"
alpha: 0.1
color: "white"
rotationVariation: 180
z: -1
}
//! [0]
}
ListModel {
id: petsModel
ListElement {
name: "Polly"
type: "Parrot"
age: 12
size: "Small"
}
ListElement {
name: "Penny"
type: "Turtle"
age: 4
size: "Small"
}
ListElement {
name: "Warren"
type: "Rabbit"
age: 2
size: "Small"
}
ListElement {
name: "Spot"
type: "Dog"
age: 9
size: "Medium"
}
ListElement {
name: "Schrödinger"
type: "Cat"
age: 2
size: "Medium"
}
ListElement {
name: "Joey"
type: "Kangaroo"
age: 1
size: "Medium"
}
ListElement {
name: "Kimba"
type: "Bunny"
age: 65
size: "Large"
}
ListElement {
name: "Rover"
type: "Dog"
age: 5
size: "Large"
}
ListElement {
name: "Tiny"
type: "Elephant"
age: 15
size: "Large"
}
}
}
|
