File: WebTabBar.qml

package info (click to toggle)
qt6-webengine 6.9.2%2Bdfsg-4
  • links: PTS, VCS
  • area: main
  • in suites: forky, sid
  • size: 4,111,664 kB
  • sloc: cpp: 21,437,331; ansic: 8,087,114; javascript: 2,747,888; python: 856,615; asm: 848,149; xml: 616,344; java: 222,847; sh: 105,209; objc: 99,183; perl: 70,870; cs: 51,103; sql: 40,087; makefile: 26,384; pascal: 25,140; fortran: 24,137; tcl: 9,609; yacc: 8,132; php: 7,051; lisp: 3,462; lex: 1,327; ruby: 914; awk: 339; csh: 120; sed: 36
file content (53 lines) | stat: -rw-r--r-- 1,094 bytes parent folder | download | duplicates (5) 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
 
// Copyright (C) 2019 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause

import QtQuick
import QtQuick.Controls
import QtQuick.Controls.Material
import QtQuick.Layouts

Pane {
    id: root

    property Action newTabAction

    property alias currentIndex: tabBar.currentIndex

    signal closeRequested(int index)

    Material.background: Material.color(Material.Grey, Material.Shade900)
    Material.elevation: 4
    padding: 0

    RowLayout {
        spacing: 0
        anchors.fill: parent

        TabBar {
            id: tabBar
            Layout.fillWidth: true
            Layout.fillHeight: true
        }

        WebToolButton {
            Layout.bottomMargin: 2

            action: root.newTabAction
            text: "+"
            ToolTip.text: root.newTabAction.text
        }
    }

    Component {
        id: factory
        WebTabButton {}
    }

    function createNewTab(properties) {
        return factory.createObject(tabBar, properties)
    }

    function closeTab(index) {
        tabBar.takeItem(index).destroy()
    }
}