File: tools.pro

package info (click to toggle)
qtdeclarative-opensource-src 5.7.1-2
  • links: PTS, VCS
  • area: main
  • in suites: stretch
  • size: 88,360 kB
  • ctags: 56,741
  • sloc: cpp: 388,287; xml: 8,608; ansic: 2,554; python: 940; sh: 659; makefile: 57; perl: 50; php: 27
file content (41 lines) | stat: -rw-r--r-- 1,027 bytes parent folder | download
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
TEMPLATE = subdirs
SUBDIRS += \
    qmlmin \
    qmlimportscanner

qmlmin.CONFIG = host_build
qmlimportscanner.CONFIG = host_build

!android|android_app {
    SUBDIRS += \
        qml \
        qmllint

    !contains(QT_CONFIG, no-qml-debug): SUBDIRS += qmlprofiler

    qtHaveModule(quick) {
        !static: {
            SUBDIRS += \
                qmlscene \
                qmlplugindump \
                qmltime
        }
        qtHaveModule(widgets): SUBDIRS += qmleasing
    }
    qtHaveModule(qmltest): SUBDIRS += qmltestrunner
    contains(QT_CONFIG, private_tests): SUBDIRS += qmljs
}

qml.depends = qmlimportscanner
qmleasing.depends = qmlimportscanner

# qmlmin, qmlimportscanner & qmlbundle are build tools.
# qmlscene is needed by the autotests.
# qmltestrunner may be useful for manual testing.
# qmlplugindump cannot be a build tool, because it loads target plugins.
# The other apps are mostly "desktop" tools and are thus excluded.
qtNomakeTools( \
    qmlprofiler \
    qmlplugindump \
    qmleasing \
)