File: embed_info_plist.pri

package info (click to toggle)
qtwebengine-opensource-src 5.15.13%2Bdfsg-1~deb12u1
  • links: PTS, VCS
  • area: main
  • in suites: bookworm
  • size: 2,112,448 kB
  • sloc: cpp: 13,167,885; ansic: 4,228,702; javascript: 1,909,649; python: 554,805; asm: 529,966; xml: 496,619; java: 151,702; objc: 80,776; perl: 73,361; sh: 71,208; cs: 30,383; makefile: 20,779; yacc: 9,120; tcl: 8,394; php: 5,896; sql: 5,473; pascal: 4,510; lex: 2,884; lisp: 2,727; ruby: 559; awk: 200; sed: 40
file content (13 lines) | stat: -rw-r--r-- 503 bytes parent folder | download | duplicates (7) 
1
2
3
4
5
6
7
8
9
10
11
12
13
 
macos {
    CONFIG -= app_bundle

    # QTBUG-57354 embed Info.plist so that certain fonts can be found in non-bundle apps
    out_info = $$OUT_PWD/Info.plist
    embed_info_plist.input = $$PWD/Info.plist.in
    embed_info_plist.output = $$out_info
    TARGET_HYPHENATED = $$replace(TARGET, [^a-zA-Z0-9-.], -)
    QMAKE_SUBSTITUTES += embed_info_plist
    QMAKE_LFLAGS += -Wl,-sectcreate,__TEXT,__info_plist,$$shell_quote($$out_info)
    PRE_TARGETDEPS += $$out_info
    QMAKE_DISTCLEAN += $$out_info
}