File: tools.pro

package info (click to toggle)
qtdeclarative-opensource-src 5.3.2-4~bpo70%2B4
  • links: PTS, VCS
  • area: main
  • in suites: wheezy-backports
  • size: 75,780 kB
  • sloc: cpp: 354,437; xml: 8,608; ansic: 2,512; python: 940; sh: 702; perl: 50; makefile: 34; php: 27
file content (34 lines) | stat: -rw-r--r-- 900 bytes parent folder | download | duplicates (2)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
TEMPLATE = subdirs
SUBDIRS += \
    qmlmin \
    qmlimportscanner

qmlmin.CONFIG = host_build
qmlimportscanner.CONFIG = host_build

!android|android_app {
    SUBDIRS += \
        qml \
        qmlprofiler \
        qmlbundle
    qtHaveModule(quick) {
        !static: SUBDIRS += qmlscene qmlplugindump
        qtHaveModule(widgets): SUBDIRS += qmleasing
    }
    qtHaveModule(qmltest): SUBDIRS += qmltestrunner
    contains(QT_CONFIG, private_tests): SUBDIRS += qmljs
}

qml.depends = qmlimportscanner
qmleasing.depends = qmlimportscanner

# qmlmin, qmlimportscanner & qmlbundle are build tools.
# qmlscene is needed by the autotests.
# qmltestrunner may be useful for manual testing.
# qmlplugindump cannot be a build tool, because it loads target plugins.
# The other apps are mostly "desktop" tools and are thus excluded.
qtNomakeTools( \
    qmlprofiler \
    qmlplugindump \
    qmleasing \
)