File: FindNinja.cmake

package info (click to toggle)
qt6-webengine 6.8.2%2Bdfsg-4
  • links: PTS, VCS
  • area: main
  • in suites: trixie
  • size: 3,834,164 kB
  • sloc: cpp: 20,319,195; ansic: 8,076,006; javascript: 3,260,843; asm: 839,896; python: 814,858; xml: 506,536; java: 215,396; sh: 104,539; objc: 99,126; perl: 71,598; cs: 50,882; fortran: 24,137; makefile: 24,065; sql: 19,787; pascal: 13,725; tcl: 9,530; yacc: 8,012; php: 6,830; lisp: 3,457; lex: 1,323; ruby: 901; awk: 339; csh: 120; sed: 37
file content (34 lines) | stat: -rw-r--r-- 1,028 bytes parent folder | download | duplicates (3) 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
 
# Copyright (C) 2022 The Qt Company Ltd.
# SPDX-License-Identifier: BSD-3-Clause

if (NOT DEFINED WEBENGINE_ROOT_BUILD_DIR)
    set(WEBENGINE_ROOT_BUILD_DIR ${CMAKE_CURRENT_BINARY_DIR})
endif()

find_program(Ninja_EXECUTABLE NAMES ninja ninja-build PATHS "${WEBENGINE_ROOT_BUILD_DIR}/install/bin" NO_DEFAULT_PATH)
find_program(Ninja_EXECUTABLE NAMES ninja ninja-build)

if(Ninja_EXECUTABLE)
    execute_process(
        COMMAND ${Ninja_EXECUTABLE} --version
        OUTPUT_VARIABLE Ninja_VERSION
        ERROR_QUIET
        OUTPUT_STRIP_TRAILING_WHITESPACE)
endif()

include(FindPackageHandleStandardArgs)
find_package_handle_standard_args(
    Ninja
    REQUIRED_VARS Ninja_EXECUTABLE
    VERSION_VAR Ninja_VERSION)

if(Ninja_FOUND AND NOT TARGET Ninja::ninja)
    add_executable(Ninja::ninja IMPORTED)
    set_property(TARGET Ninja::ninja PROPERTY IMPORTED_LOCATION ${Ninja_EXECUTABLE})
endif()

include(FeatureSummary)
set_package_properties(Ninja PROPERTIES
    URL "https://ninja-build.org/"
    DESCRIPTION "Build tool"
)