1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
|
/****************************************************************************
**
** Copyright (C) 2016 Jeremy Katz
** Contact: https://www.qt.io/licensing/
**
** This file is part of the test suite of the Qt Toolkit.
**
** $QT_BEGIN_LICENSE:GPL-EXCEPT$
** Commercial License Usage
** Licensees holding valid commercial Qt licenses may use this file in
** accordance with the commercial license agreement provided with the
** Software or, alternatively, in accordance with the terms contained in
** a written agreement between you and The Qt Company. For licensing terms
** and conditions see https://www.qt.io/terms-conditions. For further
** information use the contact form at https://www.qt.io/contact-us.
**
** GNU General Public License Usage
** Alternatively, this file may be used under the terms of the GNU
** General Public License version 3 as published by the Free Software
** Foundation with exceptions as appearing in the file LICENSE.GPL3-EXCEPT
** included in the packaging of this file. Please review the following
** information to ensure the GNU General Public License requirements will
** be met: https://www.gnu.org/licenses/gpl-3.0.html.
**
** $QT_END_LICENSE$
**
****************************************************************************/
import QtQuick 2.0
import QtQuick.Window 2.0
import QtTest 1.0
MultiPointTouchArea {
id: touchArea
width: 100
height: 100
// touchUpdatedSpy stores the QQuickTouchPoint, and in some cases
// MultiPointTouchArea can delete it out from under us.
// (test_simpleChain was failing because touchUpdatedSpy.signalArguments[0][0][0]
// ended up as an empty object somehow.) If we declare
// all the touchpoints that this test will use, that won't happen.
touchPoints: [
TouchPoint { },
TouchPoint { }
]
SignalSpy {
id: touchUpdatedSpy
target: touchArea
signalName: "touchUpdated"
}
SignalSpy {
id: interiorSpy
target: interior
signalName: "touchUpdated"
}
MultiPointTouchArea {
id: interior
width: parent.width / 2
height: parent.height
anchors.right: parent.right
}
Window {
width: 100; height: 100
SignalSpy {
id: subWindowSpy
target: subWindowTouchArea
signalName: "touchUpdated"
}
MultiPointTouchArea {
id: subWindowTouchArea
anchors.fill: parent
}
}
TestCase {
when: windowShown
name: "touch"
function comparePoint(point, id, x, y) {
var retval = true;
var pointId = point.pointId & 0xFFFFFF; //strip device identifier
if (pointId !== id) {
warn("Unexpected pointId: " + pointId + ". Expected " + id);
retval = false;
}
if (point.x !== x) {
warn("Unexpected x: " + point.x + ". Expected " + x);
retval = false;
}
if (point.y !== y) {
warn("Unexpected y: " + point.y + ". Expected " + y);
retval = false;
}
return retval;
}
function cleanup() {
touchUpdatedSpy.clear();
interiorSpy.clear();
subWindowSpy.clear();
}
function test_secondWindow() {
var first = 1;
var sequence = touchEvent(subWindowTouchArea);
sequence.press(first, 0, 0, 0);
sequence.commit();
sequence.release(first, subWindowTouchArea, 0, 0)
sequence.commit();
compare(subWindowSpy.count, 2);
var touchPoint = subWindowSpy.signalArguments[0][0][0];
verify(comparePoint(touchPoint, first, 0, 0));
}
function initTestCase() {
waitForRendering(touchArea) // when: windowShown may be insufficient
}
function test_childMapping() {
var sequence = touchEvent(touchArea);
var first = 1;
// Test mapping touches to a child item
sequence.press(first, interior, 0, 0);
sequence.commit();
// Map touches to the parent at the same point
sequence.move(first, touchArea, interior.x, interior.y);
sequence.commit();
sequence.release(first, touchArea, interior.x, interior.y);
sequence.commit();
compare(interiorSpy.count, 3);
verify(comparePoint(interiorSpy.signalArguments[0][0][0], first, 0, 0));
verify(comparePoint(interiorSpy.signalArguments[1][0][0], first, 0, 0));
}
function test_fullSequence() {
var sequence = touchEvent(touchArea);
verify(sequence);
var first = 1;
var second = 2;
sequence.press(first, null, 0, 0);
sequence.commit();
compare(touchUpdatedSpy.count, 1);
var touchPoints = touchUpdatedSpy.signalArguments[0][0];
compare(touchPoints.length, 1);
verify(comparePoint(touchPoints[0], first, 0, 0));
sequence.stationary(first);
sequence.press(second, null, 1, 0);
sequence.commit();
compare(touchUpdatedSpy.count, 2);
touchPoints = touchUpdatedSpy.signalArguments[1][0];
compare(touchPoints.length, 2);
verify(comparePoint(touchPoints[0], first, 0, 0));
verify(comparePoint(touchPoints[1], second, 1, 0));
sequence.release(first);
sequence.move(second, null, 1, 1);
sequence.commit();
compare(touchUpdatedSpy.count, 3);
touchPoints = touchUpdatedSpy.signalArguments[2][0];
compare(touchPoints.length, 1);
verify(comparePoint(touchPoints[0], second, 1, 1));
sequence.release(second, null, 0, 1);
sequence.commit();
compare(touchUpdatedSpy.count, 4);
touchPoints = touchUpdatedSpy.signalArguments[3][0];
compare(touchPoints.length, 0);
}
function test_simpleChain() {
var first = 1;
touchEvent(interior).press(first).commit().release(first).commit();
compare(interiorSpy.count, 2);
var touchPoint = interiorSpy.signalArguments[0][0][0];
verify(comparePoint(touchPoint, first, interior.width / 2, interior.height / 2));
}
}
}
|
