1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
|
#-------------------------------------------------
#
# Qthid project file.
#
#-------------------------------------------------
QT += core gui widgets
TEMPLATE = app
macx {
TARGET = Qthid
} else {
TARGET = qthid
}
# disable debug messages in release
CONFIG(debug, debug|release) {
# Define version string (see below for releases)
VER = $$system(git describe --abbrev=8)
} else {
DEFINES += QT_NO_DEBUG
DEFINES += QT_NO_DEBUG_OUTPUT
VER = 4.1
}
# Tip from: http://www.qtcentre.org/wiki/index.php?title=Version_numbering_using_QMake
VERSTR = '\\"$${VER}\\"' # place quotes around the version string
DEFINES += VERSION=\"$${VERSTR}\" # create a VERSION macro containing the version string
QMAKE_CXXFLAGS += $$(CPPFLAGS)
QMAKE_CPPFLAGS += $$(CPPFLAGS)
QMAKE_CFLAGS += $$(CFLAGS)
QMAKE_LFLAGS += $$(LDFLAGS)
SOURCES +=\
mainwindow.cpp \
main.cpp \
fcd.c \
freqctrl.cpp \
firmware.cpp
mac: SOURCES += hidmac.c
win32: SOURCES += hidwin.c
HEADERS += \
mainwindow.h \
fcd.h fcdhidcmd.h \
freqctrl.h \
firmware.h
FORMS += \
mainwindow.ui \
firmware.ui
mac:LIBS += /System/Library/Frameworks/CoreFoundation.framework/CoreFoundation \
/System/Library/Frameworks/IOKit.framework/Versions/A/IOKit
win32:LIBS += "C:\\Program Files\\Microsoft SDKs\\Windows\\v7.0\\Lib\\setupapi.lib"
# libusb-1.0 on Linux uses pkg-config
linux-g++|linux-g++-64 {
# CONFIG += link_pkgconfig
# PKGCONFIG += libusb-1.0
# SOURCES += hid-libusb.c
LIBS += -ludev -lhidapi-hidraw
} else:unix {
CONFIG += link_pkgconfig
PKGCONFIG += libusb-1.0
LIBS += -lhidapi-libusb
}
RESOURCES += \
qthid.qrc
win32 {
# application icon on Windows
RC_FILE = qthid.rc
} else:macx {
# app icon on OSX
ICON = images/qthid.icns
}
OTHER_FILES += AUTHORS.txt LICENSE.txt NEWS.txt README.txt \
qthid.rc \
images/qthid.ico \
images/qthid.icns
|
