File: WebTabStack.qml

package info (click to toggle)
qt6-webengine 6.10.2%2Bdfsg-1
  • links: PTS, VCS
  • area: main
  • in suites: experimental
  • size: 4,671,016 kB
  • sloc: cpp: 22,197,192; ansic: 7,781,909; javascript: 3,732,826; asm: 884,326; python: 854,764; xml: 640,231; java: 234,410; sh: 105,601; objc: 99,884; perl: 72,440; cs: 49,062; sql: 44,944; makefile: 25,638; fortran: 24,137; pascal: 23,962; tcl: 9,609; yacc: 8,631; php: 6,473; lisp: 4,674; lex: 1,327; ruby: 914; awk: 339; csh: 120; sed: 36
file content (51 lines) | stat: -rw-r--r-- 1,198 bytes parent folder | download | duplicates (6) 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
 
// Copyright (C) 2019 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause

import QtQml.Models
import QtQuick
import QtQuick.Controls

Rectangle {
    id: root

    signal closeRequested(int index)
    signal drawerRequested

    property int freezeDelay
    property int discardDelay

    property int currentIndex
    property var currentTab: model.children[currentIndex]
    property alias count: model.count

    color: "white"

    ObjectModel {
        id: model
    }

    Component {
        id: factory
        WebTab {
            readonly property int index : ObjectModel.index
            anchors.fill: parent
            visible: index == root.currentIndex
            freezeDelay: root.freezeDelay
            discardDelay: root.discardDelay
            onCloseRequested: root.closeRequested(index)
            onDrawerRequested: root.drawerRequested()
        }
    }

    function createNewTab(properties) {
        const tab = factory.createObject(root, properties)
        model.append(tab)
        return tab
    }

    function closeTab(index) {
        const tab = model.get(index)
        model.remove(index)
        tab.destroy()
    }
}