1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
|
// Copyright (C) 2021 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
import QtQuick
import QtQuick.Shapes
Rectangle {
id: root
width: 1024
height: 768
readonly property color col: "lightsteelblue"
gradient: Gradient {
GradientStop {
position: 0.0
color: Qt.tint(root.col, "#20FFFFFF")
}
GradientStop {
position: 0.1
color: Qt.tint(root.col, "#20AAAAAA")
}
GradientStop {
position: 0.9
color: Qt.tint(root.col, "#20666666")
}
GradientStop {
position: 1.0
color: Qt.tint(root.col, "#20000000")
}
}
Rectangle {
id: scissorRect
width: 200
height: 200
x: 150
readonly property real centerY: parent.height / 2 - height / 2
property real dy: 0
y: centerY + dy
clip: true
Loader {
id: loader1
width: parent.width
height: parent.height
y: 25 - scissorRect.dy
source: "tiger.qml"
asynchronous: true
visible: status === Loader.Ready
}
SequentialAnimation {
loops: Animation.Infinite
running: loader1.status === Loader.Ready && (loader1.item as Shape)?.status === Shape.Ready
NumberAnimation {
target: scissorRect
property: "dy"
from: 0
to: -scissorRect.centerY
duration: 2000
}
NumberAnimation {
target: scissorRect
property: "dy"
from: -scissorRect.centerY
to: scissorRect.centerY
duration: 4000
}
NumberAnimation {
target: scissorRect
property: "dy"
from: scissorRect.centerY
to: 0
duration: 2000
}
}
}
// With a more complex transformation (like rotation), stenciling is used
// instead of scissoring, this is more expensive. It may also trigger a
// slower code path for Shapes, depending on the path rendering backend
// in use, and may affect rendering quality as well.
Rectangle {
id: stencilRect
width: 300
height: 200
anchors {
right: parent.right
rightMargin: 100
verticalCenter: parent.verticalCenter
}
clip: true // NB! still clips to bounding rect (not shape)
Loader {
id: loader2
width: parent.width
height: parent.height
source: "tiger.qml"
asynchronous: true
visible: status === Loader.Ready
}
NumberAnimation on rotation {
from: 0
to: 360
duration: 5000
loops: Animation.Infinite
}
}
}
|
