File: qmltest.pro

package info (click to toggle)
qtdeclarative-opensource-src 5.15.2%2Bdfsg-6
  • links: PTS, VCS
  • area: main
  • in suites: bullseye
  • size: 259,220 kB
  • sloc: javascript: 512,396; cpp: 493,894; xml: 8,892; python: 3,304; ansic: 2,764; sh: 206; makefile: 59; php: 27
file content (44 lines) | stat: -rw-r--r-- 1,124 bytes parent folder | download | duplicates (4)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
TARGET     = QtQuickTest

QMAKE_DOCS = $$PWD/doc/qtqmltest.qdocconf

DEFINES += QT_NO_URL_CAST_FROM_STRING QT_NO_FOREACH
QT = core testlib-private
QT_PRIVATE = quick quick-private qml-private gui core-private

# Testlib is only a private dependency, which results in our users not
# inheriting testlibs's MODULE_CONFIG transitively. Make it explicit.
MODULE_CONFIG += $${QT.testlib.CONFIG}

qtHaveModule(widgets) {
    QT += widgets
    DEFINES += QT_QMLTEST_WITH_WIDGETS
}

SOURCES += \
    $$PWD/quicktest.cpp \
    $$PWD/quicktestresult.cpp

HEADERS += \
    $$PWD/quicktestglobal.h \
    $$PWD/quicktest.h \
    $$PWD/quicktest_p.h \
    $$PWD/quicktestresult_p.h \
    $$PWD/qtestoptions_p.h

qtConfig(qml-debug): DEFINES += QT_QML_DEBUG_NO_WARNING

load(qt_module)

QMLTYPES_FILENAME = plugins.qmltypes
QMLTYPES_INSTALL_DIR = $$[QT_INSTALL_QML]/Qt/test/qtestroot
QML_IMPORT_NAME = Qt.test.qtestroot
QML_IMPORT_VERSION = 1.0
CONFIG += qmltypes install_qmltypes install_metatypes

# Install qmldir
qmldir.files = $$PWD/qmldir
qmldir.path = $$QMLTYPES_INSTALL_DIR

prefix_build: INSTALLS += qmldir
else: COPIES += qmldir