File: spellchecking.pro

package info (click to toggle)
qtwebengine-opensource-src 5.15.2%2Bdfsg-3
  • links: PTS, VCS
  • area: main
  • in suites: bullseye
  • size: 1,891,008 kB
  • sloc: cpp: 12,231,790; ansic: 4,139,950; javascript: 590,747; python: 550,957; asm: 507,724; xml: 434,729; java: 166,199; objc: 79,696; perl: 72,973; sh: 70,983; cs: 30,332; makefile: 21,627; yacc: 8,867; tcl: 8,297; php: 5,896; pascal: 4,488; lex: 2,830; lisp: 2,703; sql: 1,810; ruby: 683; awk: 200; sed: 56
file content (24 lines) | stat: -rw-r--r-- 764 bytes parent folder | download | duplicates (6) 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
 
include(../tests.pri)

DISTFILES += \
    dict/en-US.dic \
    dict/en-US.aff \
    dict/de-DE.dic \
    dict/de-DE.aff \

qtPrepareTool(CONVERT_TOOL, qwebengine_convert_dict)

debug_and_release {
    CONFIG(debug, debug|release): DICTIONARIES_DIR = debug/qtwebengine_dictionaries
    else: DICTIONARIES_DIR = release/qtwebengine_dictionaries
} else {
    DICTIONARIES_DIR = qtwebengine_dictionaries
}

dict.files = $$PWD/dict/en-US.dic $$PWD/dict/de-DE.dic
dictoolbuild.input = dict.files
dictoolbuild.output = $${DICTIONARIES_DIR}/${QMAKE_FILE_BASE}.bdic
dictoolbuild.commands = $${CONVERT_TOOL} ${QMAKE_FILE_IN} ${QMAKE_FILE_OUT}
dictoolbuild.name = Build ${QMAKE_FILE_IN_BASE}
dictoolbuild.CONFIG = no_link target_predeps
QMAKE_EXTRA_COMPILERS += dictoolbuild